Help File/Documentation Issues. (Discussion Only)

[jpm]

Yes there is a pb scrollbars example have not been update I will fix them

[argumentum]

; SQLite3 dll version must match

#include <MsgBoxConstants.au3>
#include <SQLite.au3>
#include <SQLite.dll.au3>

Global $sSQliteDll = _SQLite_Startup()
If @error Then
    If MsgBox($MB_SYSTEMMODAL + $MB_YESNO + $MB_DEFBUTTON2, "SQLite Error", (@AutoItX64 ? 'SQLite3_x64.dll' : 'SQLite3.dll') & " Can't be Loaded!" & @CRLF & @CRLF & _
            "Not FOUND in @ScriptDir, @WorkingDir," & @CRLF & @TAB & "@LocalAppDataDir\AutoIt v3\SQLite," & @CRLF & @TAB & "@SystemDir or @WindowsDir" & _
            @CRLF & @CRLF & "Would you like to go to the site to download it ?") = $IDYES Then ShellExecute("https://www.sqlite.org/download.html")
    Exit 4
EndIf

MsgBox($MB_SYSTEMMODAL, (@AutoItX64 ? 'SQLite3_x64.dll' : 'SQLite3.dll') & " Loaded", $sSQliteDll & " (v" & _SQLite_LibVersion() & ")")
ConsoleWrite("_SQLite_LibVersion=" & _SQLite_LibVersion() & @CRLF)
_SQLite_Shutdown()

This "Example 1" will be better than the current one.
If the DLL is not there it takes you to the site for download.
 

[argumentum]

..to be or not to be..

As the well read and organized coder that I am ( or aim to be  ) I read the WiKi. Add button(s) with $idRun, and $idCancel to have $idCntrlName = ...
Then I run the script and I get "error: $idCancel previously declared as a 'Const'." and I open the offending file and I read:

...
Global Const $MB_SERVICE_NOTIFICATION = 0x00200000 ; The caller is a service notifying the user of an event.

Global Const $MB_RIGHTJUSTIFIED = $MB_RIGHT ; Do not use, see $MB_RIGHT. Included for backwards compatibility.

; Indicates the button selected in the message box
Global Const $IDTIMEOUT = -1 ; The message box timed out
Global Const $IDOK = 1 ; OK button was selected
Global Const $IDCANCEL = 2 ; Cancel button was selected
...

... I found it, "funny" ? 🤷‍♂️

[donnyh13]

To help some unnecessary confusion, I was thinking a small note added to OnAutoItExitRegister may be handy:

Quote

Any declared parameters in a function called by OnAutoItExitRegister are treated as undeclared when called, and will cause a crash if used by the function. Use @NumParams or IsDeclared if a function with parameters must be used.

Best Regards

Donny

[argumentum]

..it'd be better to say that "the function shall not have parameters", same as with AdlibRegister().
I can not see a reason where "if a function with parameters must be used." other than convenience 🤔

[donnyh13]

Good points @argumentum,

Quote

The function called must not have any parameters.

 

[argumentum]

JPM already patched it all with our inputs. So, coming soon ( some day ) to a beta ( or alpha ) near you   

Edited Wednesday at 01:40 AM by argumentum

[jpm]

I hope I did the right job ...

[donnyh13]

In the examples of StdoutRead and StdioClose, the following lines occur:

; Use StringSplit to split the output of StdoutRead to an array. All carriage returns (@CRLF) are stripped and @CRLF (line feed) is used as the delimiter.
    Local $aArray = StringSplit(StringTrimRight(StringStripCR($sOutput), StringLen(@LF)), @LF)

The description, I think, is slightly inaccurate:

Quote

All carriage returns (@CRLF) are stripped and @CRLF (line feed) is used as the delimiter.

It should read:

Quote

All carriage returns (@CR) are stripped and @LF (line feed) is used as the delimiter.

Thanks for your work jpm,

Best Regards,

Donny

[mLipok]

I was working with LV justification.

Here is my modified _GUICtrlListView_JustifyColumn.au3 :

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>
#include <ListViewConstants.au3>
#include <WindowsStylesConstants.au3>

Example()

Func Example()
    GUICreate("ListView Justify  (v" & @AutoItVersion & ")", 400, 300)
    Local $idListview
    If $IDNO = MsgBox($MB_YESNO + $MB_TOPMOST + $MB_ICONQUESTION + $MB_DEFBUTTON2, "Question", _
            "Right to Left Text (RTL Layout) ?") Then
        $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    Else
        $idListview = GUICtrlCreateListView("", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_SINGLESEL), $WS_EX_LAYOUTRTL)
    EndIf

    GUISetState(@SW_SHOW)

    ; Set ANSI format
;~     _GUICtrlListView_SetUnicodeFormat($idListview, False)

    ; Add columns
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 2", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 3", 100)

    ; Change column
    Local $aInfo, $sInformation = ''
    For $i = 0 To 2
        $aInfo = _GUICtrlListView_GetColumn($idListview, $i)
        $sInformation &= "Column " & $i & " justification: " & $aInfo[0] & @CRLF
    Next

    MsgBox($MB_SYSTEMMODAL, "Information before justification", $sInformation)
    $sInformation = ''

    _GUICtrlListView_JustifyColumn($idListview, 0, 0)
    _GUICtrlListView_JustifyColumn($idListview, 1, 1)
    _GUICtrlListView_JustifyColumn($idListview, 2, 2)

    For $i = 0 To 2
        $aInfo = _GUICtrlListView_GetColumn($idListview, $i)
        $sInformation &= "Column " & $i & " justification: " & $aInfo[0] & @CRLF
    Next

    MsgBox($MB_SYSTEMMODAL, "Information after justification", $sInformation)

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

Help file says:

$iAlign [optional] Alignment of the column header and the subitem text in the column:
    0 - Text is left aligned
    1 - Text is right aligned
    2 - Text is centered

But the description is only correct for the LTR layout, and if you're using the RTL layout, the description seems misleading.

Any ideas on how to improve the description?

maybe just:

$iAlign [optional] Alignment of the column header and the subitem text in the column:
    0 - Text is left aligned for LTR Layout, and right aligned for RTL Layout
    1 - Text is right aligned for LTR Layout, and left aligned for RTL Layout
    2 - Text is centered

 

Edited Friday at 10:33 PM by mLipok