IE Upload Files button

[Juvigy 50]

 Hi Guys, i am trying to automate a site where you click a button and a window open and ask you to select a file for upload.
 That part works fine, but after that i cant get Autoit to select a file for the upload. I am trying to use the "ControlSend" and similar functions,
 but i cant get it to work. Nothing happens. Here is the screenshot from the info tool:

What am i missing ? It should be an easy thing to do...

 

Edited February 23, 2018 by Juvigy
images got lost

[Danp2 1,156]

It would be helpful if you showed up the script so that we can see what you are trying to do. Chances are that the script is paused waiting for the dialog to disappear.

[Juvigy 50]

Yes, that's the thing - i have noticed that the script is paused until i close the popup. Why does it wait?

Here is my code snippet. You can see i tried many things to get the handle or the control.

IF $oDiv.innerHTML = "Add Files..." Then
;~                      ConsoleWrite("Test:"&$oDiv.id&@CRLF)
;~                      ConsoleWrite("Test:"&$oDiv.title&@CRLF)
                        _IEAction($oDiv,"click")
                        Sleep(1000)
;~                      ControlSetText("Choose File to Upload", "", "","C:\test.txt")
;~                      $hWnd = WinWait("[CLASS:Edit; INSTANCE:1]" ,"",1)
                        $hWnd = WinGetHandle("#32770")
                        MsgBox(0, @error, $hWnd)
;~                      ControlSend($hWnd, "", "", "This is some text")
;~                      ControlClick("[CLASS:Button; INSTANCE:1]","", "")
                    EndIf

 

[Danp2 1,156]

Have you search the forum? You should be able to locate prior discussions where this has already been solved.

[mLipok 1,251]

Take a look here:

 

 

[Juvigy 50]

Danp2

I tried this one instead of the IEclick:

$iBrowserX = _IEPropertyGet($oDiv, "browserx")
$iBrowserY = _IEPropertyGet($oDiv, "browsery")
$iWidth = _IEPropertyGet($oDiv, "width")
$iHeight = _IEPropertyGet($oDiv, "height")
ControlClick(_IEPropertyGet($oIE, "hwnd"), "", "", "left", 1, $iBrowserX + $iWidth/2, $iBrowserY + $iHeight/2)

From e topic from Dale, it didnt work.

mLipok

I tried this and it didnt work.

_ExecuteInBackground
_IEAction($oDiv,"click")

Func _ExecuteInBackground()
    Local $sCommand = _
            'Local ' & _
            '$Dummy1 = WinWaitActive("[CLASS:#32770]", "Choose File to Upload",10), ' & _
            '$Dummy2 = Sleep(1000), ' & _
            '$Dummy3 = ControlSend("[CLASS:#32770]", "Choose File to Upload", "[CLASS:Edit; INSTANCE:1]", "c:\test.txt") ' & _
            ''
    $sCommand = '"' & StringReplace($sCommand, '"', '""') & '"'
    ConsoleWrite($sCommand & @CRLF)
    Run(@AutoItExe & ' /AutoIt3ExecuteLine ' & $sCommand)
EndFunc   ;==>_ExecuteInBackground

 

Edited February 23, 2018 by Juvigy
tested

[Dent 2]

I use the following code to paste in a hard-coded file link to a file upload dialog box in IE

 

WinWait("Choose File to Upload")
$hChoose = WinGetHandle("Choose File to Upload")
Sleep(1000)
ControlSetText($hChoose, "", "Edit1", "C:\Path\To\File.doc")
Sleep(1000)
Send("{ENTER}")
Sleep(1000)

It may work fine without the Sleep's but on the particular box I have this running on I was getting inconsistent results without them.

[Juvigy 50]

Hi Dent,

That works when i do it as a test. I will incorporate it in my script and see if it works.

[Juvigy 50]

It worked, the issue is solved. This is the final code:

 

Func _ExecuteInBackground()
    Local $sCommand = _
            'Local ' & _
            '$Dummy1 = WinWaitActive("Choose File to Upload", "", 20), ' & _
            '$Dummy2 = Sleep(1000), ' & _
            '$Dummy3 = ControlSetText("Choose File to Upload", "", "Edit1", "C:\Path\To\File.doc;C:\Path\To\File1.doc"), ' & _
            '$Dummy4 = ControlClick("Choose File to Upload", "", "Button1") ' & _
            ''
    $sCommand = '"' & StringReplace($sCommand, '"', '""') & '"'
    ConsoleWrite($sCommand & @CRLF)
    Run(@AutoItExe & ' /AutoIt3ExecuteLine ' & $sCommand)
EndFunc   ;==>_ExecuteInBackground

 

[gabi10 0]

😃😃😃 Thank you