Example: Console Debug

[mLipok]

expandcollapse popup

; IMHO:
; Each "Logging" function should store and restore @error and @extended
; I think that as each "Logging" function should be transparent to the script
; The following example script shows what I mean

_main()
Exit

Func _main()
    ; this following line is only for keep Clean in SciTE console (Output Pane)
    ConsoleWrite(@CRLF & @CRLF & '+ >>>> SCRIPT START' & @CRLF)

    ; here you start some function
    _SomeExampleFunction()

    ; as this "Logging" function store and restore @error and @extended (implemented in this example)
    ; you can still check "correct"   @error and @extended   values
    _DebugErrExt('Outside function')

    StringReplace('test', 't', 'x')
    _DebugErrExt('Testing StringReplace')

    ; this following line is only for keep Clean in SciTE console (Output Pane)
    ConsoleWrite('+ >>>> SCRIPT END' & @CRLF & @CRLF & @CRLF)

EndFunc   ;==>_main

Func _SomeExampleFunction()
    Local $vResult = StringRegExp('test', '(?i', 3)
    _DebugInfo('Some description') ; will write message to the console in any case
    _DebugErrExt('Inside function') ; will write message to the console in case of @error or @extended

    ; as this "Logging" function store and restore @error and @extended (implemented in this example)
    ; you can still return "correct"   @error and @extended   values
    Return SetError(@error, @extended, $vResult)

EndFunc   ;==>_SomeExampleFunction

Func _DebugInfo($sMessage, Const $iError = @error, Const $iExtended = @extended)
    ConsoleWrite($sMessage & @CRLF)

    ; each "Logging" function should store and restore @error and @extended
    Return SetError($iError, $iExtended, Null)
EndFunc   ;==>_DebugInfo

Func _DebugErrExt($sMessage, Const $iError = @error, Const $iExtended = @extended)
    If $iError Then
        ConsoleWrite('! ERR=' & $iError & ' EXT=' & $iExtended & ' :  ' & $sMessage & @CRLF)
    ElseIf $iExtended Then
        ConsoleWrite('> EXT=' & $iExtended & ' :  ' & $sMessage & @CRLF)
    EndIf

    ; each "Logging" function should store and restore @error and @extended
    Return SetError($iError, $iExtended, Null)
EndFunc   ;==>_DebugErrExt

 

[JohnOne]

But does @error and @extended get set to 0 the instant you hit "Func" line?

[mLipok]

Do you ask about this concept:

Func _DebugInfo($sMessage, Const $iError = @error, Const $iExtended = @extended, Const $iScriptLineNumber = @ScriptLineNumber)
    ConsoleWrite('INFO: LINE=' & $iScriptLineNumber & ' : ' & $sMessage & @CRLF)

    ; each "Logging" function should store and restore @error and @extended
    Return SetError($iError, $iExtended, Null)
EndFunc   ;==>_DebugInfo

Func _DebugErrExt($sMessage, Const $iError = @error, Const $iExtended = @extended, Const $iScriptLineNumber = @ScriptLineNumber)
    If $iError Then
        ConsoleWrite('! ERR=' & $iError & ' EXT=' & $iExtended & ' LINE=' & $iScriptLineNumber & ' :  ' & $sMessage & @CRLF)
    ElseIf $iExtended Then
        ConsoleWrite('> EXT=' & $iExtended & ' LINE=' & $iScriptLineNumber & ' :  ' & $sMessage & @CRLF)
    EndIf

    ; each "Logging" function should store and restore @error and @extended
    Return SetError($iError, $iExtended, Null)
EndFunc   ;==>_DebugErrExt

?

 

Edited April 7, 2016 by mLipok
script concept changed

[mLipok]

@JohnOne Can you reword or explain your question ?

Edited April 7, 2016 by mLipok

[JohnOne]

The instant your code enters a function, any function either native or udf, @error and @extended are both set to 0 internally.

So unless you pass @error and @extended as arguments to those function you made, they don't mean or change anything at all.

[mLipok]

I can say that this function is a kind of workaround to the default Function behavior.
As they store nad restore @error and @extended vaules. I mean this macro values are exactly the same before and after calling this function.

 

Just for note: 
This function do not need to pass @error or @extended to function manually as this is default values for this parameteres.
 

Edited April 7, 2016 by mLipok

[mLipok]

57 minutes ago, JohnOne said:

@error and @extended are both set to 0 internally.

 

Do you mean this:
https://www.autoitscript.com/autoit3/docs/function_notes.htm

Quote

........
@error is always set to 0 when entering in a function.
........

??

I check it on SVN and this is little changed for next beta/release, here is current description:

Quote

........ @error will be reset to 0 when entering the next function. 
........

But I think even this modified description is not quite true.
I think It should be like this:

Quote

........ @error will be reset to 0 after entering the next function. 
........

[JohnOne]

Yes, you are correct, and I agree about the should be.

_SetError()
Test()

Func Test($ierror = @error)
    MsgBox(0,@error,$ierror)
EndFunc   ;==>_Sleep

Func _SetError()
    SetError(2)
EndFunc   ;==>_SetError

 

[mLipok]

Modified/merged example:

expandcollapse popup

; IMHO:
; Each "Logging" function should store and restore @error and @extended
; I think that as each "Logging" function should be transparent to the script
; The following example script shows what I mean

_main()
Exit

Func _main()
    ; this following line is only for keep Clean in SciTE console (Output Pane)
    ConsoleWrite(@CRLF & @CRLF & '+ >>>> SCRIPT START' & @CRLF)

    ; here you start some function
    _SomeExampleFunction()

    ; as this "Logging" function store and restore @error and @extended (implemented in this example)
    ; you can still check "correct"   @error and @extended   values
    _DebugErrExt('Outside function')

    StringReplace('test', 't', 'x')
    _DebugErrExt('Testing StringReplace')

    ; this following line is only for keep Clean in SciTE console (Output Pane)
    ConsoleWrite('+ >>>> SCRIPT END' & @CRLF & @CRLF & @CRLF)

EndFunc   ;==>_main

Func _SomeExampleFunction()
    Local $vResult = StringRegExp('test', '(?i', 3)
    _DebugInfo('Some description') ; will write message to the console in any case
    _DebugErrExt('Inside function') ; will write message to the console in case of @error or @extended

    ; as this "Logging" function store and restore @error and @extended (implemented in this example)
    ; you can still return "correct"   @error and @extended   values
    Return SetError(@error, @extended, $vResult)

EndFunc   ;==>_SomeExampleFunction

Func _DebugInfo($sMessage, Const $iError = @error, Const $iExtended = @extended, Const $iScriptLineNumber = @ScriptLineNumber)
    ConsoleWrite('INFO: LINE=' & $iScriptLineNumber & ' : ' & $sMessage & @CRLF)

    ; each "Logging" function should store and restore @error and @extended
    Return SetError($iError, $iExtended, Null)
EndFunc   ;==>_DebugInfo

Func _DebugErrExt($sMessage, Const $iError = @error, Const $iExtended = @extended, Const $iScriptLineNumber = @ScriptLineNumber)
    If $iError Then
        ConsoleWrite('! ERR=' & $iError & ' EXT=' & $iExtended & ' LINE=' & $iScriptLineNumber & ' :  ' & $sMessage & @CRLF)
    ElseIf $iExtended Then
        ConsoleWrite('> EXT=' & $iExtended & ' LINE=' & $iScriptLineNumber & ' :  ' & $sMessage & @CRLF)
    EndIf

    ; each "Logging" function should store and restore @error and @extended
    Return SetError($iError, $iExtended, Null)
EndFunc   ;==>_DebugErrExt

 

 

[mLipok]

I have a look on FAQ in WikiPage, and I found that this following example uses the same concept.

https://www.autoitscript.com/wiki/FAQ#OutputDebugString_native_call