ListView + LVGROUPMETRICS

[mLipok]

 I just wana try to use:

https://learn.microsoft.com/en-us/windows/win32/api/commctrl/ns-commctrl-lvgroupmetrics

As so far I got:

expandcollapse popup

#AutoIt3Wrapper_UseX64=N

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>
#include <WinAPISys.au3>

; https://learn.microsoft.com/en-us/windows/win32/api/commctrl/ns-commctrl-lvgroupmetrics
Global Const $tagLVGROUPMETRICS = _
        "uint cbSize;" & _
        "uint mask;" & _
        "uint Left;" & _
        "uint Top;" & _
        "uint Right;" & _
        "uint Bottom;" & _
        "COLORREF crLeft;" & _
        "COLORREF crTop;" & _
        "COLORREF crRight;" & _
        "COLORREF crBottom;" & _
        "COLORREF crHeader;" & _
        "COLORREF crFooter;"

Global Const $LVGMF_BORDERSIZE = 0x00000001
Global Const $LVGMF_BORDERCOLOR = 0x00000002
Global Const $LVGMF_TEXTCOLOR = 0x00000004

_Example()

Func _Example()

    ; GUI
    Local $hGUI = GUICreate("Windows 11 LVGROUPMETRICS", 900, 500)
    #forceref $hGUI

    Local $idLV = GUICtrlCreateListView( _
            "Name|Description|State", _
            10, 10, 880, 440, _
            BitOR($LVS_REPORT, $LVS_SHOWSELALWAYS))

    Local $hLV = GUICtrlGetHandle($idLV)

    ; Explorer theme (Win11)
    DllCall("uxtheme.dll", "none", "SetWindowTheme", _
            "hwnd", $hLV, _
            "wstr", "Explorer", _
            "ptr", 0)

    ; Extended styles
    _GUICtrlListView_SetExtendedListViewStyle($hLV, _
            BitOR($LVS_EX_FULLROWSELECT, _
            $LVS_EX_DOUBLEBUFFER, _
            $LVS_EX_BORDERSELECT))

    ; Group view
    _GUICtrlListView_EnableGroupView($hLV, True)

    ; Groups
    _GUICtrlListView_InsertGroup($hLV, 0, 100, "Applications")
    _GUICtrlListView_InsertGroup($hLV, 1, 200, "Services")

    ; Items
    Local $i

    $i = _GUICtrlListView_AddItem($hLV, "Explorer.exe")
    _GUICtrlListView_AddSubItem($hLV, $i, "Windows Shell", 1)
    _GUICtrlListView_AddSubItem($hLV, $i, "Running", 2)
    _GUICtrlListView_SetItemGroupID($hLV, $i, 100)

    $i = _GUICtrlListView_AddItem($hLV, "Notepad.exe")
    _GUICtrlListView_AddSubItem($hLV, $i, "Text Editor", 1)
    _GUICtrlListView_AddSubItem($hLV, $i, "Idle", 2)
    _GUICtrlListView_SetItemGroupID($hLV, $i, 100)

    $i = _GUICtrlListView_AddItem($hLV, "AudioSrv")
    _GUICtrlListView_AddSubItem($hLV, $i, "Windows Audio", 1)
    _GUICtrlListView_AddSubItem($hLV, $i, "Active", 2)
    _GUICtrlListView_SetItemGroupID($hLV, $i, 200)

    #Region ; LVGROUPMETRICS

    Local $tMetrics = DllStructCreate($tagLVGROUPMETRICS)

    DllStructSetData($tMetrics, "cbSize", DllStructGetSize($tMetrics))

    DllStructSetData($tMetrics, "mask", _
            BitOR($LVGMF_BORDERSIZE, _
            $LVGMF_BORDERCOLOR, _
            $LVGMF_TEXTCOLOR))

    ; Margins
    DllStructSetData($tMetrics, "Left", 12)
    DllStructSetData($tMetrics, "Top", 8)
    DllStructSetData($tMetrics, "Right", 12)
    DllStructSetData($tMetrics, "Bottom", 8)

    ; Border colors
    DllStructSetData($tMetrics, "crLeft", 0xFFD0D0)
    DllStructSetData($tMetrics, "crTop", 0xD0FFD0)
    DllStructSetData($tMetrics, "crRight", 0xD0D0FF)
    DllStructSetData($tMetrics, "crBottom", 0xD0D0D0)

    ; Header text color (BGR)
    DllStructSetData($tMetrics, "crHeader", 0xFF0000)

    ; Footer text color (BGR)
    ; RGB(0,128,0)
    DllStructSetData($tMetrics, "crFooter", 0x00FF00)

    #EndRegion ; LVGROUPMETRICS

    ; ----------------------------
    ; Apply metrics
    ; ----------------------------
    Local $bRet = _GUICtrlListView_SetGroupMetrics($hLV, $tMetrics)

    ConsoleWrite("SetGroupMetrics: " & $bRet & @CRLF)

    ; ----------------------------
    ; Column widths
    ; ----------------------------
    _GUICtrlListView_SetColumnWidth($hLV, 0, 220)
    _GUICtrlListView_SetColumnWidth($hLV, 1, 350)
    _GUICtrlListView_SetColumnWidth($hLV, 2, 120)

    GUISetState(@SW_SHOW)

    While True
        Switch GUIGetMsg()

            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd

EndFunc   ;==>_Example

Func _GUICtrlListView_SetGroupMetrics($hWnd, $pMetrics)

    If Not IsHWnd($hWnd) Then
        $hWnd = GUICtrlGetHandle($hWnd)
    EndIf

    If $hWnd = 0 Then
        Return SetError(1, 0, False)
    EndIf

    If Not IsDllStruct($pMetrics) Then
        Return SetError(2, 0, False)
    EndIf

    Return _SendMessage( _
            $hWnd, _
            $LVM_SETGROUPMETRICS, _
            0, _
            DllStructGetPtr($pMetrics), _
            0, _
            "ptr")

EndFunc   ;==>_GUICtrlListView_SetGroupMetrics

of course most features are: Not implemented by MS