[SOLVE] Is possible to Hide [index] in _ArrayDisplay?

Underdogger · January 17, 2013

-

Edited February 5, 2013 by ElsonBrown

guinness · January 17, 2013

_ArrayDisplay is meant for debugging only, I wouldn't use it in a production script.

#include <Array.au3>
#include <File.au3>

Local $aInput = 0
Local $sFilePath = FileOpenDialog('Choose', @ScriptDir, 'type(*.txt;*.log;*.csv;*.ini)', 1, '')
If Not @error Then
    _FileReadToArray($sFilePath, $aInput)
    ; For $i = 1 To UBound($aInput) - 1
    ; Next
    _ArrayDelete($aInput, 0)
    _ArrayDisplay($aInput, 'clipboard', -1, 0, '', '', '')
    Local $sClipGet = ClipGet()
    If $sClipGet Then
        $sClipGet = StringRegExpReplace($sClipGet, '\[\d+\]\|(.*)', '\1')
        If @extended Then ClipPut($sClipGet)
    EndIf
EndIf

water · January 17, 2013

Write the array to the clipboard using AutoIt. Example:

#include <Array.au3>
Global $aArray[2][2] = [[11,12],[21,22]]
Global $sString
For $iIndexRow = 0 To Ubound($aArray, 1) - 1
    For $iIndexColumn = 0 To Ubound($aArray, 2) - 1
        If $iIndexColumn > 0 Then $sString = $sString & @TAB
        $sString = $sString & $aArray[$iIndexRow][$iIndexColumn]
    Next
    If $iIndexRow < Ubound($aArray, 1) - 1 Then $sString = $sString & @CRLF
Next
ClipPut($sString)

Underdogger · January 17, 2013

Sorry guinness,I found the problem still there.While I click the button of "Select to clipboard". It still appears "[0]|XXXXX". Thanks for applying my simple Question.

guinness · January 17, 2013

It works for me. It only works once _ArrayDisplay is closed, you understand?

Underdogger · January 17, 2013

It works for me. It only works once _ArrayDisplay is closed, you understand?

Yes,You are right,Thanks.

But is it possible to add the StringRegExpReplace to Default #include Func _ArrayDisplay while the script start copy the data or copy the Func out to script then modifying?

water · January 17, 2013

No. It's not recommended to alter AutoIt internal UDFs.

In this case I suggest to copy the _ArrayDisplay function as - lets say - _ArrayDisplayEX into your script and add the StringRegExpReplace there.

Underdogger · January 17, 2013

No. It's not recommended to alter AutoIt internal UDFs.
In this case I suggest to copy the _ArrayDisplay function as - lets say - _ArrayDisplayEX into your script and add the StringRegExpReplace there.

_ArrayDisplayEX is UDF or default Func?Where to download?

water · January 17, 2013

_ArrayDisplayEx is the function you write yourself. It's a copy of _ArrayDisplay + StringRegExpReplace.

guinness · January 17, 2013

Re-read what water said again, water said "copy it", therefore it doesn't exist, you create it yourself. Also, I won't be modifying _ArrayDisplay in AutoIt, as it's a debugging only function and this wouldn't benefit anyone.

Underdogger · January 17, 2013

Thanks two nice guys!!I will try it myself :thumbsup:

water · January 17, 2013

guinness · January 17, 2013

You're welcome.

Underdogger · January 17, 2013

I copy the default Func to my self script then use guinness's StringRegExpReplace to modify it . IT WORKS. THANKS SO MUCH!! :thumbsup:

water · January 17, 2013

Glad to be of service

Malkey · January 17, 2013

Here is a modified _ArrayDisplay function example.

#include <array.au3>

;===============================================================================
; Example 1
;===============================================================================
Local $asControls = StringSplit(WinGetClassList("[active]", ""), @LF)
_ArrayDisplayModified($asControls, "Class List of Active Window")

;===============================================================================
; Example 2 (using a manually-defined array)
;===============================================================================
Local $avArray[10]

$avArray[0] = "JPM"
$avArray[1] = "Holger"
$avArray[2] = "Jon"
$avArray[3] = "Larry"
$avArray[4] = "Jeremy"
$avArray[5] = "Valik"
$avArray[6] = "Cyberslug"
$avArray[7] = "Nutster"
$avArray[8] = "JdeB"
$avArray[9] = "Tylo"

_ArrayDisplayModified($avArray, "$avArray set manually 1D")
_ArrayDisplayModified($avArray, "$avArray set manually 1D transposed", -1, 1)

;===============================================================================
; Example 3 (using an array returned by StringSplit())
;===============================================================================
$avArray = StringSplit(WinGetClassList("", ""), @LF)
_ArrayDisplayModified($avArray, "$avArray as a list classes in window")

;===============================================================================
; Example 4 (a 2D array)
;===============================================================================
Local $avArray[2][5] = [["JPM", "Holger", "Jon", "Larry", "Jeremy"],["Valik", "Cyberslug", "Nutster", "JdeB", "Tylo"]]
_ArrayDisplayModified($avArray, "$avArray as a 2D array")
_ArrayDisplayModified($avArray, "$avArray as a 2D array, transposed", -1, 1)




; #FUNCTION# ====================================================================================================================
; Name...........: _ArrayDisplayModified
; Description ...: Displays given 1D or 2D array array in a listview.(First "Row" column containing "[0]" missing)
; Syntax.........: _ArrayDisplayModified(Const ByRef $avArray[, $sTitle = "Array: ListView Display"[, $iItemLimit = -1[, $iTranspose = 0[, $sSeparator = ""[, $sReplace = "|"[, $sHeader = ""]]]]]])
; Parameters ....: $avArray    - Array to display
;                 $sTitle    - [optional] Title to use for window
;                 $iItemLimit - [optional] Maximum number of listview items (rows) to show
;                 $iTranspose - [optional] If set differently than default, will transpose the array if 2D
;                 $sSeparator - [optional] Change Opt("GUIDataSeparatorChar") on-the-fly
;                 $sReplace   - [optional] String to replace any occurrence of $sSeparator with in each array element
;                 $sheader   - [optional] Header column names
; Return values .: Success - 1
;                 Failure - 0, sets @error:
;                 |1 - $avArray is not an array
;                 |2 - $avArray has too many dimensions (only up to 2D supported)
; Author ........: randallc, Ultima
; Modified.......: Gary Frost (gafrost), Ultima, Zedna, jpm, Malkey
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _ArrayDisplayModified(Const ByRef $avArray, $sTitle = "Array: ListView Display", $iItemLimit = -1, $iTranspose = 0, $sSeparator = "", $sReplace = "|", $sHeader = "")
    If Not IsArray($avArray) Then Return SetError(1, 0, 0)
    ; Dimension checking
    Local $iDimension = UBound($avArray, 0), $iUBound = UBound($avArray, 1) - 1, $iSubMax = UBound($avArray, 2) - 1
    If $iDimension > 2 Then Return SetError(2, 0, 0)

    ; Separator handling
    If $sSeparator = "" Then $sSeparator = Chr(124)

    ;  Check the separator to make sure it's not used literally in the array
    If _ArraySearch($avArray, $sSeparator, 0, 0, 0, 1) <> -1 Then
        For $x = 1 To 255
            If $x >= 32 And $x <= 127 Then ContinueLoop
            Local $sFind = _ArraySearch($avArray, Chr($x), 0, 0, 0, 1)
            If $sFind = -1 Then
                $sSeparator = Chr($x)
                ExitLoop
            EndIf
        Next
    EndIf

    ; Declare variables
    Local $vTmp, $iBuffer = 4094 ; AutoIt max item size
    Local $iColLimit = 250
    Local $iOnEventMode = Opt("GUIOnEventMode", 0), $sDataSeparatorChar = Opt("GUIDataSeparatorChar", $sSeparator)

    ; Swap dimensions if transposing
    If $iSubMax < 0 Then $iSubMax = 0
    If $iTranspose Then
        $vTmp = $iUBound
        $iUBound = $iSubMax
        $iSubMax = $vTmp
    EndIf

    ; Set limits for dimensions
    If $iSubMax > $iColLimit Then $iSubMax = $iColLimit
    If $iItemLimit < 1 Then $iItemLimit = $iUBound
    If $iUBound > $iItemLimit Then $iUBound = $iItemLimit

    ; Set header up
    If $sHeader = "" Then
        $sHeader = "" ; blanks added to adjust column size for big number of rows ; <============ Changed
        For $i = 0 To $iSubMax
            $sHeader &= $sSeparator & "Col " & $i
        Next
        $sHeader = StringTrimLeft($sHeader, 1) ; <============ New
    EndIf

    ; Convert array into text for listview
    Local $avArrayText[$iUBound + 1]
    For $i = 0 To $iUBound
        $avArrayText[$i] = "" ; <============ Changed
        For $j = 0 To $iSubMax
            ; Get current item
            If $iDimension = 1 Then
                If $iTranspose Then
                    $vTmp = $avArray[$j]
                Else
                    $vTmp = $avArray[$i]
                EndIf
            Else
                If $iTranspose Then
                    $vTmp = $avArray[$j][$i]
                Else
                    $vTmp = $avArray[$i][$j]
                EndIf
            EndIf

            ; Add to text array
            $vTmp = StringReplace($vTmp, $sSeparator, $sReplace, 0, 1)

            ; Set max buffer size
            If StringLen($vTmp) > $iBuffer Then $vTmp = StringLeft($vTmp, $iBuffer)

            $avArrayText[$i] &= $sSeparator & $vTmp
        Next
        $avArrayText[$i] = StringTrimLeft($avArrayText[$i], 1) ; <============ New
    Next

    ; GUI Constants
    Local Const $_ARRAYCONSTANT_GUI_DOCKBORDERS = 0x66
    Local Const $_ARRAYCONSTANT_GUI_DOCKBOTTOM = 0x40
    Local Const $_ARRAYCONSTANT_GUI_DOCKHEIGHT = 0x0200
    Local Const $_ARRAYCONSTANT_GUI_DOCKLEFT = 0x2
    Local Const $_ARRAYCONSTANT_GUI_DOCKRIGHT = 0x4
    Local Const $_ARRAYCONSTANT_GUI_EVENT_CLOSE = -3
    Local Const $_ARRAYCONSTANT_LVM_GETCOLUMNWIDTH = (0x1000 + 29)
    Local Const $_ARRAYCONSTANT_LVM_GETITEMCOUNT = (0x1000 + 4)
    Local Const $_ARRAYCONSTANT_LVM_GETITEMSTATE = (0x1000 + 44)
    Local Const $_ARRAYCONSTANT_LVM_SETEXTENDEDLISTVIEWSTYLE = (0x1000 + 54)
    Local Const $_ARRAYCONSTANT_LVS_EX_FULLROWSELECT = 0x20
    Local Const $_ARRAYCONSTANT_LVS_EX_GRIDLINES = 0x1
    Local Const $_ARRAYCONSTANT_LVS_SHOWSELALWAYS = 0x8
    Local Const $_ARRAYCONSTANT_WS_EX_CLIENTEDGE = 0x0200
    Local Const $_ARRAYCONSTANT_WS_MAXIMIZEBOX = 0x00010000
    Local Const $_ARRAYCONSTANT_WS_MINIMIZEBOX = 0x00020000
    Local Const $_ARRAYCONSTANT_WS_SIZEBOX = 0x00040000

    ; Set interface up
    Local $iWidth = 640, $iHeight = 480
    Local $hGUI = GUICreate($sTitle, $iWidth, $iHeight, Default, Default, BitOR($_ARRAYCONSTANT_WS_SIZEBOX, $_ARRAYCONSTANT_WS_MINIMIZEBOX, $_ARRAYCONSTANT_WS_MAXIMIZEBOX))
    Local $aiGUISize = WinGetClientSize($hGUI)
    Local $hListView = GUICtrlCreateListView($sHeader, 0, 0, $aiGUISize[0], $aiGUISize[1] - 26, $_ARRAYCONSTANT_LVS_SHOWSELALWAYS)
    Local $hCopy = GUICtrlCreateButton("Copy Selected", 3, $aiGUISize[1] - 23, $aiGUISize[0] - 6, 20)
    GUICtrlSetResizing($hListView, $_ARRAYCONSTANT_GUI_DOCKBORDERS)
    GUICtrlSetResizing($hCopy, $_ARRAYCONSTANT_GUI_DOCKLEFT + $_ARRAYCONSTANT_GUI_DOCKRIGHT + $_ARRAYCONSTANT_GUI_DOCKBOTTOM + $_ARRAYCONSTANT_GUI_DOCKHEIGHT)
    GUICtrlSendMsg($hListView, $_ARRAYCONSTANT_LVM_SETEXTENDEDLISTVIEWSTYLE, $_ARRAYCONSTANT_LVS_EX_GRIDLINES, $_ARRAYCONSTANT_LVS_EX_GRIDLINES)
    GUICtrlSendMsg($hListView, $_ARRAYCONSTANT_LVM_SETEXTENDEDLISTVIEWSTYLE, $_ARRAYCONSTANT_LVS_EX_FULLROWSELECT, $_ARRAYCONSTANT_LVS_EX_FULLROWSELECT)
    GUICtrlSendMsg($hListView, $_ARRAYCONSTANT_LVM_SETEXTENDEDLISTVIEWSTYLE, $_ARRAYCONSTANT_WS_EX_CLIENTEDGE, $_ARRAYCONSTANT_WS_EX_CLIENTEDGE)

    ; Fill listview
    For $i = 0 To $iUBound
        GUICtrlCreateListViewItem($avArrayText[$i], $hListView)
    Next

    ; adjust window width
    $iWidth = 0
    For $i = 0 To $iSubMax + 1
        $iWidth += GUICtrlSendMsg($hListView, $_ARRAYCONSTANT_LVM_GETCOLUMNWIDTH, $i, 0)
    Next
    If $iWidth < 250 Then $iWidth = 230
    $iWidth += 20

    If $iWidth > @DesktopWidth Then $iWidth = @DesktopWidth - 100

    WinMove($hGUI, "", (@DesktopWidth - $iWidth) / 2, Default, $iWidth)

    ; Show dialog
    GUISetState(@SW_SHOW, $hGUI)

    While 1
        Switch GUIGetMsg()
            Case $_ARRAYCONSTANT_GUI_EVENT_CLOSE
                ExitLoop

            Case $hCopy
                Local $sClip = ""

                ; Get selected indices [ _GUICtrlListView_GetSelectedIndices($hListView, True) ]
                Local $aiCurItems[1] = [0]
                For $i = 0 To GUICtrlSendMsg($hListView, $_ARRAYCONSTANT_LVM_GETITEMCOUNT, 0, 0)
                    If GUICtrlSendMsg($hListView, $_ARRAYCONSTANT_LVM_GETITEMSTATE, $i, 0x2) Then
                        $aiCurItems[0] += 1
                        ReDim $aiCurItems[$aiCurItems[0] + 1]
                        $aiCurItems[$aiCurItems[0]] = $i
                    EndIf
                Next

                ; Generate clipboard text
                If Not $aiCurItems[0] Then
                    For $sItem In $avArrayText
                        $sClip &= $sItem & @CRLF
                    Next
                Else
                    For $i = 1 To UBound($aiCurItems) - 1
                        $sClip &= $avArrayText[$aiCurItems[$i]] & @CRLF
                    Next
                EndIf
                ClipPut($sClip)
        EndSwitch
    WEnd
    GUIDelete($hGUI)

    Opt("GUIOnEventMode", $iOnEventMode)
    Opt("GUIDataSeparatorChar", $sDataSeparatorChar)

    Return 1
EndFunc   ;==>_ArrayDisplayModified

Underdogger · January 17, 2013

Thanks Malkey I will take a look at it :rambo:

Underdogger · January 17, 2013

By the way,how to change the status of this topic to [ALREADY SOLVE]?

water · January 17, 2013

Go to the first post in the thread, open the Full Editor and change the thread title.

guinness · January 17, 2013

Thanks Malkey I will take a look at it

Just use theirs, it works. Edited January 17, 2013 by guinness

Sign In

[SOLVE] Is possible to Hide [index] in _ArrayDisplay?

Recommended Posts

Underdogger

guinness

water

Underdogger

guinness

Underdogger

water

Underdogger

water

guinness

Underdogger

water

guinness

Underdogger

water

Malkey

Underdogger

Underdogger

water

guinness

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members

Browse

AutoIt Resources

Release

Beta