"ping.exe" monitoring function.

[mLipok]

I had a need to create a "ping.exe" monitoring function.
Here is the result:

expandcollapse popup

#include <AutoItConstants.au3>
#include <Debug.au3>
#include <Misc.au3>
#include <MsgBoxConstants.au3>

_DebugSetup('Check Ping - press SHIFT KEY to close')

If @ScriptName = 'Ping.exe' Then Exit ; compiled script should not be named "Ping.exe" as this is used for Run() and this can lead to recursion

OnAutoItExitRegister(_Adlib_Ping_Exit)
AdlibRegister(_Adlib_Ping)

_Example()
Func _Example()
    Local $hDLL = DllOpen('user32.dll')

    While 1
        Sleep(10)
        If _IsPressed('10', $hDLL) Then ExitLoop
    WEnd

EndFunc   ;==>_Example

Func _Adlib_Ping()
    Local Static $iPID = Run('ping www.google.com -l 1024 -t', @SystemDir, @SW_HIDE, $STDIN_CHILD + $STDOUT_CHILD)
    Local Static $RUN_ONCE = __Adlib_Ping_Exit($iPID)
    #forceref $RUN_ONCE

    Local Static $sOutput = '' ; Store the output of StdoutRead to a variable.

    Local Static $hTimer = TimerInit() ; Begin the timer and store the handle in a variable.

    $sOutput &= StdoutRead($iPID) ; Read the Stdout stream of the PID returned by Run.
    If @error Then ; Exit the loop if the process closes or StdoutRead returns an error.
        _DebugOut('Ping.exe process (' & $iPID & ') not exist ? ')
        AdlibUnRegister(_Adlib_Ping)
    EndIf
    If StringRegExp($sOutput, '(?is)(\R)', $STR_REGEXPMATCH) Then
        If TimerDiff($hTimer) > 5000 Then
            _DebugOut(@HOUR & ':' & @MIN & ':' & @SEC & ' PING RESULT = ' & $sOutput)
            $hTimer = TimerInit()
        EndIf
        $sOutput = ''
    EndIf

EndFunc   ;==>_Adlib_Ping

Func _Adlib_Ping_Exit()
    __Adlib_Ping_Exit()
EndFunc   ;==>_Adlib_Ping_Exit

Func __Adlib_Ping_Exit($vParameter = Default)
    Local Static $vParameter_static = $vParameter
    If Not @Compiled Then ConsoleWrite('- ' & @ScriptLineNumber & ' Parameter=' & $vParameter & ' Static=' & $vParameter_static & @CRLF)
    If $vParameter = Default And IsInt($vParameter_static) Then
        ProcessClose($vParameter_static)
        If Not @Compiled Then ConsoleWrite('! CLOSE PORCESS' & @CRLF)
        Local $hWndReportWindow = WinGetHandle($__g_sReportTitle_Debug, $__g_sReportWindowText_Debug)
        GUIDelete($hWndReportWindow)
    ElseIf IsInt($vParameter) Then
        $vParameter_static = $vParameter
    EndIf
EndFunc   ;==>__Adlib_Ping_Exit

 

Edited May 25, 2020 by mLipok

[argumentum]

..a very Zen description of the difference between Ping(), ping.exe and your code  
Would you explain at length what need this solves ?  

[TheDcoder]

@mLipok A suggestion to improve efficiency of the main loop, use HotKeySet to modify a variable (probably a boolean) and check that instead of calling _IsPressed

[mLipok]

14 hours ago, TheDcoder said:

@mLipok A suggestion to improve efficiency of the main loop, use HotKeySet to modify a variable (probably a boolean) and check that instead of calling _IsPressed

Main loop is only an example and has nothing to do with efficiency.

 

[mLipok]

14 hours ago, argumentum said:

Would you explain at length what need this solves ?

This following improved example will explain this.

expandcollapse popup

;~ https://www.autoitscript.com/forum/topic/202843-pingexe-monitoring-function/

#include <AutoItConstants.au3>
#include <Debug.au3>
#include <Misc.au3>
#include <MsgBoxConstants.au3>

_DebugSetup('Check Ping - press SHIFT KEY to close')
OnAutoItExitRegister(__DebugClose)

If @ScriptName = 'Ping.exe' Then Exit ; compiled script should not be named "Ping.exe" as this is used for Run() and this can lead to recursion

_Example()

Func _INIT_PING_TESTING()
    _Adlib_Ping_SetURL('www.onet.pl')
    AdlibRegister(_Adlib_Ping_Wrapper)
EndFunc   ;==>_INIT_PING_TESTING

Func _Example()
    ; this example function is only for simulation of looping some activieties
    Local $hDLL = DllOpen('user32.dll')

    ; here we use ForNext Loop, as a way to simulate some data processing or GUI maintaining
    For $iStep_idx = 1 To 1000
        Sleep(1000)
        If _IsPressed('10', $hDLL) Then ExitLoop
        _DebugOut('Step #' & $iStep_idx & ' Some processing.....')
        If $iStep_idx = 11 Then _INIT_PING_TESTING() ; here we simulates a situation when USER starts testing PING
        If $iStep_idx = 100 Then _Adlib_Ping_Exit_Wrapper() ; here we simulates a situation when USER stop testing PING
    Next

    ; REMARKS
    ; PING testing is processed in the "background" as a Adlib
    ; the basic premise is to interleaves PING logs with logs from the main program loop.

EndFunc   ;==>_Example

Func _Adlib_Ping_Wrapper()
    __Adlib_Ping()
EndFunc   ;==>_Adlib_Ping_Wrapper

Func _Adlib_Ping_SetURL($sURL)
    __Adlib_Ping($sURL)
EndFunc   ;==>_Adlib_Ping_SetURL

Func __Adlib_Ping($sURL = Default)
    Local Static $iPID = 0
    If IsString($sURL) And $iPID = 0 Then
        _DebugOut('Testing URL = ' & $sURL)
        $iPID = Run('ping ' & $sURL & ' -l 1024 -t', @SystemDir, @SW_HIDE, $STDIN_CHILD + $STDOUT_CHILD)
        Return
    EndIf

    Local Static $RUN_ONCE_EXIT_1 = OnAutoItExitRegister(_Adlib_Ping_Exit_Wrapper)
    Local Static $RUN_ONCE_EXIT_2 = __Adlib_Ping_Exit($iPID)
    #forceref $RUN_ONCE_EXIT_1, $RUN_ONCE_EXIT_2

    Local Static $sOutput = '' ; Store the output of StdoutRead to a variable.

    Local Static $hTimer = TimerInit() ; Begin the timer and store the handle in a variable.

    $sOutput &= StdoutRead($iPID) ; Read the Stdout stream of the PID returned by Run.
    If @error Then ; Exit the loop if the process closes or StdoutRead returns an error.
        _DebugOut('Ping.exe process (' & $iPID & ') not exist ? ')
        AdlibUnRegister(_Adlib_Ping_Wrapper)
    EndIf
    If StringRegExp($sOutput, '(?is)(\R)', $STR_REGEXPMATCH) Then
        If TimerDiff($hTimer) > 5000 Then
            _DebugOut(@HOUR & ':' & @MIN & ':' & @SEC & ' PING RESULT = ' & $sOutput)
            $hTimer = TimerInit()
        EndIf
        $sOutput = ''
    EndIf

EndFunc   ;==>__Adlib_Ping

Func _Adlib_Ping_Exit_Wrapper()
    __Adlib_Ping_Exit()
EndFunc   ;==>_Adlib_Ping_Exit_Wrapper

Func __Adlib_Ping_Exit($vParameter = Default)
    Local Static $vParameter_static = $vParameter
    If Not @Compiled Then ConsoleWrite('- ' & @ScriptLineNumber & ' Parameter=' & $vParameter & ' Static=' & $vParameter_static & @CRLF)
    If $vParameter = Default And IsInt($vParameter_static) Then
        ProcessClose($vParameter_static)
        If Not @Compiled Then ConsoleWrite('! CLOSE PORCESS' & @CRLF)
    ElseIf IsInt($vParameter) Then
        $vParameter_static = $vParameter
    EndIf
EndFunc   ;==>__Adlib_Ping_Exit

Func __DebugClose()
    Local $hWndReportWindow = WinGetHandle($__g_sReportTitle_Debug, $__g_sReportWindowText_Debug)
    GUIDelete($hWndReportWindow)
EndFunc

 

Edited May 26, 2020 by mLipok
Example changed