how to check if a filename fits mask

[orbs 155]

hello everyone,

suppose i have a given filename (e.g. "letter.doc"), and a given mask (e.g. "*.doc"). i want to check if the filename fits the mask.

i started to work on a script that splits the filename using the known part of the mask as delimiter, and matches the split parts with the * and ? in the mask.

in this example, the delimiter is ".doc", the split part of the filename is "letter" and the split part of the mask is "*", so i can match.

but this is getting too complicated for more complex masks. is there a simple way to do it?

thanks in advance,

Or

[guinness 1,450]

Have a look at

Edited January 30, 2011 by guinness

[BrewManNH 1,062]

You could also look at the _PathSplit command, it will split a file name into its component parts such as Drive letter, path, file name, and file extension.

[UEZ 1,071]

Best is probably _PathSplit() and StringRegExp() in combination.

Br,

UEZ

[Malkey 165]

This function appears to work.

It converts a wildcard mask into a regular expression pattern.

ConsoleWrite(_CheckFilenameFitsMask("letter.doc", "*.doc") & @CRLF)

; Description - Checks if a file name, $sFileName, fits a wildcard mask, $sMask, with optional case-insensitivity.
; $sMask - A pattern string can be a combination of valid file name characters and wildcard characters.
; $CaseSensitive - Case sensitivity default = 1 meaning "function is case sensitive".
; Returns 1 (matched) or 0 (no match).
;
Func _CheckFilenameFitsMask($sFileName, $sMask = "*", $CaseSensitive = 1)
    $sMask = StringRegExpReplace($sMask, "([\.\\])", "\\\1")
    $sMask = StringReplace($sMask, "?", ".")
    $sMask = StringReplace($sMask, "*", ".*")
    If $CaseSensitive <> 1 Then $sMask = "(?i)" & $sMask
    ;ConsoleWrite($sMask & @CRLF)
    Return StringRegExp($sFileName, $sMask)
EndFunc   ;==>_CheckFilenameFitsMask

[Varian 5]

$FileMask = '*.doc'
$FileName = 'Letter.doc'
$Extension = StringRegExpReplace($FileName, '^.+\.', '')
If StringInStr($FileMask, $Extension) Then MsgBox(262208, 'Success', $FileName & ' fits File Mask ' & $FileMask)

Edited January 31, 2011 by Varian

[Ascend4nt 118]

Had this lying around

expandcollapse popup

#include-once
; ===============================================================================================================================
; <_FileWildcardPathMatch.au3>
;
; Function to test a string against another string containing DOS-style wildcards (*,?).
;   NOTE: Some users have reported that it doesn't function *exactly* like the DOS variant, which is okay
;     if you know this ahead of time (see Sources, and experiment).
;
; Function:
;   _FileWildcardPathMatch()    ; Tests 1st string against wildcard pattern of 2nd string
;
; Sources:
;   'PathMatchSpec' on MSDN @ http://msdn.microsoft.com/en-us/library/bb773727%28v=VS.85%29.aspx
;
; Author: Ascend4nt
; ===============================================================================================================================

; ===================================================================================================================
;   --------------------    MAIN FUNCTION   --------------------
; ===================================================================================================================


; ===================================================================================================================
; Func _FileWildcardPathMatch($sPath,$sWildcard)
;
; Function to test a string against another string containing DOS-style wildcards (*,?).
;   NOTE: Some users have reported that it doesn't function *exactly* like the DOS variant, which is okay
;     if you know this ahead of time (see Sources in header, and experiment!).
;
; $sPath = Path or pretty much any string that you will be testing with a wildcard string
; $sWildcard = String to test $sPath against. Obviously this would be the string containing wildcards (*,?)
;
; Return:
;   Success: 0 (no match) or 1 (match), with @error=0
;   Failure: 0 with @error set:
;       @error = 2 = DLLCall() error. @extended = actual DLLCall error code
;
; Author: Ascend4nt
; ===================================================================================================================

Func _FileWildcardPathMatch($sPath,$sWildcard)
    Local $aRet=DllCall("shlwapi.dll","bool","PathMatchSpecW","wstr",$sPath,"wstr",$sWildcard)
    If @error Then Return SetError(2,@error,False)
    Return $aRet[0]
EndFunc

;~ #cs
;~ $sFolderOrFile="mdo.tcs.txt"
;~ $sWildcard="m?o*"
;~ $sFolderOrFile="C:\folder.txt"
;~ $sWildcard="C:\folder.t*xt"
$sFolderOrFile="googly.tenat"
$sWildcard="G*y.t*t"

ConsoleWrite("Match results:"&_FileWildcardPathMatch($sFolderOrFile,$sWildcard)&", @error="&@error&", @extended="&@extended&@CRLF)