Jump to content
bailey1274

Object Wrapper for Scripting.Dictionary - WIP (Feedback)

Recommended Posts

I use Python and Autoit about half the time and always wished that AutoIt had an associative array like the dictionary data type. I've found some examples but many were functional based and seemed disconnected to me. I have been using the AutoItObject.au3 by monoceres, trancexx, Kip, and Prog@ndy (big shoutout there, this thing is amazing) and tried to take a stab at wrapping up a dictionary in an object.

Would love any feedback or ideas to make it better, it is pretty rough at this point and could use more work but the idea is there.

#include "AutoitObject.au3"
#include "Array.au3"

Local $my_dict = Dict( _
     'dog', '   woof      ' _
    ,'cat', '   meow' _
    ,'owl', '            hoot     ' _
)

msgbox(0, '', $my_dict.to_string())

$my_dict.map(StringStripWS, 3)

msgbox(0, '', $my_dict.to_string())

$my_dict.map(StringReplace, 'meow', 'purr')

msgbox(0, '', $my_dict.to_string())

; #FUNCTION# ====================================================================================================================
; Name ..........: Dict
; Description ...: Creates a wrapper object for a dictionary
; Parameters ....: $kX-$vX            - Key-Value pairs
; Return values .: Success            - Object containing a dictionary
;                  Failure            - Null
;                  @extended          - N/A
; ===============================================================================================================================
Func Dict( _
        $k1=Default, $v1=Default _
        ,$k2=Default, $v2=Default _
        ,$k3=Default, $v3=Default _
        ,$k4=Default, $v4=Default _
        ,$k5=Default, $v5=Default _
        ,$k6=Default, $v6=Default _
        ,$k7=Default, $v7=Default _
        ,$k8=Default, $v8=Default _
        ,$k9=Default, $v9=Default _
        ,$k10=Default, $v10=Default _
        ,$k11=Default, $v11=Default _
        ,$k12=Default, $v12=Default _
    )

    ; Initialize AutoItObject
    _AutoItObject_StartUp()
    Local $oClassObject = _AutoItObject_Class()
    $oClassObject.Create()

    ; -- Create Length Prop -- ;
    Local $Props = ['len']

    ; -- Create our Dictionary -- ;
    Local $oDict = ObjCreate('Scripting.Dictionary')

    ; -- Add any init key-value pairs -- ;
    Local $iLen = 0
    If $k1 Then 
        $iLen += 1
        $oDict.add($k1,$v1) 
    EndIf
    If $k2 Then 
        $iLen += 1
        $oDict.add($k2,$v2) 
    EndIf
    If $k3 Then 
        $iLen += 1
        $oDict.add($k3,$v3) 
    EndIf
    If $k4 Then 
        $iLen += 1
        $oDict.add($k4,$v4) 
    EndIf
    If $k5 Then 
        $iLen += 1
        $oDict.add($k5,$v5) 
    EndIf
    If $k6 Then 
        $iLen += 1
        $oDict.add($k6,$v6) 
    EndIf
    If $k7 Then 
        $iLen += 1
        $oDict.add($k7,$v7) 
    EndIf
    If $k8 Then 
        $iLen += 1
        $oDict.add($k8,$v8) 
    EndIf
    If $k9 Then 
        $iLen += 1
        $oDict.add($k9,$v9) 
    EndIf
    If $k10 Then 
        $iLen += 1
        $oDict.add($k10,$v10) 
    EndIf
    If $k11 Then 
        $iLen += 1
        $oDict.add($k11,$v11) 
    EndIf
    If $k12 Then 
        $iLen += 1
        $oDict.add($k12,$v12) 
    EndIf

    ; -- Add the length and dictionary to be accessed via methods -- ;
    $oClassObject.AddProperty('len', $ELSCOPE_PUBLIC, $iLen) ; Create Length Property binded to object
    $oClassObject.AddProperty('dict', $ELSCOPE_PUBLIC, $oDict) ; Create actual Dictionary as property to access in methods

    ; -- All methods (all rely on the dictionary prop) -- ;
    $oClassObject.AddMethod("get", "get")
    $oClassObject.AddMethod("set", "set")
    $oClassObject.AddMethod("keys", "keys")
    $oClassObject.AddMethod("values", "values")
    $oClassObject.AddMethod("exists", "exists")
    $oClassObject.AddMethod("to_string", "to_string")
    $oClassObject.AddMethod("clear", "clear")
    $oClassObject.AddMethod("remove", "remove")
    $oClassObject.AddMethod("map", "map")

    ; -- Add destructor -- ;
    $oClassObject.AddDestructor("Dict_Destructor")

    Return $oClassObject.Object

EndFunc

; -- Destorys the Dict upon deletion of object -- ;
Func Dict_Destructor($oSelf)
    ConsoleWrite("Destorying Dict")
    $oSelf.dict.RemoveAll
EndFunc

; -- Sets the value for a given key -- ;
Func set($oSelf, $sKey, $sValue)
    If $oSelf.dict.Exists($sKey) Then 
        $oSelf.remove($sKey)
        $oSelf.dict.add($sKey, $sValue)
    Else
        $oSelf.len += 1
        $oSelf.dict.add($sKey, $sValue)
    EndIf
EndFunc

; -- Gets the value for a key -- ;
Func get($oSelf, $sKey)
    If $oSelf.dict.Exists($sKey) Then
        Return $oSelf.dict.Item($sKey)
    Else
        Return "KEY_ERR"
    EndIf
EndFunc

; -- Removes the Key-Value pair by key -- ;
Func remove($oSelf, $sKey)
    If $oSelf.dict.Exists($sKey) Then
        $oSelf.dict.Remove($sKey)
        Return
    Else
        Return "KEY_ERR"
    EndIf
EndFunc

; -- Returns an array of keys -- ;
Func keys($oSelf)
    Local $aKeys[0]
    For $item in $oSelf.dict.Keys
        _ArrayAdd($aKeys, $item)
    Next
    Return $aKeys
EndFunc

; -- Returns the Array of Values -- ;
Func values($oSelf)
    Local $aVals[0]
    For $item in $oSelf.dict.Items
        _ArrayAdd($aVals, $item)
    Next
    Return $aVals
EndFunc

; -- Returns Bool if keys exists or not -- ;
Func exists($oSelf, $sKey)
    If $oSelf.dict.Exists($sKey) Then
        Return True
    EndIf
    Return False
EndFunc

; -- Returns a json notation string -- ;
Func to_string($oSelf)
    Local $aKeys = $oSelf.keys
    Local $aVals = $oSelf.values
    Local $str = "{"&@CRLF
    For $i=0 to UBound($oSelf.keys)-1
        $str &= @TAB &'"'& $aKeys[$i] &'"'& ', "'& $aVals[$i] &'"'&@CRLF
    Next
    $str &= "}"
    Return $str
EndFunc

; -- Clears the entire dict -- ;
Func clear($oSelf)
    $oSelf.len = 0
    $oSelf.dict.RemoveAll()
EndFunc

; -- Maps given function to the values -- ;
Func map($oSelf, $oFunc, $param1=Default, $param2=Default)
    If $param2 and $param1 Then
        For $key in $oSelf.keys
            $oSelf.set($key, $oFunc($oSelf.get($key), $param1, $param2))
        Next
    ElseIf $param1 Then
        For $key in $oSelf.keys
            $oSelf.set($key, $oFunc($oSelf.get($key), $param1))
        Next
    EndIf
EndFunc

 

Share this post


Link to post
Share on other sites

using Scripting.Dictionary is quite simple and efficient as-is, why bother wrapping it?

if it's the syntax you're uncomfortable with, wrapping it to look like standard AutoIt code is quite simple, already done many times - some 13 years ago... and mentioned in the wiki as well...

what do you expect to benefit from wrapping an object by another object?

Share this post


Link to post
Share on other sites

Also native Map datatype is now stable even if only in beta.


This wonderful site allows debugging and testing regular expressions (many flavors available). An absolute must have in your bookmarks.
Another excellent RegExp tutorial. Don't forget downloading your copy of up-to-date pcretest.exe and pcregrep.exe here
RegExp tutorial: enough to get started
PCRE v8.33 regexp documentation latest available release and currently implemented in AutoIt beta.

SQLitespeed is another feature-rich premier SQLite manager (includes import/export). Well worth a try.
SQLite Expert (freeware Personal Edition or payware Pro version) is a very useful SQLite database manager.
An excellent eBook covering almost every aspect of SQLite3: a must-read for anyone doing serious work.
SQL tutorial (covers "generic" SQL, but most of it applies to SQLite as well)
A work-in-progress SQLite3 tutorial. Don't miss other LxyzTHW pages!
SQLite official website with full documentation (may be newer than the SQLite library that comes standard with AutoIt)

Share this post


Link to post
Share on other sites

Exactly, personally I just wasn't a fan of the syntax the functional approach uses. It feels a bit clunky to me. I think it just comes down to my preference of objects over functional programming. Don't really have any expectations other than readability (and possibly adding things like that map method). If I want to reference a dictionary value inside of another function, calling a function to access it as a parameter just feels off to me. (I think my affinity for python I think pulls me to match syntax when I can)

I unfortunately can't use the beta in my environment or maps would be great. 

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now

  • Recently Browsing   0 members

    No registered users viewing this page.

×
×
  • Create New...