StringRegExp - example for: $STR_REGEXPARRAYGLOBALFULLMATCH

[mLipok]

#include <Array.au3>

If @Compiled Then Exit

Global Enum $FUNC_OUTER, $FUNC_NAME, $FUNC_PARAM, $FUNC_INNER

_Example()
Func _Example()
    Local $sIncludeDir = StringTrimRight(@AutoItExe, StringLen('AutoIt3.exe')) & 'Include\'

    Local $aOuterArray = _GetFunctionsToArray($sIncludeDir & 'Color.au3')
    If Not @error Then
        For $iOuter_idx = 0 To UBound($aOuterArray) - 1
            _ArrayDisplay($aOuterArray[$iOuter_idx], ($aOuterArray[$iOuter_idx])[$FUNC_NAME])
        Next
    EndIf
EndFunc   ;==>_Example

Func _GetFunctionsToArray($sUDF_FileFullPath)
    Local $sUDFContent = FileRead($sUDF_FileFullPath)
    Local $aResult = StringRegExp($sUDFContent, '(?is)\RFunc (.*?)\((.*?)\)\v\R(.*?)\REndFunc', $STR_REGEXPARRAYGLOBALFULLMATCH)
    Return SetError(@error, @extended, $aResult)
EndFunc   ;==>_GetFunctionsToArray

 

Edited January 27, 2016 by mLipok
typo in variable name

[GMK]

Another variation:

#include <Array.au3>

If @Compiled Then Exit

_Example()
Func _Example()
    Local $sIncludeDir = StringLeft(@AutoItExe, StringInStr(@AutoItExe, '\', 0, -1)) & 'Include\'

    Local $aArray = _GetFunctionsToArray($sIncludeDir & 'Color.au3')
    _ArrayDisplay($aArray)
EndFunc   ;==>_Example

Func _GetFunctionsToArray($sUDF_FileFullPath)
    Local $sUDFContent = FileRead($sUDF_FileFullPath)
    Local $aResult = _StringRegExp2D($sUDFContent, '(?is)\RFunc (.*?)\((.*?)\)\v\R(.*?)\REndFunc')
    Return SetError(@error, @extended, $aResult)
EndFunc   ;==>_GetFunctionsToArray

Func _StringRegExp2D($sTest, $sPattern)
    Local $avSRE = StringRegExp($sTest, $sPattern, $STR_REGEXPARRAYGLOBALFULLMATCH)
    If @error Then Return SetError(@error, @extended, 0)
    Local $iSRERows = UBound($avSRE)
    Local $avReturn[$iSRERows][0]
    For $iRow = 0 To $iSRERows - 1
        Local $avCols = $avSRE[$iRow]
        Local $iCols = UBound($avCols)
        If UBound($avReturn, 2) < $iCols - 1 Then ReDim $avReturn[$iSRERows][$iCols - 1]
        For $iCol = 1 To $iCols - 1
            $avReturn[$iRow][$iCol - 1] = $avCols[$iCol]
        Next
    Next
    Return $avReturn
EndFunc   ;==>_StringRegExp2D

 

Edited August 26, 2016 by GMK
Edited for speed; added error checking