self_update

[gcue]

hello world.

I am trying to do a self updating script.  I see several examples which use a batch file and taskkill to end the current script and copy the new one.  however, with windows 7 the batch file has to run with elevated rights to taskkill the process successfully and the user running the script may not necessarily have those rights.

has anyone found another way to get around this?

thanks =>

[water]

Is it necessary to update the running script?

You should separate data and code. Data should be changeable by the user, code changes should only be made and tested by a coder/scripter/programmer.

Can you describe your problem in more detail?

[gcue]

there really isnt data.. so the script changes reflect bug fixes or enhancements to the functionality.

i think i may have thought of a way.

expandcollapse popup

Func Check_Updates()
 
$remote_version = FileGetVersion($tools_dir & "\" & @ScriptName)
$local_version = FileGetVersion(@ScriptFullPath)
 
$compare_versions = _VersionCompare($local_version, $remote_version)
 
If Not @error Then
If $compare_versions = -1 Then
Get_Update()
EndIf
EndIf
 
EndFunc   ;==>Check_Updates
 
Func Get_Update()
 
$remote_file = $tools_dir & "\" & @ScriptName
 
$script_name = StringReplace(@ScriptName, ".exe", "")
$script_name = StringStripWS($script_name, 8)
$batch_file = @TempDir & "\update_" & $script_name & ".cmd"
 
If FileExists($batch_file) Then
FileDelete($batch_file)
EndIf
 
$command = '@echo off' & @CRLF
$command &= '' & @CRLF
$command &= 'ping localhost -n 5 > nul' & @CRLF
$command &= 'del /f /q "' & @ScriptFullPath & '"' & @CRLF
$command &= 'copy /y "' & $remote_file & '" "'& @ScriptFullPath & '"' & @CRLF
$command &= @ScriptFullPath & @CRLF
$command &= 'del %0'
 
FileWrite($batch_file, $command)
 
Run($batch_file, @ScriptDir, @SW_HIDE)
 
_Exit()
 
EndFunc   ;==>Get_Update

[BrewManNH]

Better idea would be to have a separate script that downloads the updates and then copies the files to the installation location. Run the update script, and exit the current script right after you do that. Then you don't need to force close the main script as it's already closed.

[gcue]

where would the seperate script reside?  copy it to the pc using fileinstall and just leave it there?  thats an idea too.. 

[water]

That would be a simple and reliable way to solve your problem.

If needed you could delete the update script if no update is needed. So no traces are left on the users PC.

[gcue]

self delete?  thats through batch file tho right?  need the elevated rights to taskkill it first?

or

delete through parent script.  and only delete it if theres no updates - otherwise let it linger on their pc ;-)

[water]

The idea is:

Check if an update is available

If yes:

• Fileinstall the Update script
• start the update script
• exit the main script
• Now the update is being done by the update script
• call >_SelfDelete to delete the update script

[gcue]

good process except that selfdelete uses taskkill - need elevated rights for that =)

[guinness]

There is a _SelfUpdate() in my signature.

[water]

There are other SelfDelete solutions available that simple write a BAT file to disk, call this bat file and exit.

Shouldn't need elevated permissions.

[water]

There is a _SelfUpdate() in my signature.

Your _SelfUpdate uses TaskKill which needs elevated permissions which isn't possible for gcue according to his OP.

[gcue]

There are other SelfDelete solutions available that simple write a BAT file to disk, call this bat file and exit.

Shouldn't need elevated permissions.

 

good point =)

thank you gentlemen

[kaotkbliss]

Here's what I do if it helps at all

I have an installer, packed in the installer is the main script.

The main script (when installed) can search for updates by downloading a txt file in my dropbox and comparing the current version with the last version listed in my text file. 

If there is a newer version in the text file, the main program prompts a download.

The new download is the main program packed in an installer.

The installer (when run) ProcessCloses any instances of the main program running and extracts the new files.

Then it starts the (new) main program and exits itself.

Update done.

[guinness]

Your _SelfUpdate uses TaskKill which needs elevated permissions which isn't possible for gcue according to his OP.

They can delete that line if they so wish.

[ZacUSNYR]

I do a version updating script here for our users for launching our in house web based accounting system and our legacy term window system.

I have two files, the launcher and an update script. I tossed a file (ini file which includes the versions of both on the network, just for information.  If this file exists I allow the script to version check both).  This allows me to remove this file to stop any updating if it goes bonkers.

On startup I check the local update.exe version against the server - this is just a filecopy.  I also check the launcher file against the server version, if the server one is new I copy it over to a temp name, launch the update.exe with a parameter (just so you can't run it by itself) and close out of the launcher.  When update.exe starts, it looks for the process that you pass to it, when that terms, It replaces the launcher file with the temp file it downloaded.  I cache the version in an ini file local as well so I can version compare to find out if it's first run, that way I can do first run versioning stuff (sometimes they download a new icon or I change an ODBC connection).

Works really well, i've done over a dozen version changes with no oddball behavior.

[corgano]

 

The idea is:

Check if an update is available

If yes:

• Fileinstall the Update script
• start the update script
• exit the main script
• Now the update is being done by the update script
• call >_SelfDelete to delete the update script

Why not

Parent fileinstall update script

parent close

update script updates

update starts parent

update script closes as parent sleeps for an amount of time (~200ms)

parent deletes update script

Or you could have the update script launch the parent script with a command line peram that tells the parent to delete it and then close, otherwise parent runs normally

Edited November 13, 2013 by corgano

[water]

Great. That seems to be the simplest solution to the OPs "problem"

[gcue]

hmm i am getting "update failed to download" (from updater script) approximately 1 out of 10 attempts.  in addition to the error, the parent script dissapears and the updater script remains.

works fine the other 9 times - problem with logic?

parent script

Func Check_Updates()
 
$remote_version = FileGetVersion($tools_dir & "\" & @ScriptName)
$local_version = FileGetVersion(@ScriptFullPath)
 
$compare_versions = _VersionCompare($local_version, $remote_version)
 
If Not @error Then
If $compare_versions = -1 Then
FileInstall("C:\updater.exe", @TempDir & "\updater.exe", 1)
Get_Update()
EndIf
EndIf
 
EndFunc   ;==>Check_Updates
 
Func Get_Update()
 
If FileExists(@TempDir & "\updater.exe") Then
$remote_file = $tools_dir & "\" & @ScriptName
 
Run(@TempDir & '\updater.exe -remote_file "' & $remote_file & '" -local_file "' & @ScriptFullPath & '" -process_exe "' & @ScriptName & '"')
_Exit() 
EndIf
 
EndFunc   ;==>Get_Update

updater script

expandcollapse popup

#region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=updater.ico
#AutoIt3Wrapper_Outfile=updater.exe
#AutoIt3Wrapper_Run_Tidy=y
#endregion ;**** Directives created by AutoIt3Wrapper_GUI ****
 
#include <WindowsConstants.au3>
 
Global $msg_error = 262160
 
Opt("TrayOnEventMode", 1)
Opt("TrayMenuMode", 1 + 2)
TrayCreateItem("Exit")
TrayItemSetOnEvent(-1, "_Exit")
 
TraySetToolTip(StringReplace(@ScriptName, ".exe", ""))
 
TraySetState(1)
 
If $CmdLine[0] > 0 Then
For $i = 1 To $CmdLine[0]
Select
Case $CmdLine[$i] = "-remote_file"
$remote_file = $CmdLine[$i + 1]
Case $CmdLine[$i] = "-local_file"
$local_file = $CmdLine[$i + 1]
Case $CmdLine[$i] = "-process_exe"
$process_exe = $CmdLine[$i + 1]
 
UpdateScript($local_file, $remote_file, $process_exe)
EndSelect
Next
EndIf
 
Func UpdateScript($local_file, $remote_file, $process_exe)
 
$process_name = StringReplace($process_exe, ".exe", "")
 
$progress = GUICreate("Please Wait", 200, 70, -1, -1, $WS_EX_MDICHILD, $WS_EX_TOPMOST)
GUISetFont(10, 600)
GUICtrlCreateLabel("Updating...", 10, 10)
 
GUISetState()
 
$log = @TempDir & "\log.txt"
 
$close = Kill_Process($process_exe)
 
If $close = 1 Then
$copy = FileCopy($remote_file, $local_file, 1)
 
If $copy = 0 Then
$copy = FileCopy($remote_file, $local_file, 1)
 
If $copy = 0 Then
FileWrite($log, $close & @CRLF & $copy & @CRLF & $remote_file & @CRLF & $local_file)
MsgBox($msg_error, $process_name, "Update failed to download.")
_Exit()
EndIf
EndIf
 
ShellExecute($local_file)
Else
MsgBox($msg_error, $process_name, "Unable to exit " & $process_name & "." & @CRLF & _
"" & @CRLF & _
"Update canceled.")
EndIf
 
Self_Delete()
 
_Exit()
 
EndFunc   ;==>UpdateScript
 
Func Kill_Process($process_exe)
 
For $x = 1 To 10
If ProcessExists($process_exe) Then
ProcessClose($process_exe)
Else
ExitLoop
EndIf
Next
 
$close = 1
 
If ProcessExists($process_exe) Then
$close = ProcessWaitClose($process_exe, 3)
EndIf
 
Return $close
 
EndFunc   ;==>Kill_Process
 
Func Self_Delete()
 
$batch_file = @TempDir & "\delete_updater.cmd"
 
If FileExists($batch_file) Then
FileDelete($batch_file)
EndIf
 
$command = '@echo off' & @CRLF
$command &= '' & @CRLF
$command &= 'ping localhost -n 3 > nul' & @CRLF
$command &= 'del /f /q "' & @ScriptFullPath & '"' & @CRLF
$command &= 'del %0'
 
FileWrite($batch_file, $command)
 
Run($batch_file, @ScriptDir, @SW_HIDE)
 
EndFunc   ;==>Self_Delete
 
Func _Exit()
Exit
EndFunc   ;==>_Exit

Edited November 13, 2013 by gcue

[gcue]

the log shows the right paths as expected.  so based off the return values, the parent process is terminated successfully and the copy command fails twice.

makes sense that the updater file remains because it never goes through the self_delete function but dont understand why the parent script disappears.

if the copy fails when replacing a file, does it delete the original one anyway?