Operators in a variable

[MyEarth]

Hello,

I'm stuck with a probably stupid problem but my mind can't find an easier solution

I have a GUI, in this GUI the user can select the operator type, based on the operator type do another Func()

I can't put the operator in a variable for "syntax error", how can i resolve?

$Test = 3
$Operator = ""

;User select the operator, example:
$Operator = "<"

;~ If $Test $Operator 1 Then _Func() ;WRONG
If $Test < 1 Then _Func()

Func _Func()
    ;do many thing
EndFunc

Edited June 27, 2014 by MyEarth

[water]

You need to test for any possible operator:

If $Operator = "<" Then ...

And so on.

[guinness]

Little but of laterally thinking is required.

Switch $sOperator
    Case '<'
        If $iTest < 1 Then ...
    
    Case '>'
        If $iTest > 1 Then ...
EndSwitch

[MyEarth]

But there are many operators combination

There isn't any alternative?

[water]

No.

[guinness]

There aren't that many combinations, and I would use an integer value to correspond to the operator rather than a string representation. If you're using a combo box then the initial index is zero, so it's a lot easier to manage with this approach.

Local Enum $OP_LESSTHAN, $OP_GREATERTHAN, $OP_GREATERTHANEQUAL
Switch $iOperator
    Case $OP_LESSTHAN
        If $iTest < 1 Then ...
    
    Case $OP_GREATERTHAN
        If $iTest > 1 Then ...
            
    Case $OP_GREATERTHANEQUAL
        If $iTest >= 1 Then ...
EndSwitch

[Malkey]

Maybe this method.

$Test = 3
$Operator = ""

;User select the operator, example:
$Operator = ">"

If Execute($Test & $Operator & 1) Then _Func() ;WORKS
;~If $Test > 1 Then _Func()

Func _Func()
    MsgBox(0, "", "do many thing", 1)
EndFunc   ;==>_Func

[jguinch]

Well,

Local $Test = 10
Local $aOperators[] = [ "<", "<=", ">", ">=", "=" ]
Local $compareTo = 5

For $i = 0 To UBound($aOperators) - 1
    If Execute($test & $aOperators[$i] & $compareTo) Then ConsoleWrite($test & " " &  $aOperators[$i] & " " & $compareTo & @CRLF)
Next

Sorry, i didn't see Malkey's code

 

Or this, cleaner :

ConsoleWrite( _Compare(5, "<" , 10) )

Func _Compare($a, $operator, $b)
    Return Execute(Number($a) & $operator & Number($b) )
Endfunc

Edited June 27, 2014 by jguinch

[Mat]

You should be using Number() on the variables to execute, or else you could be open to an injection attack.

If you want an alternative to switching or execute, then this is how I'd do it in other languages:

#include <Array.au3>

_Apply(5, 2, ">")


Func _Apply($a, $b, $operator)
    Local Static  $aOps[3][2] = [["<", Lessthan], [">", GreaterThan], ["=", Equal]]

    Local $index = _ArraySearch($aOps, $operator, 0, 0, 0, 0, 1, 0)
    If @error Then Return SetError(1, 0, False) ; Operator not recognised.

    Return $aOps[$index][1]($a, $b)
EndFunc

Func LessThan($a, $b)
    Return $a < $b
EndFunc
Func GreaterThan($a, $b)
    Return $a > $b
EndFunc
Func Equal($a, $b)
    Return $a = $b
EndFunc