_GUICtrlListView_InsertGroup - a question about $iIndex and $iGroupID paramater

[mLipok]

I try to use _GUICtrlListView_InsertGroup() funcion.

The help file and example are not clear to me - I just don't understand them (in this small part of course).

According to helpfile:

Quote

$iIndex

Index where the group is to be added. If this is -1, the group is added at the end of the list.

 

But in the examples it is not added "at the end of the ListView"

So what kind of list it is ?

I even tried to play with the example and change:

_GUICtrlListView_InsertGroup($hListView, -1, 1, "Group 1")
    _GUICtrlListView_InsertGroup($hListView, -1, 2, "Group 2")

to

_GUICtrlListView_InsertGroup($hListView, 2, 1, "Group 1")
    _GUICtrlListView_InsertGroup($hListView, 3, 2, "Group 2")

and nothing new happend - no change at all.

What exactly $iIndex do?

Edited December 29, 2025 by mLipok

[pixelsearch]

Hello. Please try this in the example file. Instead of...

_GUICtrlListView_InsertGroup($idListview, -1, 1, "Group 1")
_GUICtrlListView_InsertGroup($idListview, -1, 2, "Group 2")

...we can try this :

_GUICtrlListView_InsertGroup($idListview, -1, 1, "Group 1")
_GUICtrlListView_InsertGroup($idListview, 0, 2, "Group 2")

Does group 2 display before group 1?

[pixelsearch]

The help file example, with an additional item and additional group, allows to better test the -1 value, changing it to 0 or 1 and see exactly where the group is inserted.

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>

Example()

Func Example()
    GUICreate("ListView Insert Group (v" & @AutoItVersion & ")", 400, 300)
    Local $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    ; Enable extended control styles
    _GUICtrlListView_SetExtendedListViewStyle($idListview, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
    GUISetState(@SW_SHOW)

    ; Set ANSI format
;~     _GUICtrlListView_SetUnicodeFormat($idListview, False)

    ; Load images
    Local $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($idListview, $hImage, 1)

    ; Add columns
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 2", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 3", 100)

    ; Add items
    _GUICtrlListView_AddItem($idListview, "Row 0: Col 0", 0)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 0: Col 1", 1, 1)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 0: Col 2", 2, 2)
    _GUICtrlListView_AddItem($idListview, "Row 1: Col 0", 1)
    _GUICtrlListView_AddSubItem($idListview, 1, "Row 1: Col 1", 1, 2)
    _GUICtrlListView_AddItem($idListview, "Row 2: Col 0", 2)
    _GUICtrlListView_AddItem($idListview, "Row 3: Col 0")

    ; Build groups
    _GUICtrlListView_EnableGroupView($idListview)
    _GUICtrlListView_InsertGroup($idListview, -1, 0, "Group 0")
    _GUICtrlListView_InsertGroup($idListview, -1, 1, "Group 1")
    _GUICtrlListView_InsertGroup($idListview, -1, 2, "Group 2")
    _GUICtrlListView_SetItemGroupID($idListview, 0, 0)
    _GUICtrlListView_SetItemGroupID($idListview, 1, 1)
    _GUICtrlListView_SetItemGroupID($idListview, 2, 2)
    _GUICtrlListView_SetItemGroupID($idListview, 3, 2)

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

 

1 hour ago, mLipok said:

What exactly $iIndex do?

It indicates the place where a group will be displayed, relatively to the other groups.
Its value starts with 0, to display the group before any others, 1 to have it displayed just after the 1st group etc... or -1 to display it after all other groups.

Hope it helps

[mLipok]

I start to wonder also what $iGroupID parameter is.
Also why in some cases $iGroupID =0 is wrong choices as I hit some issues with using @Nine awesome code :

Here is my repro for the issue :

expandcollapse popup

#include <Color.au3>
#include <GUIConstants.au3>
#include <GuiListView.au3>

Global $b_TEST = False
Example()

Func Example()
    GUICreate("Example")
    Local $idListview = GUICtrlCreateListView("", 10, 10, 350, 200)
    GUISetState()

    GUIRegisterMsg($WM_NOTIFY, WM_NOTIFY)

    _GUICtrlListView_AddColumn($idListview, "Column 0", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)

    _GUICtrlListView_AddItem($idListview, "Row 0: Col 0", 0)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 0: Col 1", 1)
    _GUICtrlListView_AddItem($idListview, "Row 1: Col 0", 1)
    _GUICtrlListView_AddSubItem($idListview, 1, "Row 1: Col 1", 1)
    _GUICtrlListView_AddItem($idListview, "Row 2: Col 0", 2)

    _GUICtrlListView_EnableGroupView($idListview)

    $b_TEST = False
    _GUICtrlListView_InsertGroup($idListview, -1, 0, "$iGroupID=0")
    _GUICtrlListView_InsertGroup($idListview, -1, 1, "$iGroupID=1")
    _GUICtrlListView_InsertGroup($idListview, -1, 2, "$iGroupID=2")
    _GUICtrlListView_SetItemGroupID($idListview, 0, 0)
    _GUICtrlListView_SetItemGroupID($idListview, 1, 1)
    _GUICtrlListView_SetItemGroupID($idListview, 2, 2)

    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, 'CASE 1 : ' & $b_TEST)

    _GUICtrlListView_RemoveAllGroups($idListview)
    $b_TEST = True
    _GUICtrlListView_InsertGroup($idListview, -1, 0, "$iGroupID=0")
    _GUICtrlListView_InsertGroup($idListview, -1, 1, "$iGroupID=1")
    _GUICtrlListView_InsertGroup($idListview, -1, 2, "$iGroupID=2")
    _GUICtrlListView_SetItemGroupID($idListview, 0, 0)
    _GUICtrlListView_SetItemGroupID($idListview, 1, 1)
    _GUICtrlListView_SetItemGroupID($idListview, 2, 2)

    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, 'CASE 2 : ' & $b_TEST)

    _GUICtrlListView_RemoveAllGroups($idListview)
    $b_TEST = True
    _GUICtrlListView_InsertGroup($idListview, -1, 1, "$iGroupID=0")
    _GUICtrlListView_InsertGroup($idListview, -1, 2, "$iGroupID=1")
    _GUICtrlListView_InsertGroup($idListview, -1, 3, "$iGroupID=2")
    _GUICtrlListView_SetItemGroupID($idListview, 0, 1)
    _GUICtrlListView_SetItemGroupID($idListview, 1, 2)
    _GUICtrlListView_SetItemGroupID($idListview, 2, 3)

    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, 'CASE 3 : ' & $b_TEST)

EndFunc   ;==>Example

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam

    Local $tItem = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
    Local $iItem = $tItem.dwItemSpec - 1 ; Item index

    If $b_TEST And $iItem >= 0 And _WinAPI_GetClassName($tItem.hWndFrom) = "SysListView32" And $tItem.Code = $NM_CUSTOMDRAW And $tItem.dwItemType = $LVCDI_GROUP And $tItem.dwDrawStage = $CDDS_PREPAINT Then
        ConsoleWrite($iItem & @CRLF)
        Local $aGroup = _GUICtrlListView_GetGroupInfoByIndex($tItem.hWndFrom, $iItem)
        _WinAPI_SetBkColor($tItem.HDC, _WinAPI_SwitchColor(0xAAAAA0))
        _WinAPI_SetBkMode($tItem.HDC, $OPAQUE)
        _WinAPI_SetTextColor($tItem.HDC, _WinAPI_SwitchColor(0xAA0000))
        Local $tRect = DllStructCreate($tagRECT, DllStructGetPtr($tItem, "left"))
        _WinAPI_DrawText($tItem.HDC, $aGroup[0], $tRect, $DT_LEFT)
        Return $CDRF_SKIPDEFAULT
    EndIf
EndFunc   ;==>WM_NOTIFY

 

And the question is:

Why "CASE 2" doesn't show the group header "$iGroupID=2" ?

 

Edited Monday at 01:53 AM by mLipok
"CASE 2" is issue not "CASE 3" + rewording question

[pixelsearch]

I tried another function, which seems to give better results. Instead of...

Local $aGroup = _GUICtrlListView_GetGroupInfoByIndex($tItem.hWndFrom, $iItem)

..the following one seems ok, at least I got all colored headers displayed in all your tests :

Local $aGroup = _GUICtrlListView_GetGroupInfo($tItem.hWndFrom, $iItem)

After this change, if the header text isn't accurate, try the following and compare :

; Local $iItem = $tItem.dwItemSpec - 1 ; Item index
Local $iItem = $tItem.dwItemSpec ; Item index

Finally, even with both changes, on my computer (and old OS), CASE #3 doesn't show correct text headers.
Changing the groups id's from "1, 2, 3" to "0, 1, 2" in Case #3 seems to work fine.
Or just indicate group id's which doesn't mix with indexes, for example "100, 110, 120" for group id's and keep "-1, -1, -1" for indexes (for the record, indexes "-1, -1, -1" is equivalent to "0, 1, 2") as indexes are 0-based (tested)

Good luck

Edited Monday at 08:42 AM by pixelsearch
rephrased the beginning of the post

[pixelsearch]

I confirm this : in your case, $tItem.dwItemSpec is not a listview item number. It is a group id
We can see it with this code in Case #3 :

_GUICtrlListView_InsertGroup($idListview, -1, 100, "$iGroupID=0")
_GUICtrlListView_InsertGroup($idListview, -1, 110, "$iGroupID=1")
_GUICtrlListView_InsertGroup($idListview, -1, 120, "$iGroupID=2")
_GUICtrlListView_SetItemGroupID($idListview, 0, 100)
_GUICtrlListView_SetItemGroupID($idListview, 1, 110)
_GUICtrlListView_SetItemGroupID($idListview, 2, 120)

then your ConsoleWrite shows this :
 

Local $iItem = $tItem.dwItemSpec ; Item index (no)
...
ConsoleWrite($iItem & @CRLF)
100
110
120

 

[MattyD]

Edit: Apologies, disregard... I originally posted some nonsense, fixed it, then found its already been posted by pixelsearch.
 

Spoiler

3 hours ago, pixelsearch said:

Local $aGroup = _GUICtrlListView_GetGroupInfo($tItem.hWndFrom, $iItem)

Yep, this looks to be correct.. 

Then this seems to help 

Local $iIndex = $tItem.dwItemSpec
;Not: Local $iIndex = $tItem.dwItemSpec - 1

 

expandcollapse popup

#include <Color.au3>
#include <GUIConstants.au3>
#include <GuiListView.au3>

Global $b_TEST = False
Example()

Func Example()
    GUICreate("Example")
    Local $idListview = GUICtrlCreateListView("", 10, 10, 350, 200)
    GUISetState()

    GUIRegisterMsg($WM_NOTIFY, WM_NOTIFY)

    _GUICtrlListView_AddColumn($idListview, "Column 0", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)

    _GUICtrlListView_AddItem($idListview, "Row 0: Col 0", 0)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 0: Col 1", 1)
    _GUICtrlListView_AddItem($idListview, "Row 1: Col 0", 1)
    _GUICtrlListView_AddSubItem($idListview, 1, "Row 1: Col 1", 1)
    _GUICtrlListView_AddItem($idListview, "Row 2: Col 0", 2)

    _GUICtrlListView_EnableGroupView($idListview)

    $b_TEST = False
    _GUICtrlListView_InsertGroup($idListview, -1, 0, "$iGroupID=0")
    _GUICtrlListView_InsertGroup($idListview, -1, 1, "$iGroupID=1")
    _GUICtrlListView_InsertGroup($idListview, -1, 2, "$iGroupID=2")
    _GUICtrlListView_SetItemGroupID($idListview, 0, 0)
    _GUICtrlListView_SetItemGroupID($idListview, 1, 1)
    _GUICtrlListView_SetItemGroupID($idListview, 2, 2)

    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, 'CASE 1 : ' & $b_TEST)

    _GUICtrlListView_RemoveAllGroups($idListview)
    $b_TEST = True
    _GUICtrlListView_InsertGroup($idListview, -1, 0, "$iGroupID=0")
    _GUICtrlListView_InsertGroup($idListview, -1, 1, "$iGroupID=1")
    _GUICtrlListView_InsertGroup($idListview, -1, 2, "$iGroupID=2")
    _GUICtrlListView_SetItemGroupID($idListview, 0, 0)
    _GUICtrlListView_SetItemGroupID($idListview, 1, 1)
    _GUICtrlListView_SetItemGroupID($idListview, 2, 2)

    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, 'CASE 2 : ' & $b_TEST)

    _GUICtrlListView_RemoveAllGroups($idListview)
    $b_TEST = True
    _GUICtrlListView_InsertGroup($idListview, -1, 1, "$iGroupID=0")
    _GUICtrlListView_InsertGroup($idListview, -1, 2, "$iGroupID=1")
    _GUICtrlListView_InsertGroup($idListview, -1, 3, "$iGroupID=2")
    _GUICtrlListView_SetItemGroupID($idListview, 0, 1)
    _GUICtrlListView_SetItemGroupID($idListview, 1, 2)
    _GUICtrlListView_SetItemGroupID($idListview, 2, 3)

    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, 'CASE 3 : ' & $b_TEST)

EndFunc   ;==>Example

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam

    Local $tItem = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
    Local $iItem = $tItem.dwItemSpec; Item index

    If $b_TEST And _WinAPI_GetClassName($tItem.hWndFrom) = "SysListView32" And $tItem.Code = $NM_CUSTOMDRAW And $tItem.dwItemType = $LVCDI_GROUP And BitAND($tItem.dwDrawStage, $CDDS_PREPAINT) Then
        ConsoleWrite($iItem & @CRLF)

        Local $aGroup = _GUICtrlListView_GetGroupInfo($tItem.hWndFrom, $iItem)
        _WinAPI_SetBkColor($tItem.HDC, _WinAPI_SwitchColor(0xAAAAA0))
        _WinAPI_SetBkMode($tItem.HDC, $OPAQUE)
        _WinAPI_SetTextColor($tItem.HDC, _WinAPI_SwitchColor(0xAA0000))
        Local $tRect = DllStructCreate($tagRECT, DllStructGetPtr($tItem, "left"))
        _WinAPI_DrawText($tItem.HDC, $aGroup[0], $tRect, $DT_LEFT)
        Return $CDRF_SKIPDEFAULT
    EndIf
EndFunc   ;==>WM_NOTIFY

 

Edited Monday at 11:45 AM by MattyD

[mLipok]

I just tried _GUICtrlListView_GetItemEx.au3 with little mod:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>
#include <StructureConstants.au3>

Example()

Func Example()
    GUICreate("ListView Get/Set Item Ex (v" & @AutoItVersion & ")S", 400, 300)
    Local $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Set ANSI format
;~     _GUICtrlListView_SetUnicodeFormat($idListview, False)

    ; Add columns
    _GUICtrlListView_AddColumn($idListview, "Items", 100)

    ; Add items
    GUICtrlCreateListViewItem("Item 0", $idListview)
    GUICtrlCreateListViewItem("Item 1", $idListview)
    GUICtrlCreateListViewItem("Item 2", $idListview)

    ; Show item 1 raw state
    Local $tItem = DllStructCreate($tagLVITEM)
    DllStructSetData($tItem, "Mask", $LVIF_STATE)
    DllStructSetData($tItem, "Item", 1)
    DllStructSetData($tItem, "StateMask", -1)
    _GUICtrlListView_GetItemEx($idListview, $tItem)
    MsgBox($MB_SYSTEMMODAL, "Information", "Item 1 GroupID: " & DllStructGetData($tItem, "GroupID"))

    ; Change item 1
    MsgBox($MB_SYSTEMMODAL, "Information", "Changing item 1")
    Local $tText
    If _GUICtrlListView_GetUnicodeFormat($idListview) Then
        $tText = DllStructCreate("wchar Text[11]")
    Else
        $tText = DllStructCreate("char Text[11]")
    EndIf
    $tItem = DllStructCreate($tagLVITEM)
    DllStructSetData($tText, "Text", "New Item 1")
    DllStructSetData($tItem, "Mask", $LVIF_TEXT)
    DllStructSetData($tItem, "Item", 1)
    DllStructSetData($tItem, "Text", DllStructGetPtr($tText))
    _GUICtrlListView_SetItemEx($idListview, $tItem)

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

 

just changed:

; from
MsgBox($MB_SYSTEMMODAL, "Information", "Item 1 State: " & DllStructGetData($tItem, "State"))
; to
MsgBox($MB_SYSTEMMODAL, "Information", "Item 1 GroupID: " & DllStructGetData($tItem, "GroupID"))

and you know what GroupID if UNSET it is =0
So GroupID is 1-based

btw.

just as a reference

  

20 hours ago, pixelsearch said:

Local $aGroup = _GUICtrlListView_GetGroupInfoByIndex($tItem.hWndFrom, $iItem)

uses:
LVM_GETGROUPINFOBYINDEX

 

 

20 hours ago, pixelsearch said:

Local $aGroup = _GUICtrlListView_GetGroupInfo($tItem.hWndFrom, $iItem)

uses:

LVM_GETGROUPINFO

 

[mLipok]

9 minutes ago, mLipok said:

just changed:

; from
MsgBox($MB_SYSTEMMODAL, "Information", "Item 1 State: " & DllStructGetData($tItem, "State"))
; to
MsgBox($MB_SYSTEMMODAL, "Information", "Item 1 GroupID: " & DllStructGetData($tItem, "GroupID"))

and you know what GroupID if UNSET it is =0
So GroupID is 1-based

oops mistake, there is mask $LVIF_STATE:

DllStructSetData($tItem, "Mask", $LVIF_STATE)
    DllStructSetData($tItem, "Item", 1)
    DllStructSetData($tItem, "StateMask", -1)
    _GUICtrlListView_GetItemEx($idListview, $tItem)
    MsgBox($MB_SYSTEMMODAL, "Information", "Item 1 GroupID: " & DllStructGetData($tItem, "GroupID"))

Thus I get 0 
 

[mLipok]

So far I have this repro for testing:

expandcollapse popup

;~ https://www.autoitscript.com/forum/topic/213384-_guictrllistview_insertgroup-a-question-about-iindex-and-igroupid-paramater/#findComment-1548917

#include <Color.au3>
#include <GUIConstants.au3>
#include <GuiListView.au3>

Global $b_TEST = False
Example()

Func Example()
    GUICreate("Example")
    Local $idListview = GUICtrlCreateListView("", 10, 10, 350, 200)
    GUISetState()

    GUIRegisterMsg($WM_NOTIFY, WM_NOTIFY)

    _GUICtrlListView_AddColumn($idListview, "Column 0", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)

    _GUICtrlListView_AddItem($idListview, "Row 0: Col 0", 0)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 0: Col 1", 1)
    _GUICtrlListView_AddItem($idListview, "Row 1: Col 0", 1)
    _GUICtrlListView_AddSubItem($idListview, 1, "Row 1: Col 1", 1)
    _GUICtrlListView_AddItem($idListview, "Row 2: Col 0", 2)


    _GUICtrlListView_EnableGroupView($idListview)

    $b_TEST = False
    _GUICtrlListView_InsertGroup($idListview, -1, 0, "$iGroupID=0")
    _GUICtrlListView_InsertGroup($idListview, -1, 1, "$iGroupID=1")
    _GUICtrlListView_InsertGroup($idListview, -1, 2, "$iGroupID=2")
    _GUICtrlListView_SetItemGroupID($idListview, 0, 0)
    _GUICtrlListView_SetItemGroupID($idListview, 1, 1)
    _GUICtrlListView_SetItemGroupID($idListview, 2, 2)

    Sleep(100)
    ConsoleWrite(@ScriptLineNumber & ' GroupID of first ROW = ' & _GUICtrlListView_GetItemGroupID($idListview, 0) & @CRLF)
    ConsoleWrite('CASE 1 END' & @CRLF & @CRLF)
    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, 'CASE 1 : ' & $b_TEST)

    _GUICtrlListView_RemoveAllGroups($idListview)
    ConsoleWrite('CASE 2 AFTER REMOVE' & @CRLF)

    $b_TEST = True
    _GUICtrlListView_InsertGroup($idListview, -1, 0, "$iGroupID=0")
    _GUICtrlListView_InsertGroup($idListview, -1, 1, "$iGroupID=1")
    _GUICtrlListView_InsertGroup($idListview, -1, 2, "$iGroupID=2")
    _GUICtrlListView_SetItemGroupID($idListview, 0, 0)
    _GUICtrlListView_SetItemGroupID($idListview, 1, 1)
    _GUICtrlListView_SetItemGroupID($idListview, 2, 2)

    Sleep(100)
    ConsoleWrite(@ScriptLineNumber & ' GroupID of first ROW = ' & _GUICtrlListView_GetItemGroupID($idListview, 0) & @CRLF)
    ConsoleWrite('CASE 2 END' & @CRLF & @CRLF)
    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, 'CASE 2 : ' & $b_TEST)

    _GUICtrlListView_RemoveAllGroups($idListview)
    ConsoleWrite('CASE 3 AFTER REMOVE' & @CRLF)
    $b_TEST = True
    _GUICtrlListView_InsertGroup($idListview, -1, 1, "$iGroupID=0")
    _GUICtrlListView_InsertGroup($idListview, -1, 2, "$iGroupID=1")
    _GUICtrlListView_InsertGroup($idListview, -1, 3, "$iGroupID=2")
    _GUICtrlListView_SetItemGroupID($idListview, 0, 1)
    _GUICtrlListView_SetItemGroupID($idListview, 1, 2)
    _GUICtrlListView_SetItemGroupID($idListview, 2, 3)

    Sleep(100)
    ConsoleWrite(@ScriptLineNumber & ' GroupID of first ROW = ' & _GUICtrlListView_GetItemGroupID($idListview, 0) & @CRLF)
    ConsoleWrite('CASE 3 END' & @CRLF & @CRLF)
    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, 'CASE 3 : ' & $b_TEST)

    _GUICtrlListView_RemoveAllGroups($idListview)
    ConsoleWrite(@ScriptLineNumber & ' GroupID of first ROW = ' & _GUICtrlListView_GetItemGroupID($idListview, 0) & @CRLF)

EndFunc   ;==>Example

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam

    Local $tItem = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
    Local $iItem = $tItem.dwItemSpec - 1 ; Item index

    If $b_TEST And $iItem >= 0 And _WinAPI_GetClassName($tItem.hWndFrom) = "SysListView32" And $tItem.Code = $NM_CUSTOMDRAW And $tItem.dwItemType = $LVCDI_GROUP And $tItem.dwDrawStage = $CDDS_PREPAINT Then
        ConsoleWrite('$iItem = ' & $iItem & @CRLF)
        Local $aGroup = _GUICtrlListView_GetGroupInfoByIndex($tItem.hWndFrom, $iItem)
        _WinAPI_SetBkColor($tItem.HDC, _WinAPI_SwitchColor(0xAAAAA0))
        _WinAPI_SetBkMode($tItem.HDC, $OPAQUE)
        _WinAPI_SetTextColor($tItem.HDC, _WinAPI_SwitchColor(0xAA0000))
        Local $tRect = DllStructCreate($tagRECT, DllStructGetPtr($tItem, "left"))
        _WinAPI_DrawText($tItem.HDC, $aGroup[0], $tRect, $DT_LEFT)
        Return $CDRF_SKIPDEFAULT
    EndIf
EndFunc   ;==>WM_NOTIFY

Will keep diging.

[mLipok]

21 hours ago, pixelsearch said:

I confirm this : in your case, $tItem.dwItemSpec is not a listview item number. It is a group id
We can see it with this code in Case #3 :

Exactly.
And here is finally working script.

expandcollapse popup

;~ https://www.autoitscript.com/forum/topic/213384-_guictrllistview_insertgroup-a-question-about-iindex-and-igroupid-paramater/#findComment-1548917

#include <Color.au3>
#include <GUIConstants.au3>
#include <GuiListView.au3>

Global $b_TEST = False
Example()

Func Example()
    GUICreate("Example")
    Local $idListview = GUICtrlCreateListView("", 10, 10, 350, 200)
    GUISetState()

    GUIRegisterMsg($WM_NOTIFY, WM_NOTIFY)

    _GUICtrlListView_AddColumn($idListview, "Column 0", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)

    _GUICtrlListView_AddItem($idListview, "Row 0: Col 0", 0)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 0: Col 1", 1)
    _GUICtrlListView_AddItem($idListview, "Row 1: Col 0", 1)
    _GUICtrlListView_AddSubItem($idListview, 1, "Row 1: Col 1", 1)
    _GUICtrlListView_AddItem($idListview, "Row 2: Col 0", 2)


    _GUICtrlListView_EnableGroupView($idListview)

    $b_TEST = False
    _GUICtrlListView_InsertGroup($idListview, -1, 0, "$iGroupID=0")
    _GUICtrlListView_InsertGroup($idListview, -1, 1, "$iGroupID=1")
    _GUICtrlListView_InsertGroup($idListview, -1, 2, "$iGroupID=2")
    _GUICtrlListView_SetItemGroupID($idListview, 0, 0)
    _GUICtrlListView_SetItemGroupID($idListview, 1, 1)
    _GUICtrlListView_SetItemGroupID($idListview, 2, 2)

    Sleep(100)
    ConsoleWrite(@ScriptLineNumber & ' GroupID of first ROW = ' & _GUICtrlListView_GetItemGroupID($idListview, 0) & @CRLF)
    ConsoleWrite('CASE 1 END' & @CRLF & @CRLF)
    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, 'CASE 1 : ' & $b_TEST)

    _GUICtrlListView_RemoveAllGroups($idListview)
    ConsoleWrite('CASE 2 AFTER REMOVE' & @CRLF)

    $b_TEST = True
    _GUICtrlListView_InsertGroup($idListview, -1, 0, "$iGroupID=0")
    _GUICtrlListView_InsertGroup($idListview, -1, 1, "$iGroupID=1")
    _GUICtrlListView_InsertGroup($idListview, -1, 2, "$iGroupID=2")
    _GUICtrlListView_SetItemGroupID($idListview, 0, 0)
    _GUICtrlListView_SetItemGroupID($idListview, 1, 1)
    _GUICtrlListView_SetItemGroupID($idListview, 2, 2)

    Sleep(100)
    ConsoleWrite(@ScriptLineNumber & ' GroupID of first ROW = ' & _GUICtrlListView_GetItemGroupID($idListview, 0) & @CRLF)
    ConsoleWrite('CASE 2 END' & @CRLF & @CRLF)
    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, 'CASE 2 : ' & $b_TEST)

    _GUICtrlListView_RemoveAllGroups($idListview)
    ConsoleWrite('CASE 3 AFTER REMOVE' & @CRLF)
    $b_TEST = True
    _GUICtrlListView_InsertGroup($idListview, -1, 1, "$iGroupID=0")
    _GUICtrlListView_InsertGroup($idListview, -1, 2, "$iGroupID=1")
    _GUICtrlListView_InsertGroup($idListview, -1, 3, "$iGroupID=2")
    _GUICtrlListView_SetItemGroupID($idListview, 0, 1)
    _GUICtrlListView_SetItemGroupID($idListview, 1, 2)
    _GUICtrlListView_SetItemGroupID($idListview, 2, 3)

    Sleep(100)
    ConsoleWrite(@ScriptLineNumber & ' GroupID of first ROW = ' & _GUICtrlListView_GetItemGroupID($idListview, 0) & @CRLF)
    ConsoleWrite('CASE 3 END' & @CRLF & @CRLF)
    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, 'CASE 3 : ' & $b_TEST)

    _GUICtrlListView_RemoveAllGroups($idListview)
    ConsoleWrite(@ScriptLineNumber & ' GroupID of first ROW = ' & _GUICtrlListView_GetItemGroupID($idListview, 0) & @CRLF)

EndFunc   ;==>Example

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam

    Local $tItem = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
    Local $iItemSpec = $tItem.dwItemSpec ; Item index for Row element but GroupID for Group element

    If $b_TEST And $iItemSpec >= 0 And _WinAPI_GetClassName($tItem.hWndFrom) = "SysListView32" And $tItem.Code = $NM_CUSTOMDRAW And $tItem.dwItemType = $LVCDI_GROUP And $tItem.dwDrawStage = $CDDS_PREPAINT Then
        ConsoleWrite('$iItemSpec = ' & $iItemSpec & @CRLF)
        Local $aGroup = _GUICtrlListView_GetGroupInfo($tItem.hWndFrom, $iItemSpec)
        _WinAPI_SetBkColor($tItem.HDC, _WinAPI_SwitchColor(0xAAAAA0))
        _WinAPI_SetBkMode($tItem.HDC, $OPAQUE)
        _WinAPI_SetTextColor($tItem.HDC, _WinAPI_SwitchColor(0xAA0000))
        Local $tRect = DllStructCreate($tagRECT, DllStructGetPtr($tItem, "left"))
        _WinAPI_DrawText($tItem.HDC, $aGroup[0], $tRect, $DT_LEFT)
        Return $CDRF_SKIPDEFAULT
    EndIf
EndFunc   ;==>WM_NOTIFY

 

[mLipok]

hm... another question araised in my mind.

We have: _GUICtrlListView_GetGroupInfoByIndex()
which uses $LVM_GETGROUPINFOBYINDEX 

My question is how to get

Quote

 

wParam [in]

The index of the group.

when you have only 
 

Quote

 

iGroupId

Type: int

ID of the group.

 

I mean I need _GUICtrlListView_GetGroupIndexByGroupID()

I know I can enumerate all the groups and then use _GUICtrlListView_GetGroupInfoByIndex() in a loop to determine it.

But do you know any trick to get this via sending messages or any faster way than looping all groups ?

 

Edited yesterday at 11:01 AM by mLipok
typos, wording

[mLipok]

13 minutes ago, mLipok said:

I mean I need _GUICtrlListView_GetGroupIndexByGroupID()

I know I can enumerate all the groups and then use _GUICtrlListView_GetGroupInfoByIndex() in a loop to determine it.

here is example:

Func _GUICtrlListView_GetGroupIndexByGroupID($hWnd, $iGroupID)
    Local $iMaxIndex = _GUICtrlListView_GetGroupCount($hWnd) - 1
    Local $aInfo
    For $i = 0 To $iMaxIndex
        $aInfo = _GUICtrlListView_GetGroupInfoByIndex($hWnd, $i)
        If $aInfo[2] = $iGroupID Then Return $i
    Next

    Return SetError(1, 0, -1)
EndFunc   ;==>_GUICtrlListView_GetGroupIndexByGroupID

and I thinking about adding them to the AutoIt Standard UDF

 

[mLipok]

16 minutes ago, mLipok said:

But do you know any trick to get this via sending messages or any faster way than looping all groups ?

I just used my

Func _GUICtrlListView_GetGroupIndexByGroupID($hWnd, $iGroupID)

in the 

Func MY_WM_NOTIFY($hWnd, $msg, $wParam, $lParam)

    Local $tItem = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
    If $tItem.hWndFrom = $__g_hListView_Dokumenty Then
        If $tItem.dwItemType = $LVCDI_GROUP Then
            Local $iItemSpec = $tItem.dwItemSpec ; ItemIndex for "RowElement", GroupID for "GroupElement"
            If $tItem.Code = $NM_CUSTOMDRAW And $tItem.dwDrawStage = $CDDS_PREPAINT Then
.....
                    Local $iGroupIndex_0based = _GUICtrlListView_GetGroupIndexByGroupID($__g_hListView_Dokumenty, $iItemSpec)
                    _WinAPI_DrawText($tItem.HDC, ($iGroupIndex_0based + 1)  & '. ' & $s_text, $tRect, $DT_LEFT) ;
.....

Awesome Groups renumbering.

I'll make an example, just wait.

[mLipok]

 

11 hours ago, mLipok said:

Awesome Groups renumbering.

I'll make an example, just wait.

Here is it:

expandcollapse popup

#Region ; *** Dynamically added Include files ***
#include <GuiTreeView.au3>                                   ; added:01/15/26 22:15:14
#EndRegion ; *** Dynamically added Include files ***
#include <GUIConstants.au3>
#include <GuiListView.au3>

Global $_hGUI = 0, $_hListView = 00
Example()

Func Example()
    ; create GUI window
    $_hGUI = GUICreate("Example", 500, 800)
    ; create ListView control
    Local $idListview = GUICtrlCreateListView("", 10, 10, 480, 780)
    $_hListView = ControlGetHandle($_hGUI, '', $idListview)

    ; Enable extended control styles
    _GUICtrlListView_SetExtendedListViewStyle($idListview, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
    GUISetState(@SW_SHOW)

    ; Set ANSI format
;~     _GUICtrlListView_SetUnicodeFormat($idListview, False)

    GUIRegisterMsg($WM_NOTIFY, WM_NOTIFY)

    _GUICtrlListView_BeginUpdate($idListview)

    _GUICtrlListView_AddColumn($idListview, "Column 0", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)

    Local $iMAX = 499
    For $i = 0 To $iMAX
        _GUICtrlListView_AddItem($idListview, "Row " & $i & ": Col 0", 0)
        _GUICtrlListView_AddSubItem($idListview, $i, "Row " & $i & ": Col 1", 1)
    Next

    Local $iCount10 = 0, $iGroupID
    For $i = 0 To $iMAX
        If Mod($i, 10) = 0 Then
            $iGroupID = $iCount10 * 10
            $iCount10 += 1
            _GUICtrlListView_InsertGroup($idListview, -1, $iGroupID, 'GroupID=' & $iGroupID & ' for all rows with RowIndex in range <' & $iGroupID & ',' & ($iCount10 * 10) - 1 & '>')
        EndIf
        _GUICtrlListView_SetItemGroupID($idListview, $i, $iGroupID)
    Next

    _GUICtrlListView_EnableGroupView($idListview)

    _GUICtrlListView_EnsureVisible($idListview, 250)
    _GUICtrlListView_EndUpdate($idListview)

    Local $aInfo, $s_GroupHeader

;~  $aInfo = _GUICtrlListView_GetGroupInfo($idListview, 240)
    $aInfo = _GUICtrlListView_GetGroupInfoByIndex($idListview, 24) ; REMARK: 0based ListView Index  24 is $sGroupHumanIndex = "[ #25 ]"
    $s_GroupHeader = $aInfo[0] ; please note that $s_GroupHeader does not contain an index in the displayed form [ #**** ]
    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, 'Focus on $sGroupHumanIndex = "[ #25 ]" ' & @CRLF & 'Is it like following:' & @CRLF & $s_GroupHeader & @CRLF & 'It will be removed !')

    ; removing group for all 24* rows
    _GUICtrlListView_RemoveGroup($idListview, 240)

;~  $aInfo = _GUICtrlListView_GetGroupInfo($idListview, 250)
    $aInfo = _GUICtrlListView_GetGroupInfoByIndex($idListview, 24) ; REMARK: 0based ListView Index  24 is $sGroupHumanIndex = "[ #25 ]"
    $s_GroupHeader = $aInfo[0] ; please note that $s_GroupHeader does not contain an index in the displayed form [ #**** ]
    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, 'Where is $sGroupHumanIndex = "[ #25 ]" GroupID=240 ?' & @CRLF & 'Was it removed ?' & @CRLF & @CRLF & 'What content is in $sGroupHumanIndex = "[ #25 ]" ?' & @CRLF & 'Is it like following:' & @CRLF & $s_GroupHeader)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>Example

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $iMsg, $wParam

    If $hWnd = $_hGUI Then ; check if Our GUI - in case you create multiple GUI - Window
        Local $tItem = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
        If $tItem.dwItemType = $LVCDI_GROUP Then
            If $tItem.hWndFrom = $_hListView Then ; check if our ListView - in case you have few ListView on the same GUI - Window
                Local $iItemSpec = $tItem.dwItemSpec ; ItemIndex for "RowElement", GroupID for "GroupElement"
                If $iItemSpec >= 0 And $tItem.Code = $NM_CUSTOMDRAW And $tItem.dwDrawStage = $CDDS_PREPAINT Then

                    Local $tRect = DllStructCreate($tagRECT, DllStructGetPtr($tItem, "left"))

                    #Region ; create full row background (black) with a leading line (red)
                    $tRect.bottom = $tRect.top + 18
                    Local $hBrush = _WinAPI_CreateSolidBrush(0)
                    _WinAPI_FillRect($tItem.HDC, $tRect, $hBrush)
                    _WinAPI_DeleteObject($hBrush)
                    Local $hPen = _WinAPI_CreatePen($PS_SOLID, 1, _WinAPI_SwitchColor(0xFF0000)) ; RGB to BGR
                    Local $oOrig = _WinAPI_SelectObject($tItem.HDC, $hPen)
                    _WinAPI_DrawLine($tItem.HDC, $tRect.left + 5, $tRect.top + 8, $tRect.right - 5, $tRect.top + 8)
                    _WinAPI_SelectObject($tItem.HDC, $oOrig)
                    _WinAPI_DeleteObject($hPen)
                    Local $aGroup = _GUICtrlListView_GetGroupInfo($tItem.hWndFrom, $iItemSpec)
                    #EndRegion ; create full row background (black) with a leading line (red)

                    #Region ; PREFIX Group with auto INDEX - text with your own color (dark grey) and your own background (light grey) - on the previously created full row background
                    Local $iGroupIndex_0based = _GUICtrlListView_GetGroupIndexByGroupID($_hListView, $iItemSpec) ; auto count Group Index
                    Local $sGroupHumanIndex = "[ #" & $iGroupIndex_0based + 1 & ' ]'

                    $tRect.left += 10
                    _WinAPI_SetBkColor($tItem.HDC, _WinAPI_SwitchColor(0xAAAAAA)) ; RGB to BGR
                    _WinAPI_SetBkMode($tItem.HDC, $OPAQUE)
                    _WinAPI_SetTextColor($tItem.HDC, _WinAPI_SwitchColor(0x880000)) ; RGB to BGR
                    _WinAPI_DrawText($tItem.HDC, $sGroupHumanIndex, $tRect, $DT_LEFT)
                    #EndRegion ; PREFIX Group with auto INDEX - text with your own color (dark grey) and your own background (light grey) - on the previously created full row background

                    #Region ; repaint the text with your own color (dark blue) and your own background (light blue) - on the previously created full row background
                    $tRect.left += 80
                    _WinAPI_SetBkColor($tItem.HDC, _WinAPI_SwitchColor(0x55AAFF)) ; RGB to BGR
                    _WinAPI_SetBkMode($tItem.HDC, $OPAQUE)
                    _WinAPI_SetTextColor($tItem.HDC, _WinAPI_SwitchColor(0x0000FF)) ; RGB to BGR
                    _WinAPI_DrawText($tItem.HDC, "  " & $aGroup[0] & "  ", $tRect, $DT_LEFT)
                    #EndRegion ; repaint the text with your own color (dark blue) and your own background (light blue) - on the previously created full row background

                    Return $CDRF_SKIPDEFAULT
                EndIf
            EndIf
        EndIf
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func _GUICtrlListView_GetGroupIndexByGroupID($hWnd, $iGroupID)
    Local $iMaxIndex = _GUICtrlListView_GetGroupCount($hWnd) - 1
    Local $aInfo
    For $i = 0 To $iMaxIndex
        $aInfo = _GUICtrlListView_GetGroupInfoByIndex($hWnd, $i)
        If $aInfo[2] = $iGroupID Then Return $i
    Next

    Return SetError(1, 0, -1)
EndFunc   ;==>_GUICtrlListView_GetGroupIndexByGroupID

 

 

Edited 23 hours ago by mLipok

[mLipok]

Should I use Return $GUI_RUNDEFMSG at the end of:

.....
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

?

[argumentum]

3 minutes ago, mLipok said:

Should I use Return $GUI_RUNDEFMSG at the end of:

.....
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

?

I would. There's no reason not to. Plus, is good manners  

[mLipok]

28 minutes ago, argumentum said:

I would. There's no reason not to. Plus, is good manners  

I just edit the example above.

Edited 23 hours ago by mLipok

[mLipok]

7 minutes ago, argumentum said:

I would. There's no reason not to. Plus, is good manners  

hm... GUIRegisterMsg.au3 example says:

...
    ; On exit the default AutoIt3 internal message handler will run
    ; It will also run if "Return" returns $GUI_RUNDEFMSG as below
    ; Using "Return" with any other value (or no value at all) means the AutoIt handler
    ; will not run
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

 

[mLipok]

Using groups I have one more puzzle I'm struggling with.

Please take a look at this following script:

expandcollapse popup

#include <GUIConstants.au3>
#include <GuiListView.au3>

Global $_hGUI = 0, $_hListView = 00
Example()

Func Example()
    ; create GUI window
    $_hGUI = GUICreate("Example", 500, 800)
    ; create ListView control
    Local $idListview = GUICtrlCreateListView("", 10, 10, 480, 780)
    $_hListView = ControlGetHandle($_hGUI, '', $idListview)

    ; Enable extended control styles
    _GUICtrlListView_SetExtendedListViewStyle($idListview, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
    GUISetState(@SW_SHOW)

    ; Set ANSI format
;~     _GUICtrlListView_SetUnicodeFormat($idListview, False)

    GUIRegisterMsg($WM_NOTIFY, WM_NOTIFY)

    _GUICtrlListView_BeginUpdate($idListview)

    _GUICtrlListView_AddColumn($idListview, "Column 0", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)

    Local $iMAX = 499
    For $i = 0 To $iMAX
        _GUICtrlListView_AddItem($idListview, "Row " & $i & ": Col 0", 0)
        _GUICtrlListView_AddSubItem($idListview, $i, "Row " & $i & ": Col 1", 1)
    Next

    Local $iCount10 = 0, $iGroupID
    For $i = 0 To $iMAX
        If Mod($i, 10) = 0 Then
            $iGroupID = $iCount10 * 10
            $iCount10 += 1
            _GUICtrlListView_InsertGroup($idListview, -1, $iGroupID, 'GroupID=' & $iGroupID & ' for all rows with RowIndex in range <' & $iGroupID & ',' & ($iCount10 * 10) - 1 & '>')
        EndIf
        _GUICtrlListView_SetItemGroupID($idListview, $i, $iGroupID)
    Next

    _GUICtrlListView_EnableGroupView($idListview)

    _GUICtrlListView_EnsureVisible($idListview, 250)
    _GUICtrlListView_EndUpdate($idListview)

    Local $aInfo, $s_GroupHeader

;~  $aInfo = _GUICtrlListView_GetGroupInfo($idListview, 240)
    $aInfo = _GUICtrlListView_GetGroupInfoByIndex($idListview, 24) ; REMARK: 0based ListView Index  24 is $sGroupHumanIndex = "[ #25 ]"
    $s_GroupHeader = $aInfo[0] ; please note that $s_GroupHeader does not contain an index in the displayed form [ #**** ]
    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, 'Focus on $sGroupHumanIndex = "[ #25 ]" ' & @CRLF & 'Is it like following:' & @CRLF & $s_GroupHeader & @CRLF & 'It will be removed !')

    ; removing group for all 24* rows
    _GUICtrlListView_RemoveGroup($idListview, 240)

;~  $aInfo = _GUICtrlListView_GetGroupInfo($idListview, 250)
    $aInfo = _GUICtrlListView_GetGroupInfoByIndex($idListview, 24) ; REMARK: 0based ListView Index  24 is $sGroupHumanIndex = "[ #25 ]"
    $s_GroupHeader = $aInfo[0] ; please note that $s_GroupHeader does not contain an index in the displayed form [ #**** ]
    MsgBox($MB_TOPMOST, "TEST #" & @ScriptLineNumber, 'Where is $sGroupHumanIndex = "[ #25 ]" GroupID=240 ?' & @CRLF & 'Was it removed ?' & @CRLF & @CRLF & 'What content is in $sGroupHumanIndex = "[ #25 ]" ?' & @CRLF & 'Is it like following:' & @CRLF & $s_GroupHeader)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>Example

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $iMsg, $wParam

    If $hWnd = $_hGUI Then ; check if Our GUI - in case you create multiple GUI - Window
        Local $tItem = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
        If $tItem.hWndFrom = $_hListView Then     ; check if our ListView - in case you have few ListView on the same GUI - Window
            Local $iItemSpec = $tItem.dwItemSpec ; ItemIndex for "RowElement", GroupID for "GroupElement"
            If $tItem.dwItemType = $LVCDI_ITEM Then
                If $tItem.Code = $NM_SETFOCUS Or $tItem.Code = $NM_HOVER Or $tItem.Code = $NM_SETCURSOR Or $tItem.Code = $NM_CLICK Or $tItem.Code = $NM_DBLCLK Or $tItem.Code = $NM_RCLICK Or $tItem.Code = $NM_RDBLCLK Then
;~                  Sleep(100)
                    ConsoleWrite('! 1. Selection Mark = ' & _GUICtrlListView_GetSelectionMark($_hListView) & @CRLF)
                    ConsoleWrite('! 2. $iItemSpec= ' & $iItemSpec & @CRLF)
                    Return $GUI_RUNDEFMSG
                EndIf
            ElseIf $tItem.dwItemType = $LVCDI_GROUP Then
                If $tItem.Code = $NM_CLICK Or $tItem.Code = $NM_DBLCLK Or $tItem.Code = $NM_RCLICK Or $tItem.Code = $NM_RDBLCLK Then
                    ConsoleWrite('! 3. Selection Mark = ' & _GUICtrlListView_GetSelectionMark($_hListView) & @CRLF)
                    ConsoleWrite('! 4. $iItemSpec= ' & $iItemSpec & @CRLF)
                    Return $GUI_RUNDEFMSG
                ElseIf $tItem.Code = $NM_CUSTOMDRAW And $tItem.dwDrawStage = $CDDS_PREPAINT Then

                    Local $tRect = DllStructCreate($tagRECT, DllStructGetPtr($tItem, "left"))

                    #Region ; create full row background (black) with a leading line (red)
                    $tRect.bottom = $tRect.top + 18
                    Local $hBrush = _WinAPI_CreateSolidBrush(0)
                    _WinAPI_FillRect($tItem.HDC, $tRect, $hBrush)
                    _WinAPI_DeleteObject($hBrush)
                    Local $hPen = _WinAPI_CreatePen($PS_SOLID, 1, _WinAPI_SwitchColor(0xFF0000)) ; RGB to BGR
                    Local $oOrig = _WinAPI_SelectObject($tItem.HDC, $hPen)
                    _WinAPI_DrawLine($tItem.HDC, $tRect.left + 5, $tRect.top + 8, $tRect.right - 5, $tRect.top + 8)
                    _WinAPI_SelectObject($tItem.HDC, $oOrig)
                    _WinAPI_DeleteObject($hPen)
                    Local $aGroup = _GUICtrlListView_GetGroupInfo($tItem.hWndFrom, $iItemSpec)
                    #EndRegion ; create full row background (black) with a leading line (red)

                    #Region ; PREFIX Group with auto INDEX - text with your own color (dark grey) and your own background (light grey) - on the previously created full row background
                    Local $iGroupIndex_0based = _GUICtrlListView_GetGroupIndexByGroupID($_hListView, $iItemSpec) ; auto count Group Index
                    Local $sGroupHumanIndex = "[ #" & $iGroupIndex_0based + 1 & ' ]'

                    $tRect.left += 10
                    _WinAPI_SetBkColor($tItem.HDC, _WinAPI_SwitchColor(0xAAAAAA)) ; RGB to BGR
                    _WinAPI_SetBkMode($tItem.HDC, $OPAQUE)
                    _WinAPI_SetTextColor($tItem.HDC, _WinAPI_SwitchColor(0x880000)) ; RGB to BGR
                    _WinAPI_DrawText($tItem.HDC, $sGroupHumanIndex, $tRect, $DT_LEFT)
                    #EndRegion ; PREFIX Group with auto INDEX - text with your own color (dark grey) and your own background (light grey) - on the previously created full row background

                    #Region ; repaint the text with your own color (dark blue) and your own background (light blue) - on the previously created full row background
                    $tRect.left += 80
                    _WinAPI_SetBkColor($tItem.HDC, _WinAPI_SwitchColor(0x55AAFF)) ; RGB to BGR
                    _WinAPI_SetBkMode($tItem.HDC, $OPAQUE)
                    _WinAPI_SetTextColor($tItem.HDC, _WinAPI_SwitchColor(0x0000FF)) ; RGB to BGR
                    _WinAPI_DrawText($tItem.HDC, "  " & $aGroup[0] & "  ", $tRect, $DT_LEFT)
                    #EndRegion ; repaint the text with your own color (dark blue) and your own background (light blue) - on the previously created full row background

                    Return $CDRF_SKIPDEFAULT
                EndIf
            EndIf
        EndIf
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func _GUICtrlListView_GetGroupIndexByGroupID($hWnd, $iGroupID)
    Local $iMaxIndex = _GUICtrlListView_GetGroupCount($hWnd) - 1
    Local $aInfo
    For $i = 0 To $iMaxIndex
        $aInfo = _GUICtrlListView_GetGroupInfoByIndex($hWnd, $i)
        If $aInfo[2] = $iGroupID Then Return $i
    Next

    Return SetError(1, 0, -1)
EndFunc   ;==>_GUICtrlListView_GetGroupIndexByGroupID

I did some reasearch and test, but this following snipp does not work as I expected:

...
            If $tItem.dwItemType = $LVCDI_ITEM Then
                If $tItem.Code = $NM_SETFOCUS Or $tItem.Code = $NM_HOVER Or $tItem.Code = $NM_SETCURSOR Or $tItem.Code = $NM_CLICK Or $tItem.Code = $NM_DBLCLK Or $tItem.Code = $NM_RCLICK Or $tItem.Code = $NM_RDBLCLK Then
;~                  Sleep(100)
                    ConsoleWrite('! 1. Selection Mark = ' & _GUICtrlListView_GetSelectionMark($_hListView) & @CRLF)
                    ConsoleWrite('! 2. $iItemSpec= ' & $iItemSpec & @CRLF)
                    Return $GUI_RUNDEFMSG
                EndIf
            ElseIf $tItem.dwItemType = $LVCDI_GROUP Then
                If $tItem.Code = $NM_CLICK Or $tItem.Code = $NM_DBLCLK Or $tItem.Code = $NM_RCLICK Or $tItem.Code = $NM_RDBLCLK Then
                    ConsoleWrite('! 3. Selection Mark = ' & _GUICtrlListView_GetSelectionMark($_hListView) & @CRLF)
                    ConsoleWrite('! 4. $iItemSpec= ' & $iItemSpec & @CRLF)
                    Return $GUI_RUNDEFMSG
                ElseIf $tItem.Code = $NM_CUSTOMDRAW And $tItem.dwDrawStage = $CDDS_PREPAINT Then
...

How to use WM_NOTIFY to detect which ROW ITEM is selected after you click GROUP HEADER and the focus switched from GROUP ITEM to the first ROW ITEM in the GROUP ?

Edited 20 hours ago by mLipok
typo in question