_StringShuffle

[jguinch]

Here is a small function to shuffle a string :

ConsoleWrite( _StringShuffle("I like AutoIt !") )
 
Func _StringShuffle($sString)
    For $i = StringLen($sString) - 1 To 0 Step -1
        $sString = StringRegExpReplace($sString, "(?s)(.{" & Random(0, $i, 1) & "})(.)(.*)", "$1$3$2")
    Next
    Return $sString
EndFunc

It could be useful ?

[UEZ]

Nice approach using regex. 

 

Here the array version additionally:

#include <Array.au3>

$sText = "_ArrayShuffle shuffles selected rows of 1D or 2D arrays - can be limited to a specific column in 2D arrays."

$t = TimerInit()
ConsoleWrite( _StringShuffle($sText) & @CRLF )
ConsoleWrite(TimerDiff($t) & @CRLF & @CRLF)

$t = TimerInit()
ConsoleWrite( _StringShuffle2($sText) & @CRLF )
ConsoleWrite(TimerDiff($t) & @CRLF)


Func _StringShuffle($sString)
    For $i = StringLen($sString) - 1 To 0 Step -1
        $sString = StringRegExpReplace($sString, "(?s)(.{" & Random(0, $i, 1) & "})(.)(.*)", "$1$3$2")
    Next
    Return $sString
EndFunc

Func _StringShuffle2($sString)
    Local $a = StringSplit($sString, "", 2)
    _ArrayShuffle($a)
    Return _ArrayToString($a, "")
EndFunc

[guinness]

Very nice.

[iamtheky]

if _stringshuffle --> stringsplit is faster than stringsplit --> _arrayshuffle

and if there is a way you could add a parameter for a delimeter (e.g. so you only shuffle the things between commas, such that the string can be still be split on the commas afterward and result with elements rearranged).  I could see that being used widely.

Edited March 12, 2015 by boththose

[jguinch]

What about this array-based version ? Including separator option, using StringSplit and faster than _ArrayShuffle :

#include <Array.au3>

$sText = "_ArrayShuffle shuffles ,selected rows of 1D or 2D arrays, - can be limited to a specific column in 2D arrays."

$t = TimerInit()
ConsoleWrite( _StringShuffle($sText) & @CRLF )
ConsoleWrite(TimerDiff($t) & @CRLF & @CRLF)

$t = TimerInit()
ConsoleWrite( _StringShuffle2($sText) & @CRLF )
ConsoleWrite(TimerDiff($t) & @CRLF)


Func _StringShuffle($sString, $sDelimiter = "")
    Local $aString = StringSplit($sString, $sDelimiter, 2)
    Local $sOutput

    Local $iUbound = UBound($aString) - 1

    For $i = 0 To $iUbound
        $iRand = ( $i = $iUbound ? $iUbound : Random($i, $iUbound, 1) )
        $iPrev = $aString[$iRand]
        $aString[$iRand] = $aString[$i]

        $sOutput &= $iPrev
    Next
    
    Return $sOutput

EndFunc

Func _StringShuffle2($sString)
    Local $a = StringSplit($sString, "", 2)
    _ArrayShuffle($a)
    Return _ArrayToString($a, "")
EndFunc

Edited March 12, 2015 by jguinch

[UEZ]

Well, in principle the _ArrayShuffle function for 1D arrays is the same as what you did. The difference is the overhead within the function.

That's the reason why I used it and it looks smaller than to have the loop in the function.

Edited March 12, 2015 by UEZ

[czardas]

Nice example jguinch. I was wondering if the technique could be applied to array syntax such as '[[1,2],[3,4]]'. I think it would be quite a challenge but also a very neat trick. My (old) multidimensional shuffle seems to contain so much bloat and is currently limited to 11 dimensions. If anyone is interested it's here:

I remember it driving me crazy trying to figure it out.

Edited March 12, 2015 by czardas

[iamtheky]

a sporting effort with powershell

#include<AutoItConstants.au3>
#include <Array.au3>

$Str = "shuffling"

$iPID = run("powershell -join ('" & _ArrayToString(stringsplit($Str , "" , 2) , "','") & "' | Get-Random -Count " & StringLen($Str) & ")" , "" , @SW_HIDE , $stdout_child)

$sOutput = ""

     While 1
        $sOutput &= StdoutRead($iPID)
        If @error Then ExitLoop
        WEnd

msgbox(0, '' , $sOutput)