Read content inside div tag of aspx page

[nirmalsalem]

Hi,

I am trying to read a content inside a div tag of an aspx page.

<div id="EmailField">
    <span id="email">
        <a href="mailto:xxxx@yyyyy.com">xxxx@yyyyy.com</a>
    </span>
</div>

 

I want to extract the mail id inside the <a> under div tag. The webpage is designed as an aspx page.

Please advise.

 

[mLipok]

Like this ?
 

expandcollapse popup

#include <ie.au3>

_IEErrorHandlerRegister(_User_ErrFunc)
_Example()

Func _Example()
    Local $oIE = _IECreate()

    Local $s_HTML = ""
    $s_HTML &= '<div id="EmailField">' & @CRLF
    $s_HTML &= '    <span id="email">' & @CRLF
    $s_HTML &= '        <a href="mailto : aaaa@yyyyy.com">xxxx@yyyyy.com</a>' & @CRLF
    $s_HTML &= '        <a href="mailto : bbbb@yyyyy.com">xxxx@yyyyy.com</a>' & @CRLF
    $s_HTML &= '    </span>' & @CRLF
    $s_HTML &= '</div>' & @CRLF

    _IEDocWriteHTML($oIE, $s_HTML)

    ; https://www.w3.org/TR/css3-selectors/#selectors
    ; find all A tags with HREF attribute value contains the substring "mailto"
    ;   which are child of SPAN tags with ID="email"
    ;       which are child of DIV tags with ID="EmailField"

    Local $oSelection_coll = _IEquerySelectorAll($oIE,'div#EmailField>span#email>a[href*="mailto"]')
    If Not @error Then
        ConsoleWrite("! $oSelection_coll.length=" & $oSelection_coll.length & @CRLF)
        For $iSelection_idx = 0 To $oSelection_coll.length -1
            ConsoleWrite($oSelection_coll.item($iSelection_idx).href & @CRLF)
        Next
    EndIf

EndFunc    ;==>_Example



;#FUNCTION#=============================================================================================================
; Name...........: _IEquerySelectorAll()
; Description ...: Returns an Object or a Colection of objects
; Syntax.........: (ByRef $oDoc, $sQuery, $iItemIndex = Default)
; Parameters ....: $oDoc - The document object from IE
;                  $sQuery - String of Query. Example: _IEquerySelectorAll($oDoc, '"div.note, div.alert"', Default) will return a colection of div elements with classes of note and alert
;                  $iItemIndex -     [optional] Default returns a colection, else use a 0 based index to indicate the object in sequence
; Return values .: Success - Object or a Colection of objects
;                  Failure - returns 0 sets the @error flag to non-zero.
;                   3 ($_IEStatus_InvalidDataType) - Invalid Data Type
;                   4 ($_IEStatus_InvalidObjectType) - Invalid Object Type
;                   5 ($_IEStatus_InvalidValue) - Invalid Value
;                   7 ($_IEStatus_NoMatch) - No Match
; Author ........: XThrax aka uncommon
; Remarks .......: This fuction was pretty much stolen from Dale Hohm the IE UDF creator so much credit to him, also to mLipok who made the error checking better.
;                   Also note that this a relatively recent add-on to IE so it requires IE 9 and above.
;                   If you find you receive a com error of "unknown name" its likely the site is using meta tag attribute X-UA-Compatible which has reverted the browser to forget about it.
;
; Related .......: _IETagNameAllGetCollection();_IEClassNameGetCollection()
; Link ..........;https://www.autoitscript.com/forum/topic/181376-_iequeryselectorall/
;                 https://msdn.microsoft.com/en-us/library/cc304115(v=vs.85).aspx
; Example .......; No
; =====================================================================================================================


Func _IEquerySelectorAll(ByRef $oDoc, $sQuery, $iItemIndex = Default)
    If Not IsObj($oDoc) Then
        ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IEStatus_InvalidDataType & " Invalid DataType" & @LF)
        Return SetError($_IEStatus_InvalidDataType, 1, 0)
    ElseIf Not __IEIsObjType($oDoc, "browserdom") Then
        ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IEStatus_InvalidObjectType & " Invalid ObjectType" & @LF)
        Return SetError($_IEStatus_InvalidObjectType, 2, 0)
    ElseIf Not IsNumber($iItemIndex) And $iItemIndex <> Default Then
        ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IEStatus_InvalidValue & " Invalid Index" & @LF)
        Return SetError($_IEStatus_InvalidValue, 3, 0)
    ElseIf $iItemIndex = Default Or $iItemIndex >= 0 Then
        Local $oTemp = Null
        If __IEIsObjType($oDoc, "documentcontainer") Then
            $oTemp = _IEDocGetObj($oDoc)
            If @error Then Return SetError(@error, @extended, 0)
        Else
            $oTemp = $oDoc
        EndIf
        Local $oClassColl = $oTemp.querySelectorAll($sQuery)
        If @error Then
            ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IESTATUS_GeneralError & " GeneralError1: " & @error & @LF)
            Return SetError($_IESTATUS_GeneralError, 3, 0)
        ElseIf (Not IsObj($oClassColl)) Or $oClassColl = Null Or $oClassColl.length = 0 Then
            ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IEStatus_NoMatch & " NoMatch" & @LF)
            Return SetError($_IEStatus_NoMatch, 0, 0) ; Could be caused by parameter 2, 3 or both
        Else
            If $iItemIndex = Default Then
                Return SetError($_IEStatus_Success, $oClassColl.length, $oClassColl)
            ElseIf $iItemIndex > $oClassColl.length Then
                ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IEStatus_InvalidValue & " Invalid Value" & @LF)
                Return SetError($_IEStatus_InvalidValue, $oClassColl.length, 0)
            Else
                $oItem = $oClassColl.Item($iItemIndex)
                If @error Then
                    ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IESTATUS_GeneralError & " GeneralError2: " & @error & @LF)
                    Return SetError($_IESTATUS_GeneralError, 3, 0)
                ElseIf (Not IsObj($oItem)) Or $oItem = Null Then
                    ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IEStatus_NoMatch & " NoMatch Index: " & $iItemIndex & @LF)
                    Return SetError($_IEStatus_NoMatch, 0, 0) ; Could be caused by parameter 2, 3 or both
                Else
                    Return SetError($_IEStatus_Success, 0, $oItem)
                EndIf
            EndIf
        EndIf
    Else
        ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IEStatus_InvalidValue & " Invalid Value: " & $iItemIndex & @LF)
        Return SetError($_IEStatus_InvalidValue, 3, 0)
    EndIf
EndFunc   ;==>_IEquerySelectorAll

; User's COM error function.
; After SetUp with ObjEvent("AutoIt.Error", ....) will be called if COM error occurs
Func _User_ErrFunc($oError)
    ; Do anything here.
    ConsoleWrite(@ScriptFullPath & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc   ;==>_User_ErrFunc

 

Edited August 19, 2016 by mLipok

[31290]

Hi

Try:

Func f_MyFunc()
    $oIE = _IECreate("YOUR_URL.aspx", 0, 0, 1, 0) ;accord with your needs
    _IELoadWait($oIE)
    _IEQuit ( $oIE )
    $sRead = InetRead('YOUR_URL.aspx');accord with your needs
    $aLinksEmail = _StringBetween($aDataBIOS[0], '<div><a>', '</a></div>')
    $slinksEmail = ""
    For $i = 0 To UBound($aLinksEMAIL) - 1
        If StringInStr($aLinksEMAIL[$i], "email") Then
            $a2LinksEmail = _StringBetween($aLinksEMAIL[$i], '<a href="/', '"></a')
            $sLinksEmail = $a2LinksEMAIL[0]
            ExitLoop
        EndIf
    Next
    Msgbox(0, "email", $a2LinksEMAIL[0])
EndFunc

Don't forget #include <IE.au3> at the beginning.

Hope that helps

-31290-

[nirmalsalem]

Hi mlipok,

Thanks of your effort. Actually I need to read the email id rather than writing to the webpage.

 

 

[nirmalsalem]

Hi 31290,

Thank you. But I am getting "Subscript used on non-accessible variable" error.

 

 

[mLipok]

2 hours ago, nirmalsalem said:

Actually I need to read the email id rather than writing to the webpage.

Your was asking about Reading not Writing.
So did you try this my example to make what you need ?

btw.

Your HTML Snippet does not contain any "TAG" which should be editabled by EndUser.
So how user should fill up this HTML FORM ?