ListView - ScrollBar color with WM_CTLCOLORSCROLLBAR

[mLipok]

I want to ask if somebody already tried WM_CTLCOLORSCROLLBAR for changing color for ScrollBar ?

Maybe someone already has a ready example?

[MattyD]

I think it's meant for other random bars that you can create, rather than those attached to a window.

#include <GuiConstants.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

$hGUI = GUICreate("Test", 200, 100, -1, -1, BitOR($WS_OVERLAPPEDWINDOW, $WS_HSCROLL, $WS_VSCROLL))
_SBCreate($hGUI, 1000, 10, 10, 100, 20)

GUIRegisterMsg($WM_CTLCOLORSCROLLBAR, "WM_CTLCOLORSCROLLBAR")
GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

GUIDelete()

Func _SBCreate($hWnd, $idCtrlID, $iX, $iY, $iWidth, $iHeight, $iStyle = -1, $iExStyle = -1)
    If $iStyle = -1 Then $iStyle = BitOR($WS_VISIBLE, $WS_CHILD)
    If $iExStyle = -1 Then $iExStyle = 0
    Return _WinAPI_CreateWindowEx($iExStyle, $WC_SCROLLBAR, "", $iStyle, $iX, $iY, $iWidth, $iHeight, $hWnd, $idCtrlID, _WinAPI_GetModuleHandle(0), 0)
EndFunc

Func WM_CTLCOLORSCROLLBAR($hWnd, $iMsg, $wParam, $lParam)
    Return _WinAPI_GetStockObject($BLACK_BRUSH)
EndFunc

 

[mLipok]

Little modified

expandcollapse popup

#include <ColorConstants.au3>
#include <GuiConstants.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

_Example()
Func _Example()
    Local $hGUI = GUICreate("Test", 400, 200, -1, -1, BitOR($WS_OVERLAPPEDWINDOW, $WS_HSCROLL, $WS_VSCROLL))
    GUISetBkColor($COLOR_LIGHTSEAGREEN, $hGUI)
    Local $hScrollBarGUI = _SBCreate($hGUI, 1000, 20, 30, 330, 30)
    #forceref $hScrollBarGUI

    GUIRegisterMsg($WM_CTLCOLORSCROLLBAR, __WM_CTLCOLORSCROLLBAR)
    GUISetState()

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()


EndFunc   ;==>_Example

Func _SBCreate($hWnd, $idCtrlID, $iX, $iY, $iWidth, $iHeight, $iStyle = -1, $iExStyle = -1)
    If $iStyle = -1 Then $iStyle = BitOR($WS_VISIBLE, $WS_CHILD)
    If $iExStyle = -1 Then $iExStyle = 0
    Return _WinAPI_CreateWindowEx($iExStyle, $WC_SCROLLBAR, "", $iStyle, $iX, $iY, $iWidth, $iHeight, $hWnd, $idCtrlID, _WinAPI_GetModuleHandle(0), 0)
EndFunc   ;==>_SBCreate

Func __WM_CTLCOLORSCROLLBAR($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam, $lParam

;~  Return _WinAPI_GetStockObject($BLACK_BRUSH)
;~  Return _WinAPI_GetStockObject($DKGRAY_BRUSH)
    Return _WinAPI_GetStockObject($GRAY_BRUSH)

;~  Local $tItem = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam) ; $tagNMLVCUSTOMDRAW is defined in #include <StructureConstants.au3> ; https://learn.microsoft.com/en-us/windows/win32/api/commctrl/ns-commctrl-nmlvcustomdraw
;~  Local $hDC = $tItem.hdc                      ; Device context
;~  Return _WinAPI_SetDCBrushColor($hDC, $COLOR_LIGHTBLUE)
EndFunc   ;==>__WM_CTLCOLORSCROLLBAR

I read here:
https://learn.microsoft.com/en-us/windows/win32/api/wingdi/nf-wingdi-getstockobject

about:

Quote

 The GetStockObject function with an argument of DC_BRUSH or DC_PEN can be used interchangeably with the SetDCPenColor and SetDCBrushColor functions.

For this reason I was trying to use my specific color like $COLOR_LIGHTBLUE in this part:

Local $tItem = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam) ; $tagNMLVCUSTOMDRAW is defined in #include <StructureConstants.au3> ; https://learn.microsoft.com/en-us/windows/win32/api/commctrl/ns-commctrl-nmlvcustomdraw
    Local $hDC = $tItem.hdc                      ; Device context
    Return _WinAPI_SetDCBrushColor($hDC, $COLOR_LIGHTBLUE)
EndFunc   ;==>__WM_CTLCOLORSCROLLBAR

But with no success

Any help please ?

 

EDIT:
also tried this way:

Local Static $hBrush = _WinAPI_CreateSolidBrush($COLOR_AQUA)
    Local $tItem = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam) ; $tagNMLVCUSTOMDRAW is defined in #include <StructureConstants.au3> ; https://learn.microsoft.com/en-us/windows/win32/api/commctrl/ns-commctrl-nmlvcustomdraw
    Local $hDC = $tItem.hdc                      ; Device context
    _WinAPI_SelectObject($hDC, $hBrush)
    Return $CDRF_SKIPDEFAULT
EndFunc   ;==>__WM_CTLCOLORSCROLLBAR

Still with no success

Edited May 2 by mLipok

[mLipok]

Here is my another approach:

expandcollapse popup

#include <ColorConstants.au3>
#include <GuiConstants.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

_Example()
Func _Example()
    Local $hGUI = GUICreate("Test", 400, 200, -1, -1, BitOR($WS_OVERLAPPEDWINDOW, $WS_HSCROLL, $WS_VSCROLL))
    GUISetBkColor($COLOR_LIGHTSEAGREEN, $hGUI)
    Local $hScrollBarGUI = _SBCreate($hGUI, 1000, 20, 30, 330, 30)
    #forceref $hScrollBarGUI

;~  GUIRegisterMsg($WM_CTLCOLORSCROLLBAR, __WM_CTLCOLORSCROLLBAR)
    GUISetState()

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()


EndFunc   ;==>_Example

Func _SBCreate($hWnd, $idCtrlID, $iX, $iY, $iWidth, $iHeight, $iStyle = -1, $iExStyle = $WS_EX_TOPMOST, $bBorder = True)
    If $iStyle = -1 Then $iStyle = BitOR($WS_VISIBLE, $WS_CHILD)
    If $iExStyle = -1 Then $iExStyle = 0
    If $bBorder Then
        Local $idLabel = GUICtrlCreateLabel("", $iX - 2, $iY - 2, $iWidth + 4, $iHeight + 4, $SS_BLACKRECT)
        GUICtrlSetColor($idLabel, $COLOR_LIGHTCORAL)
    EndIf

    Return _WinAPI_CreateWindowEx($iExStyle, $WC_SCROLLBAR, "", $iStyle, $iX, $iY, $iWidth, $iHeight, $hWnd, $idCtrlID, _WinAPI_GetModuleHandle(0), 0)
EndFunc   ;==>_SBCreate

Func __WM_CTLCOLORSCROLLBAR($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam, $lParam

;~  Return _WinAPI_GetStockObject($BLACK_BRUSH)
;~  Return _WinAPI_GetStockObject($DKGRAY_BRUSH)
    Return _WinAPI_GetStockObject($GRAY_BRUSH)

;~  Local $tItem = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam) ; $tagNMLVCUSTOMDRAW is defined in #include <StructureConstants.au3> ; https://learn.microsoft.com/en-us/windows/win32/api/commctrl/ns-commctrl-nmlvcustomdraw
;~  Local $hDC = $tItem.hdc                      ; Device context
;~  Return _WinAPI_SetDCBrushColor($hDC, $COLOR_LIGHTBLUE)
EndFunc   ;==>__WM_CTLCOLORSCROLLBAR

But I see that $WS_EX_TOPMOST is not working as I expected.
I mean I can't click / move the ScrollBar created with _SBCreate() as my $idLabel is cover this scrollbar.
Any body has better / easier way to draw border in specific color for this ScrollBar created with  _SBCreate()  ?
Or just move Z order of the ScrollBar over the Label ?

 

Edited May 2 by mLipok

[mLipok]

Also here are some interesting findings:
https://superuser.com/a/1435181/1049106

about Registry settings:
 

Quote

Computer\HKEY_CURRENT_USER\Control Panel\Colors
Computer\HKEY_CURRENT_USER\Control Panel\Desktop\Colors

also you may want to take a look here:
 

Quote

Computer\HKEY_CURRENT_USER\Control Panel\Desktop\WindowMetrics

 

[WildByDesign]

15 hours ago, mLipok said:

I want to ask if somebody already tried WM_CTLCOLORSCROLLBAR for changing color for ScrollBar ?

I tried to use this last week for scrollbars in GUIDarkTheme UDF by returning the brush color. But unfortunately it does not work for scrollbars that are part of a control (eg. ListView, TreeView, etc.) since they all handle their own scrollbars internally.

Some of the tricks used, such as drawing custom scrollbars over top of existing scrollbars, is probably a bit too complex and resource waste for my purposes.

Regardless, I am going to continue to follow your examples in this thread because I am curious about it.

Edited May 2 by WildByDesign

[WildByDesign]

Also, we can use things like _WinAPI_SetSysColors to set the global system colors for scrollbars and other controls. But the problem in Win10/11 is that they ignore the majority of those values now because some things (scrollbars, menu, etc.) are all done through the theming engine (uxtheme) following values from within the aero.msstyles file.

[MattyD]

15 hours ago, mLipok said:

Quote

 The GetStockObject function with an argument of DC_BRUSH or DC_PEN can be used interchangeably with the SetDCPenColor and SetDCBrushColor functions.

For this reason I was trying to use my specific color like $COLOR_LIGHTBLUE in this part:

Local $tItem = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam) ; $tagNMLVCUSTOMDRAW is defined in #include <StructureConstants.au3> ; https://learn.microsoft.com/en-us/windows/win32/api/commctrl/ns-commctrl-nmlvcustomdraw
    Local $hDC = $tItem.hdc                      ; Device context
    Return _WinAPI_SetDCBrushColor($hDC, $COLOR_LIGHTBLUE)
EndFunc   ;==>__WM_CTLCOLORSCROLLBAR

But with no success

Any help please ?

A couple of things..

lparam is not a ptr to a NVLMCUSTOMDRAW here. For WM_CTLCOLORSCROLLBAR, the DC is passed to us through wParam.  We also need to return a brush for the background, which SetDCBrushColor doesn't do.

so it should look something like this. 

Func WM_CTLCOLORSCROLLBAR($hWnd, $iMsg, $wParam, $lParam)
    _WinAPI_SetDCBrushColor($wParam, $COLOR_LIGHTBLUE)
    Return _WinAPI_GetStockObject($DC_BRUSH)
EndFunc

But to @WildByDesign's point, this is all academic and doesn't really achieve much.

[mLipok]

On 5/2/2026 at 1:22 PM, mLipok said:

But I see that $WS_EX_TOPMOST is not working as I expected.
I mean I can't click / move the ScrollBar created with _SBCreate() as my $idLabel is cover this scrollbar.
Any body has better / easier way to draw border in specific color for this ScrollBar created with  _SBCreate()  ?
Or just move Z order of the ScrollBar over the Label ?

Any suggestion here ?

[pixelsearch]

Maybe disable the label just after its creation, making the scrollbar responsive ?

Local $idLabel = GUICtrlCreateLabel(...)
GUICtrlSetState(-1, $GUI_DISABLE)

 

[mLipok]

Thanks This works