WebDriver UDF - Help & Support (IV)

[Danp2]

@tac7You may want to check out this prior discussion.

 

[tac7]

Thanks a lot,

I can get 'url' and "bodyText" of all tab open by user but I need to do a:

_WD_Window($sSession, 'Switch', '{"handle":"' & $aHandle & '"}')

and this is blinking each tab in my loop:

for $aHandle in $aHandles
....
    $Session_Txt = _WD_ExecuteScript($sSession, 'return document.body.innerText',....
...
next

Before I worked with "ie.au3"  and we could get all we need on all tab without the user seeing anything !!!

My project is to check every 2 seconds a bug (an error message) in all tab open in an applicative web page !!! I managed to correct this before

[mLipok]

Please use wd_demo.au3
There is :

Func UserTesting() ; here you can replace the code to test your stuff before you ask on the forum
    _WD_Navigate($sSession, 'https://www.google.com')
    _WD_LoadWait($sSession, 10, Default, Default, $_WD_READYSTATE_Interactive)

    ConsoleWrite("- Test 1:" & @CRLF)
    _WD_FindElement($sSession, $_WD_LOCATOR_ByXPath, '')

    ConsoleWrite("- Test 2:" & @CRLF)
    _WD_WaitElement($sSession, $_WD_LOCATOR_ByCSSSelector, '#fake', 1000, 3000, $_WD_OPTION_NoMatch)
;~  Exit
EndFunc   ;==>UserTesting

please change to Usertesting() content to make some reproducer to your issue.
Then post it here to let us know what and how exactly you are trying to do.

It will help us to help you.

 

[tac7]

Thanks, here my code:

#Region - UserTesting
Func UserTesting() ; here you can replace the code to test your stuff before you ask on the forum
    _WD_Navigate($sSession, 'https://www.google.com')
    _WD_LoadWait($sSession, 10, Default, Default, $_WD_READYSTATE_Interactive)

    ConsoleWrite("- Test 1:" & @CRLF)
    _WD_FindElement($sSession, $_WD_LOCATOR_ByXPath, '')

    ConsoleWrite("- Test 2:" & @CRLF)
    _WD_WaitElement($sSession, $_WD_LOCATOR_ByCSSSelector, '#fake', 1000, 3000, $_WD_OPTION_NoMatch)

    ConsoleWrite("- Close the Popup Cookie:" & @CRLF)
    $Bouton = _WD_FindElement($sSession, $_WD_LOCATOR_ByXPath, "//button[@id='W0wltc']/div")
    _WD_ElementAction($sSession, $Bouton, 'click')

    ;       At this time, as a user, I manually open a new tab and navigate to "https://www.bing.com"

    While 1
        MsgBox(0, "INFO", "Waiting for Action.......")
        ConsoleWrite("- Get All Tab'Url:" & @CRLF)
        Local $aHandles = _WD_Window($sSession, 'handles')
        for $aHandle in $aHandles
            _WD_Window($sSession, 'Switch', '{"handle":"' & $aHandle & '"}')
            $Current_Url = _WD_Action($sSession, 'url') ; >>>
            ConsoleWrite("+ Url for Handle:" & $aHandle & " :: " & $Current_Url & @CRLF)
            sleep(2000)
        Next
    WEnd
EndFunc   ;==>UserTesting

I want to get all the url'tab => It's Work!   But I don't want all the tab are blinking. Enven without the Sleep, if I have a lot of Tabs opened, User will see the blinking.

Before with 'IE' It was good, it worked in background, User saw nothing

while 1
            $i += 1
            $oIE = _IEAttach("", "instance", $i)
            If @error Then ExitLoop
            $URL = _IEPropertyGet($oIE, "locationurl")
            ......

 

[mLipok]

Thanks @tac7 will take a look ASAP.

 

[seadoggie01]

Getting the user-activated-tab in WebDriver isn't supported through API calls, as far as I could find in my reading. That doesn't mean it's not possible in AutoIt, just that it's not as easy as it was in IE and we'll probably run into a few issues along the way. I've written a couple of functions that seem to allow getting the active tab, however they could be improved and the method could possibly be improved as well. Anyways, here's what I have so far...

expandcollapse popup

#include <wd_core.au3>

Main()

Func Main()

    ; Make this function do all of the setup you need, or replace it here, whatever works for you
    Local $sSession = _WDEx_Setup()

    ; Set the first tab to google (not required, just set the tab to something for testing)
    _WD_Navigate($sSession, "https://www.google.com")
    
    ; While the message box is visible, open any number of new tabs and switch to one of them
    MsgBox(0, "Waiting for new tabs", "Open some tabs, then click OK")

    ; Call the custom function to get the handle of the active tab
    Local $sHandle = _WDEx_GetActiveTab($sSession, Default, True)
    If @error or $sHandle = False Then
        ConsoleWrite("![_WDEx_GetActiveTab] Failed. Error: " & @error & " Extended: " & @extended & @CRLF)
        MsgBox(0, "Nope", "Sorry, I can't help you get the active tab")
    Else
        _WDEx_Window($sSession, "switch", $sHandle)
        MsgBox(0, "Active Tab", "This is the tab you had open previously!")
        ConsoleWrite("Handle: " & $sHandle & @CRLF)
    EndIf

    ; Do your cleanup here
    _WD_DeleteSession($sSession)

EndFunc

; ================ WIP Function ================
; Gets the user activated active tab
; ==============================================
; Returns - handle of user-activated-tab, attempts to keep webdriver-active-tab as the active
; Errors (sets @extended to @error of mentioned function)
; 0 - @extended set to 1, no results found
; 1 - _WDEx_Window failed to get active window
; 2 - WinList failed, check $sWinTitle
; 3 - _WDEx_Window failed to get all handles (tabs)
; 4 - _WDEx_Window failed to switch to a tab
; 5 - _WDEx_ExecuteScriptResult failed to get the tab's title
Func _WDEx_GetActiveTab($sSession, $sWinTitle = Default)

    If IsKeyword($sWinTitle) Then $sWinTitle = "[CLASS:Chrome_WidgetWin_1]"

    ; Get webdriver's currently active window
    Local $sHandle = _WDEx_Window($sSession, "window")
    If @error Then Return SetError(1, @error, False)

    ; Only if it's Chrome/Edge, but substitue as needed...
    Local $aWin = WinList($sWinTitle)
    If @error Then Return SetError(2, @error, False)

    ; Get the list of open tabs
    Local $aHandles = _WDEx_Window($sSession, "handles")
    If @error Then Return SetError(3, @error, False)

    Local $sTitle, $iFound
    For $i=1 To UBound($aHandles) - 1
        ; Switch to the tab
        _WDEx_Window($sSession, "switch", $aHandles[$i])
        If @error Then Return SetError(4, @error, False)

        ; Get the title of the tab
        $sTitle = _WDEx_ExecuteScriptResult($sSession, "return document.title")
        If @error Then Return SetError(5, @error, False)

        ; Use a regular expression search (document.title doesn't return the browser's name, like the window does)
        $iFound = _ArraySearch($aWin, "\Q" & $sTitle & "\E.*", 0, 0, 0, 3)
        If Not ($iFound = -1) Then ExitLoop
    Next

    ; Switch back to the old (last used in webdriver) tab 
    _WDEx_Window($sSession, "switch", $sHandle)

    If $iFound = -1 Then Return SetExtended(1, False)

    ; Return the handle of the matching tab
    return $aHandles[$iFound]

EndFunc
; ================ WIP Function ================
; Checks if a tab is currently active. WARNING: returns false if browser window is not active!
; ==============================================
Func _WD_TabIsActive($sSession)

    return _WDEx_ExecuteScriptResult($sSession, "return document.visibilityState") = "visible"

EndFunc

; ================ WIP Function ================
; Runs a basic script and parses the return value... use _WD_ExecuteScript($sSession, $sJavascript, Default, Default, "[value]") instead
; ==============================================
Func _WDEx_ExecuteScriptResult($sSession, $sJavascript)
    return _WD_ExecuteScript($sSession, $sJavascript, Default, Default, "[value]")
    ; Local $vRet = _WD_ExecuteScript($sSession, $sJavascript)
    ; Local $oJson = Json_Decode($vRet)
    ; return Json_Get($oJson, "[value]")
EndFunc

; #FUNCTION# ====================================================================================================================
; Name ..........: _WDEx_Window
; Description ...: Wrapper for _WD_Window, wraps window functionality inside the required {"handle": <window>} format
; Syntax ........: _WDEx_Window($sSession, $sCommand[, $sOption = Default])
; Parameters ....: $sSession            - a string value.
;                  $sCommand            - a string value.
;                  $sOption             - [optional] a string value. Default is Default.
; Return values .: See: _WD_Window
; Author ........: Seadoggie01
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _WDEx_Window($sSession, $sCommand, $sOption = Default)

    If IsKeyword($sOption) Then $sOption = ""
    $sCommand = StringLower($sCommand)

    Switch $sCommand
        Case "switch", "window"
            ; Cause nobody wants to type this *ahem* stuff *ahem* out
            If $sOption <> "" Then $sOption = '{"handle":"' & $sOption & '"}'
    EndSwitch

    Local $vRet = _WD_Window($sSession, $sCommand, $sOption)
    Return SetError(@error, @extended, $vRet)

EndFunc

It's possible that checking the results of WinList before & after changing the currently active tab could help confirm that we have the correct window, but this worked in my test case and will likely work as long as you don't have two windows (one webdriver and one non-webdriver) with the same title open at the same time. Maybe we could set the title of the tab to some random string to identify the correct window, then use that to find the correct window with Win* functions, but again, this worked well enough for now

Edited February 20, 2023 by seadoggie01
_WD_ExecuteScript has a feature to retrieve [value]

[mLipok]

Today I hit another problem

My script just click some button element and then I just use 

Local $i_Result = _WD_LoadWait($WD_SESSION, $iDelay, $iTimeout, $sElement)

Here is my log.

Quote

1676639352370   webdriver::server       DEBUG   -> POST /session/a3164194-032d-4a2c-90cd-912108cf0ac6/execute/sync {"script":"arguments[0].click();return true;", "args":[{"element-6066-11e4-a52e-4f735466cecf":"41932b48-5ef7-48eb-b34e-0750e90a3f55"}]}
1676639352381   webdriver::server       DEBUG   <- 200 OK {"value":true}
1676639352893   webdriver::server       DEBUG   -> POST /session/a3164194-032d-4a2c-90cd-912108cf0ac6/execute/sync {"script":"return document.readyState", "args":[]}
1676639352944   webdriver::server       DEBUG   <- 200 OK {"value":null}
1676639352966   webdriver::server       DEBUG   -> POST /session/a3164194-032d-4a2c-90cd-912108cf0ac6/execute/sync {"script":"return document.readyState", "args":[]}
1676639352967   webdriver::server       DEBUG   <- 404 Not Found {"value":{"error":"no such window","message":"Browsing context has been discarded","stacktrace":"RemoteError ... ontent/marionette/server.sys.mjs:250:9\n_onJSONObjectReady/<@chrome://remote/content/marionette/transport.sys.mjs:496:20\n"}}

Question:
Why I hit the "Browsing context has been discarded" issue ?
Any concept how to solve this issue ?

 

[seadoggie01]

Was it because it was a background tab and it was discarded? (even top level tabs can be discarded if they haven't been used for a while) Tab Discarding in Chrome - A Memory-Saving Experiment - Chrome Developers (old article, but explains it well) There might be a setting you can use to disable the discarding if so. Personally, I've found it's easier to refresh at least every 5 minutes to avoid it and avoid logging out anyways

[mLipok]

My script routine is
OpenBrowser.. Navigate ... filup LoginForm..... Click LoginButton ... 

and just after click into the LoginButton I use 

Local $i_Result = _WD_LoadWait($WD_SESSION, $iDelay, $iTimeout, $sElement)

So there is no way to have 5 minutes inactivities.

[mLipok]

btw. you can also notice that in my log cleary says that the first readystate was performed well and only second attempt was wrong.

Quote

1676639352381   webdriver::server       DEBUG   <- 200 OK {"value":true}
1676639352893   webdriver::server       DEBUG   -> POST /session/a3164194-032d-4a2c-90cd-912108cf0ac6/execute/sync {"script":"return document.readyState", "args":[]}
1676639352944   webdriver::server       DEBUG   <- 200 OK {"value":null}
1676639352966   webdriver::server       DEBUG   -> POST /session/a3164194-032d-4a2c-90cd-912108cf0ac6/execute/sync {"script":"return document.readyState", "args":[]}
1676639352967   webdriver::server       DEBUG   <- 404 Not Found {"value":{"error":"no such window","message":"Browsing context has been discarded","stacktrace":"RemoteError ...

 

[seadoggie01]

Right, but I have no way to confirm how long was between those requests, I can just see your logs  That's interesting, I haven't seen a discarded window outside of that context before

[mLipok]

I just did some workaround:

Local $i_Result = _WD_LoadWait($WD_SESSION, $iDelay, $iTimeout, $sElement)
    If StringInStr($_WD_HTTPRESPONSE, 'Browsing context has been discarded') Then
        __WD_Sleep(2000)
        _WD_CheckContext($WD_SESSION, Default)
        $i_Result = _WD_LoadWait($WD_SESSION, $iDelay, $iTimeout, $sElement)
    EndIf

 

EDIT: THIS FOLLOWING PART IS NOT NEEDED

Spoiler

but I had to modify: _WD_ExecuteScript() by adding "$_WD_HTTPRESPONSE = $sResponse" after __WD_Post()

$sResponse = __WD_Post($_WD_BASE_URL & ":" & $_WD_PORT & "/session/" & $sSession & "/execute/" & $sCmd, $sData)
        Local $iErr = @error
        $_WD_HTTPRESPONSE = $sResponse

 

 

Edited February 17, 2023 by mLipok

[mLipok]

My final workaround that starts works properly is:

Local $CURRENT_TAB = _WD_Window($WD_SESSION, 'WINDOW')
Local $i_Result = _WD_LoadWait($WD_SESSION, $iDelay, $iTimeout, $sElement)
If StringInStr($_WD_HTTPRESPONSE, 'Browsing context has been discarded') Then
    For $i = 1 To 10
        __WD_Sleep($i * $iDelay)
        _WD_Refresh($WD_SESSION, @ScriptLineNumber)
        _WD_CheckContext($WD_SESSION, Default, $CURRENT_TAB)
        $i_Result = _WD_LoadWait($WD_SESSION, $iDelay, $iTimeout, $sElement)
        If StringInStr($_WD_HTTPRESPONSE, 'Browsing context has been discarded') = 0 Then ExitLoop
    Next
EndIf

 

Edited February 17, 2023 by mLipok

[Danp2]

Hi @seadoggie01,

I haven't yet gone through all the code you posted, but I did want to share a few comments with you --

Quote

; ================ WIP Function ================
; Runs a basic script and parses the return value
; ==============================================
Func _WDEx_ExecuteScriptResult($sSession, $sJavascript)
    Local $vRet = _WD_ExecuteScript($sSession, $sJavascript)
    Local $oJson = Json_Decode($vRet)
    return Json_Get($oJson, "[value]")
EndFunc

This functionality already exists in _WD_ExecuteScript. Please take a look at the optional $vSubNode parameter. To locate some instances where this functionality is already in use, search for "Default, $_WD_JSON_Value".

Quote

; ================ WIP Function ================
; Checks if a tab is currently active. WARNING: returns false if browser window is not active!
; ==============================================
Func _WD_TabIsActive($sSession)

    return _WDEx_ExecuteScriptResult($sSession, "return document.visibilityState") = "visible"

EndFunc

I was initially going to comment that your closing parentheses appears to be misplaced and you should use === when comparing Javascript strrings, but now I see that you are performing the comparison in AutoIt.

Is there an advantage with checking  "document.visibilityState" over "document.hidden"?

[Danp2]

11 hours ago, mLipok said:

Why I hit the "Browsing context has been discarded" issue ?

I'd like to take a closer look at this. Can you share some code that we can execute in the wd_demo / Usertesting function?

[mLipok]

1 hour ago, Danp2 said:

I'd like to take a closer look at this. Can you share some code that we can execute in the wd_demo / Usertesting function?

Danp2 only when we meet again.

But maybe... it be possible without logging.

Must to check.

Edited February 18, 2023 by mLipok

[Danp2]

On 2/17/2023 at 7:34 AM, mLipok said:

Question: Why I hit the "Browsing context has been discarded" issue ? Any concept how to solve this issue ?

I can only guess at the cause due to the limited information provided. I suspect that the current tab is being closed and a new tab opened when the button is clicked.

FWIW, _WD_LoadWait could be updated to detect the discarded browsing context.

[mLipok]

I just did many tests on my home laptop.
I was able to repclicate this issue by about 3 hours.

But then I change something in my config which has an effect that fix the issue and now I can't replicate it on my laptop.
I think I will be still able to replicate it when I back to my office, or on one of my clients computer.

For this moment I think that this issue is somehow realated to FireFox profile which we use for few programs.
This profile is created on disc by each of my program but all my programs uses the same profile.

Normally using FireFox by normal standard user he is using another profile.

When I back to my office then in first place I plan to ZIP FireFox profile which we use.
And then I start testing again with a script that I had to develope as repro code for @Danp2

 

[seadoggie01]

Thank you for the note about _WD_ExecuteScript, that's nice! I'll edit my code above to use that/point it out

Hidden and visibilityState seem to report the same things. I was using visibilityState because I saw it elsewhere (a StackOverflow answer, perhaps?)

[mLipok]

On 2/18/2023 at 4:21 PM, Danp2 said:

I can only guess at the cause due to the limited information provided. I suspect that the current tab is being closed and a new tab opened when the button is clicked.

FWIW, _WD_LoadWait could be updated to detect the discarded browsing context.

@Danp2 thank you that you look at my repro code that I post you via PM.

I think the answer i usefully to entire community members which are interested in WebDriver automation, so Let me quote your statement:

On 2/20/2023 at 9:33 PM, Danp2 said:

I was able to replicate the issue by making the following change --

;    _WD_LoadWait($_IMSIG__WD_SESSION)
    _WD_LoadWait($_IMSIG__WD_SESSION, 1000)
    ConsoleWrite("! END OF TESTING" & @CRLF)

This now makes sense to me as I can see that --

• you had entered a frame to perform the login,
• you submitted the form by clicking the submit button, and finally
• the frame was removed prior to or during the _WD_LoadWait

which lead to the error message that you received. I have already started to add some code to return a unique error code when this scenario occurs, but I haven't yet decided how to update _WD_LoadWait.

Also, the error no longer occurs if you call _WD_FrameLeave prior to _WD_LoadWait.

and my answer is:

Yes this is it.

as to your:
https://github.com/Danp2/au3WebDriver/pull/418

I test it and it works fine - I mean it catches this error properly.