Multiple OAuth 2.0 autorization with TCP on localhost

[maniootek]

I want to get access code for some REST API website (www.allegro.pl) which use OAuth 2.0 protocol. I have code which works fine. After code execution, new tab in my default browser is open with the webpage where I enter login and password and then script read the access code using TCP build in functions in AutoIt.

Everything works good but when I try to use my function in loop for multiple accounts then it works only for the first time, the other time TCPRecv() return empty string. I am not familiar with TCP stuff. Maybe there is some more experienced user here who can help me to figure this out?

expandcollapse popup

#include <MsgBoxConstants.au3>
#include <WinAPIError.au3>
#include <Array.au3>


Global $g_ALLEGRO_CLIENT_ID = "123456789" ; not real data
Global $g_URL_REDIRECTION = "http://localhost:80"
GLobal $g_URL = "https://allegro.pl/auth/oauth/authorize?response_type=code&client_id=" & $g_ALLEGRO_CLIENT_ID & "&redirect_uri=" & $g_URL_REDIRECTION
Global $g_IP = "127.0.0.1"
Global $g_PORT = 80
Global $g_aAccessCodes[0]

For $i=0 to 12
    $access_code = Oauth($g_URL, $g_IP, $g_PORT)
    _ArrayAdd($g_aAccessCodes, $access_code)
Next

_ArrayDisplay($g_aAccessCodes)

Func OAuth($url, $ip, $port)
    TCPStartup() ; Start the TCP service.

    ; Register OnAutoItExit to be called when the script is closed.
    OnAutoItExitRegister("OnAutoItExit")

    ; Assign a Local variable the Listening socket and bind to the IP Address and Port specified with a maximum of 100 pending connexions.
    Local $MainSocketIdentifier = TCPListen($ip, $port, 100)
    if @error then Exit MsgBox($MB_ICONERROR, Default, "TCPListen() error. Could not listen, Error code: " & @error & @CRLF & @CRLF & _WinAPI_GetErrorMessage(@error))

    ShellExecute($url)

    Local $hTimer = TimerInit()
    Local $bErrorTimeout = False
    Local $ConnectedSocketIdentifier
    Do ; Wait for someone to connect (Unlimited).
        ; Accept incomming connexions if present (Socket to close when finished; one socket per client).
        $ConnectedSocketIdentifier = TCPAccept($MainSocketIdentifier)
        If @error Then Exit MsgBox($MB_ICONERROR, Default, "Could not accept the incoming connection, Error code: " & @error & @CRLF & @CRLF & _WinAPI_GetErrorMessage(@error))
        If TimerDiff($hTimer) > (1000 * 10) Then
            $bErrorTimeout = True
            ExitLoop
        EndIf
        Sleep(100)
    Until $ConnectedSocketIdentifier <> -1
    If $bErrorTimeout Then Exit MsgBox($MB_ICONERROR, Default, "TCPAccept() timeout")

    ; Close the Listening socket to allow afterward binds.
    TCPCloseSocket($MainSocketIdentifier)

    ; Assign a Local variable the data received.
    Local $sReceived = TCPRecv($ConnectedSocketIdentifier, 1024)
    $sReceived = BinaryToString($sReceived, 4)
    ConsoleWrite("$sReceived: " & $sReceived & @CRLF)

    Local $aReg = StringRegExp($sReceived, "(?m)(?s)\?code=(.*) HTTP", 3)
    Local $sAuthorizationCode = ""
    If IsArray($aReg) Then $sAuthorizationCode = $aReg[0]
    ConsoleWrite("$sAuthorizationCode: [" & $sAuthorizationCode & "]" & @CRLF)

    TCPSend($ConnectedSocketIdentifier, "The authentication flow has completed. You may close this window.")
    If $ConnectedSocketIdentifier <> -1 Then
        TCPCloseSocket($ConnectedSocketIdentifier)
        TCPShutdown()
    EndIf

    Local $sCode = $sAuthorizationCode
    if $sCode = "" then Exit MsgBox($MB_ICONERROR, Default, "Unable To Get Access Code")
    ConsoleWrite("Access Code: " & $sCode & @CRLF)
    Return $sCode
EndFunc

Func OnAutoItExit()
    TCPShutdown() ; Close the TCP service.
EndFunc   ;==>OnAutoItExit

Edited March 14 by maniootek

[Jos]

Removed duplicate 

[mLipok]

9 hours ago, maniootek said:

Everything works good but when I try to use my function in loop for multiple accounts then it works only for the first time, the other time TCPRecv() return empty string.

Q1: Multpile times per each account ?
Q2: How you loop them ?
Q3: Do you close connection each time ?
Q4: Do you store connection handle for each account separately ?
Q5: Did you try winhttp.au3 ?
 

[maniootek]

9 minutes ago, mLipok said:

Q1: Multpile times per each account ?
Q2: How you loop them ?
Q3: Do you close connection each time ?
Q4: Do you store connection handle for each account separately ?
Q5: Did you try winhttp.au3 ?
 

Q1. I have 12 accounts and I want to get API access code for each of them using OAuth protocol
Q2. I use my OAuth() function in loop and I store API access codes in array $g_aAccessCodes
Q3. Yes I use TCPCloseSocket() and TCPShutdown() but it looks like TCPShutdown() does not reset TCP session I made
Q4. There is no such a thing as connection handle, there is sockets which I close
Q5. I didn't try winhttp.au3. As I said, I am not familiar with http/web stuff. The code I posted was oryginally wrote by @Danyfirex long time ago

[maniootek]

Maybe there is more simple way to get what I want.

Let me explain what I need to do:

1. Go to the webpage with special url
this I can do using code ShellExecute($url) which open new tab with that url in my default browser like Google Chrome

2. On that webpage there is a form to log in with username and password.
This must be done manually by user and we wait for it

3. After user logged in, webpage redirect to new address in localhost (could be specified some web server too but I want to do it locally on user computer) with special code in address bar which I need to read, but I don't know how?

Maybe there is easier way? I can do it easily with IE.au3 with code:
 

EPropertyGet($oIE, "locationurl")

but it's not supported anymore on my users computer.
 

[maniootek]

I also noticed that when I close all sockets with TCPCloseSocket() function and close TCP session with TCPShutdown() function then when I run this command:

Quote

netstat -ano | find "127.0.0.1:80"

with my cmd.exe as admin then I still got this entry with TIME_WAIT state for like 1 minute:

Quote

  TCP    127.0.0.1:80           127.0.0.1:59566        TIME_WAIT       0

Like session is still open or something. It's not closed fully yet. Maybe this is the problem?

[maniootek]

OK I think I solved the problem. I just have to wait few seconds after TCPShutdown() function is called
All entries in netstat with SYN_SENT state must gone before I use TCPStartup() function again

[mLipok]

Still I think you can do it better with winhttp.au3

EDIT:
For example you should be able to handle connection to each account and just switch between them without a need to start/stop new connection for each loop iteration.

Edited March 14 by mLipok