Stringregexpreplace A Specifc Iinstance In A String?

[smashly]

Hi,

Thank You for taking the time to read my post.

Could someone please post a brief example of using StringRegExpReplace() to replace a word at a specific count.

For example I'm trying to replace only the 2nd instance of the word "Dog" with "Turtle" in the string below.

$sStr = "CatDogMouseBirdHorseDogBirdHorseMouseBirdDogAnt"

Edited December 23, 2012 by smashly

[PhoenixXL]

$sStr = "CatDogMouseBirdHorseDogBirdHorseMouseBirdDogAnt"

MsgBox(0,0,StringRegExpReplace($sstr, '(?s)(?U)' & _ ;(?s)will make . to match anything; (?U) makes repeating character Lazy[ie Now * is *?]
'(Dog)' & _ ; [First Group] The FirstMatch of the SearchString
'(.*)(\1)' & _ ; [Second Group] Match the least number of characters after which [Third Group] the first back-reference(i.e "Dog") is found
,'\1\2Turtle') & _ ; Replace the Third Group with Turtle
)

Edited December 23, 2012 by PhoenixXL

[smashly]

Thank You

[Melba23]

PhoenixXL,

Always a good idea to explain what is going on in the SRE - would you mind?

M23

[PhoenixXL]

M23,

I'll keep it in mind next time

I have added comments in the Code

BTW thanks for the advice

[Melba23]

PhoenixXL,

Thanks - I learnt a lot from that.

M23

[careca]

In a more rudimentar way...

$sStr = "CatDogMouseBirdHorseDogBirdHorseMouseBirdDogAnt"
$sStrSplt = StringSplit($sStr, 'Dog', 1)
;MsgBox(64, '', ' 0 '&$sStrSplt[0]&' | 1 '&$sStrSplt[1]&' | 2 '&$sStrSplt[2]&' | 3 '&$sStrSplt[3]&' | 4 '&$sStrSplt[4])
MsgBox(64, '', $sStrSplt[1]&'Dog'&$sStrSplt[2]&'Turtle'&$sStrSplt[3]&$sStrSplt[4])

[UEZ]

Hi smashly!

Back again? I hope so!

Br,

UEZ

[guinness]

Even though you wanted an example using SRER, I thought I would let you know that not everything has to be done with SRE if you don't feel like a guru. Here is an example using AutoIt native string functions.

Local Const $sFind = 'Dog', $iOccurrence = 2
Local $sText = 'CatDogMouseBirdHorseDogBirdHorseMouseBirdDogAnt'
Local $iPosition = StringInStr($sText, $sFind, 2, $iOccurrence) ; Case-insensitive, second occurance.

; Left side of Dog.
Local $sLeft = StringLeft($sText, $iPosition - 1)
ConsoleWrite('Left part: ' & $sLeft & @CRLF)

; Right side of Dog.
Local $sRight = StringMid($sText, $iPosition + StringLen($sFind), StringLen($sText) - $iPosition)
ConsoleWrite('Right part: ' & $sRight & @CRLF)

ConsoleWrite('Final: ' & $sLeft & 'Turtle' & $sRight & @CRLF)

[PhoenixXL]

For more examples of such Regular Expressions look

A Bit Extension of StringReplace with RegEx

expandcollapse popup

#include <Array.au3>


;Replaces the 2nd Occurence with the ReplaceString [Case - Sensitive]
$sStr = RegEx_StringReplace ("CatDogMouseBirdHorseDogBirdHorseMouseBirdDogAnt", 'Dog', 'Turtle', 0, 2, False) ;True will cause 1st and 2nd Occurence to get replaced
MsgBox (0, @extended,  $sStr )



Func RegEx_StringReplace($sString, $sSearch, $sReplace, $iInSensitive = 1, $iOccurrence = 0, $iContinue = False, $iRegEx = False)
Local $iReverse = False
;Insensitiveness
If $iInSensitive Then
$iInSensitive = '(?i)'
Else
$iInSensitive = ''
EndIf
If $iOccurrence < 0 Then
;Check for Negative occurance
$iReverse = True
$iOccurrence *= -1
$sString = RegEx_StringReverse($sString)
EndIf
;Check for special characters
If Not $iRegEx Then
CheckPattern( $sSearch )
If ($iOccurrence - 1) And Not $iContinue Then
$sSearch = '(?s)' & $sSearch & '((.*?)(\1)){' & $iOccurrence - 1 & '}'
$sReplace = '\1\3' & $sReplace
EndIf
EndIf
;main function
Local $aRet = StringRegExpReplace($sString, $iInSensitive & $sSearch , $sReplace, $iOccurrence)
Local $iExt = @extended
If Not $iContinue Then $iExt = 1
If $iReverse Then $aRet = RegEx_StringReverse($sString)
Return SetExtended($iExt, $aRet)
EndFunc ;==>RegEx_StringReplace

Func RegEx_StringReverse($sString, $iStart = 0, $iEnd = 0)
Local $sStart = '', $sEnd = ''
;Get the Start which would not be reversed
If $iStart > 0 Then $sStart = RegEx_StringMid($sString, 0, $iStart)
;Get the Start which would not be reversed
If $iStart + $iEnd < RegEx_StringLen($sString) Then $sEnd = RegEx_StringMid($sString, RegEx_StringLen($sString) - ($iStart + $iEnd))
;The Original String which has to be reversed
$sString = RegEx_StringMid($sString, $iStart, $iEnd)
;main function
Local $aRet = StringRegExp($sString, '(?s)(.)', 3)
_ArrayReverse($aRet)
Return $sStart & _ArrayToString($aRet, '') & $sEnd
EndFunc ;==>RegEx_StringReverse

Func RegEx_StringLen($sString)
;Replace Each Character
StringRegExpReplace($sString, '(?s)(.)', '')
;Return the Number of replacements
Return @extended
EndFunc ;==>RegEx_StringLen

Func RegEx_StringMid($sString, $iStart = 0, $iEnd = 0) ;First Char = 0
;If Start and End are 0 then Return the whole string
If Not BitOR($iStart, $iEnd) Then Return $sString
;If Out of Bounds then Return
If $iStart + $iEnd > RegEx_StringLen($sString) Then Return SetError(1, 0, $sString)
If $iStart > RegEx_StringLen($sString) Then Return SetError(2, 0, $sString)
If $iEnd < 0 Then Return SetError(3, 0, $sString)
If $iStart < 0 Then Return SetError(4, 0, $sString)
;Carry Out the Main Function
If $iStart Then $sString = StringRegExpReplace($sString, '(?s)(.{' & $iStart & '})', '', 1)
If $iEnd Then $sString = StringRegExpReplace($sString, '(?s)(.{' & $iEnd & '})(.*)', '\1', 1)
Return $sString
EndFunc ;==>RegEx_StringMid

Func CheckPattern (ByRef $sString )
;enclose withing sets so that special character lose their meaning
$sString = '(' & StringRegExpReplace ( $sString, '(?s)(.)', '[\1]' ) & ')'
Return 1
EndFunc

Edited December 24, 2012 by PhoenixXL