Sign in to follow this  
Followers 0
wakillon

TinyBatteryBar

9 posts in this topic

#1 ·  Posted (edited)

Only for LapTop and inspired of PowerMeterPlus, I tried to do it in AutoIt ;)
 

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_icon=07.ico
#AutoIt3Wrapper_outfile=TinyBatteryBar.exe
#AutoIt3Wrapper_Res_Comment=Tested on Xp 32bit
#AutoIt3Wrapper_Res_Description=Indicate the level of battery charge and remaining time.
#AutoIt3Wrapper_Res_Fileversion=1.0.1
#AutoIt3Wrapper_Res_Fileversion_AutoIncrement=Y
#AutoIt3Wrapper_Res_LegalCopyright=Copyright ? 2010 wakillon
#AutoIt3Wrapper_Res_Language=1036
://////=__=
://////=__=
#AutoIt3Wrapper_Res_Icon_Add=Icons03.ico
#AutoIt3Wrapper_Res_Icon_Add=Icons07.ico
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

#cs --------------------------------------------------------------------------------------------------------------------

AutoIt Version  : 3.3.6.1
Author        : wakillon
Script Fonction : Tiny Battery Bar, indicate the level of battery charge and remaining time.

#ce --------------------------------------------------------------------------------------------------------------------
#Include <ProgressConstants.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include <GUIConstants.au3>
#include <Constants.au3>
#Include <WinAPIEx.au3>
#Include <String.au3>
#include <Misc.au3>
#Include <Date.au3>

Opt ( "TrayOnEventMode", 1 )
Opt ( "TrayMenuMode", 1 )

Global $_Timer = _NowCalc ( )
Global $_GuiHeight = ( @DesktopHeight/4 )
Global $_GuiWidth = 20
Global $_GuiXPos = ( @DesktopWidth - 20 -10 )
Global $_GuiYPos = ( @DesktopHeight - $_GuiHeight - _GetTaskbarHeight ( ) -10 )
Global $_Data[4], $_Font = "ARIAL", $_Init=1, $_XPos, $_StateLabel, $_ProgressBar, $_PercentLabel, $_Gui, $_StartItem, $_AboutItem
Global $_TitleKey = 'TinyBatterryBar', $_RegKeySettings

If Not _Singleton ( @ScriptName, 1 ) Then Exit
OnAutoItExitRegister ( "_OnAutoItExit" )
If Not _IsLaptopPC ( ) Then Exit MsgBox ( 4096, "Error", "It's not a LapTop PC", 6 )
_Gui ( )
_SetTrayMenu ( )
_ReduceMemory ( )

While 1
    $_NowCalc = _NowCalc ( )
    If _DateDiff ( "s", $_Timer, $_NowCalc ) >= 10 Or $_Init Then
        $_Timer = $_NowCalc
        _BatteryStatus ( )
            If IsArray ( $_Data ) Then
            If $_Data[2] < 10 Then
                TraySetIcon ( @ScriptFullPath, -5 )  
                TraySetState ( 4 )            
                GUICtrlSetColor ( $_StateLabel, 0xFF0000 )
                GUICtrlSetColor ( $_ProgressBar, 0xFF0000 )
            Else
                TraySetIcon ( @ScriptFullPath, 0 )  
                TraySetState ( 8 )
                GUICtrlSetColor ( $_StateLabel, 0x000000 )
                GUICtrlSetColor ( $_ProgressBar, 0x009300 )
            EndIf
            GUICtrlSetState ( $_StateLabel, $GUI_ENABLE )
            GUICtrlSetData ( $_ProgressBar, $_Data[2] )
            GUICtrlSetData ( $_PercentLabel, $_Data[2]  & "%" )
            GUICtrlSetData ( $_StateLabel, $_Data[0] )
            WinSetOnTop ( $_Gui, '', 1 )
            $_Init=0
        EndIf
    EndIf
    Sleep ( 20 )
    If _GetHoveredHwnd ( ) = $_Gui Then
        $_WinPos = WinGetPos ( $_Gui )
        If $_WinPos[0] = $_GuiXPos Then
            $_XPos = 10
        Else    
            $_XPos = $_GuiXPos        
        EndIf  
        WinMove ( $_Gui , "", $_XPos, $_GuiYPos )
    EndIf
WEnd

Func _Gui ( )
    $_Gui = GUICreate ( "", $_GuiWidth, $_GuiHeight, $_GuiXPos, $_GuiYPos, $WS_POPUP+$WS_THICKFRAME )
    GUISetFont ( 8, 400, 2, $_Font, $_Gui, 5 )
    $_StateLabel = GUICtrlCreateLabel ( "", 0, 3, $_GuiWidth, 20, $SS_CENTER )
    $_ProgressBar = GUICtrlCreateProgress ( 0, 22, $_GuiWidth, $_GuiHeight-40, $PBS_VERTICAL )
    DllCall ( "UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle ( $_ProgressBar ), "wstr", " ", "wstr", " " )
    GUICtrlSetStyle ( $_ProgressBar, 5 )
    GUICtrlSetColor ( $_ProgressBar, 0x009300 )
    $_PercentLabel = GUICtrlCreateLabel ( "", 0, $_GuiHeight-15, $_GuiWidth, 20, $SS_CENTER )
    GuiSetStyle ( $WS_POPUPWINDOW, $WS_EX_CLIENTEDGE + $WS_EX_TOOLWINDOW )
    GUISetState ( )
EndFunc ;==> _Gui ( )

Func _GetHoveredHwnd ( )
    Local $iRet = DllCall ( "user32.dll", "int", "WindowFromPoint", "long", MouseGetPos ( 0 ), "long", MouseGetPos ( 1 ) )
    If IsArray ( $iRet )  Then Return HWnd ( $iRet[0] )
    Return SetError ( 1, 0, 0 )
EndFunc ;==> _GetHoveredHwnd ( )

Func _GetTaskbarHeight ( )
    Local Const $SPI_GETWORKAREA = 48
    Local $WorkArea, $stRect = DllStructCreate ( "long left;long top;long right;long bottom" )
    Local $iResult = _WinAPI_SystemParametersInfo ( $SPI_GETWORKAREA, 0, DllStructGetPtr ( $stRect ), 0 )
    If $iResult = True Then
        $WorkArea = DllStructGetData ( $stRect, "bottom" ) - DllStructGetData ( $stRect, "top" )
        If Not @error Then Return @DesktopHeight - $WorkArea
    Else    
        Return 0
    EndIf
EndFunc ;==> _GetTaskbarHeight ( )

Func _BatteryStatus ( )
    $_Data = _WinAPI_GetSystemPowerStatus ( )
    If Not IsArray ( $_Data ) Then Return
    If BitAND ( $_Data[1], 128 ) Then
        $_Data[0] = 'Not present'
        For $i = 1 To 3
            $_Data[$i] = '?'
        Next
    Else
        Switch $_Data[2]
            Case 0 To 100
                $_Data[2] =$_Data[2]
            Case Else
                $_Data[2] = '?'
        EndSwitch
        Switch $_Data[3]
            Case -1
                $_Data[3] = '?'
            Case Else
                $H = ( $_Data[3] - Mod ( $_Data[3], 3600 ) ) / 3600
                $M = ( $_Data[3] - Mod ( $_Data[3], 60 ) ) / 60 - $H * 60
                $_Data[3] = StringFormat ( $H & ':%02d', $M )
        EndSwitch
        Switch $_Data[0]
            Case 0
                $_Data[0] = $_Data[3]
            Case 1
                $_Data[0] = 'Chg'
            Case Else
                $_Data[0] = '?'
        EndSwitch     
    EndIf
EndFunc ;==> _BatteryStatus ( )

Func _StartWithWindows ( )
    $_ItemGetState = TrayItemGetState ( $_StartItem )
    If $_ItemGetState = 64+1 Then
        RegWrite ( "HKCUSoftwareMicrosoftWindowsCurrentVersionRun", $_TitleKey, "REG_SZ", @ScriptFullPath )
    Else
        RegDelete ( "HKCUSoftwareMicrosoftWindowsCurrentVersionRun", $_TitleKey )
    EndIf
EndFunc ;==> _StartWithWindows ( )

Func _IsLaptopPC ( $_myComputer='.' )
    $_objWMIService = ObjGet ( "winmgmts://" & $_myComputer & "/root/cimv2" )
    $_colItems = $_objWMIService.ExecQuery ( "Select * from Win32_Battery" )
    For $_objItem in $_colItems
        If $_objItem <> '' Then Return True
    Next
    Return False
EndFunc ;==> _IsLaptopPC ( )

Func _ReduceMemory ( $i_PID=-1 )
    If $i_PID <> -1 Then
        Local $ai_Handle = DllCall ( "kernel32.dll", 'int', 'OpenProcess', 'int', 0x1f0fff, 'int', False, 'int', $i_PID )
        Local $ai_Return = DllCall ( "psapi.dll", 'int', 'EmptyWorkingSet', 'long', $ai_Handle[0] )
        DllCall ( 'kernel32.dll', 'int', 'CloseHandle', 'int', $ai_Handle[0] )
    Else
        Local $ai_Return = DllCall ( "psapi.dll", 'int', 'EmptyWorkingSet', 'long', -1 )
    EndIf
    Return $ai_Return[0]
EndFunc ;==> _ReduceMemory ( )

Func _About ( )
    MsgBox ( 64 + 8192, "About", "Informations" & @CRLF & @CRLF & StringTrimRight ( @ScriptName, 4 ) & @CRLF & @CRLF _
    & "This program is Freeware. It may be distributed and copied, and should be Changed and Distributed under a different Name or Author." & @CRLF _
    & @CRLF & @CRLF & "Thanks, To use " & StringTrimRight ( @ScriptName, 4 ) & " !" & @CRLF & @CRLF & "wakillon." )
    TrayItemSetState ( $_AboutItem , $TRAY_UNCHECKED )
EndFunc ;==> _About ( )

Func _SetTrayMenu ( )
                 TraySetToolTip ( "TinyBatteryBar v1.01" & " RightClick to Traymenu" )
                 TraySetIcon ( @ScriptFullPath, 0 )  
$_StartItem = TrayCreateItem ( "Start With Windows" )
                 TrayItemSetOnEvent ( -1, "_StartWithWindows" )
                 $_RegRead = RegRead ( "HKCUSoftwareMicrosoftWindowsCurrentVersionRun", $_TitleKey )
                 If $_RegRead <> '' Then TrayItemSetState ( $_StartItem, $TRAY_CHECKED )
                 TrayCreateItem ( "" )
$_AboutItem = TrayCreateItem ( "About" )
                 TrayItemSetOnEvent ( -1, "_About" )
                 TrayCreateItem ( "" )
$_ExitItem   = TrayCreateItem ( "Exit" )
                 TrayItemSetOnEvent ( -1, "_Exit" )   
                 TraySetClick ( 16 )
                 TraySetState ( )
EndFunc ;==> _SetTrayMenu ( )

Func _Exit ( )
    Exit
EndFunc ;==> _Exit ( )

Func _OnAutoItExit ( )
    Opt ( "TrayIconHide", 0 )
    Local $_Space=""
    If @OSVersion = "WIN_XP" Then $_Space = _StringRepeat ( " ", 8 )
    TrayTip ( "TinyBatteryBar", $_Space & "by wakillon...", 1, 1 )
    Sleep ( 2000 )
    TrayTip ( '', '', 1, 1 )
EndFunc ;==> _OnAutoItExit ( )


Icons + WinAPIEx.au3

Icons.7z

Scripts and executables with full embeded files are available on GoogleCode, see link in my sig.

Simple and practical, battery bar move if mouse is over,
If it can help...

20140725102536.jpg

Edited by wakillon

AutoIt 3.3.14.2 X86 - SciTE 3.6.0WIN 8.1 X64 - Other Example Scripts

Share this post


Link to post
Share on other sites



You just forgot to mention that WinAPIEx UDF is necessary to make it work. ;)

I don't have a laptop here to test it. Anyway, good job! :)


Share this post


Link to post
Share on other sites

#3 ·  Posted (edited)

You just forgot to mention that WinAPIEx UDF is necessary to make it work. ;)

I don't have a laptop here to test it. Anyway, good job! :)

Thanks, I inserted it in the icons archive ! Posted Image

Edited by wakillon

AutoIt 3.3.14.2 X86 - SciTE 3.6.0WIN 8.1 X64 - Other Example Scripts

Share this post


Link to post
Share on other sites

Several comments:

  • Using the _ReduceMemory() within the loop is a very bad idea. This will reduce performance than memory usage. Enough to call once at the script beginning.
  • If you are using a WinAPIEx UDF then _WinAPI_EmptyWorkingSet() function does the same as _ReduceMemory().
  • You can use a Battery UDF to get additional information about the installed battery.
  • Use TimerDiff() or AdlibRegister() instead of _NowCalc() and _DateDiff().
  • Use #AutoIt3Wrapper_Res_Icon_Add directives instead of FileInstall().
Anyway, it's a good utility.

Share this post


Link to post
Share on other sites

Thanks for your advices ! Posted Image

I'll try to fix all this...

And I forget to thank you for WinAPIEx.au3 !Posted Image


AutoIt 3.3.14.2 X86 - SciTE 3.6.0WIN 8.1 X64 - Other Example Scripts

Share this post


Link to post
Share on other sites

#6 ·  Posted (edited)

Corected and Updated !
 

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_icon=07.ico
#AutoIt3Wrapper_outfile=TinyBatteryBar.exe
#AutoIt3Wrapper_Res_Comment=Tested on Xp 32bit
#AutoIt3Wrapper_Res_Description=Indicate the level of battery charge and remaining time.
#AutoIt3Wrapper_Res_Fileversion=1.0.1
#AutoIt3Wrapper_Res_Fileversion_AutoIncrement=Y
#AutoIt3Wrapper_Res_LegalCopyright=Copyright ? 2010 wakillon
#AutoIt3Wrapper_Res_Language=1036
://////=__=
://////=__=
#AutoIt3Wrapper_Res_Icon_Add=Icons\03.ico
#AutoIt3Wrapper_Res_Icon_Add=Icons\07.ico
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

#cs --------------------------------------------------------------------------------------------------------------------

 AutoIt Version  : 3.3.6.1
 Author          : wakillon
 Script Fonction : Tiny Battery Bar, indicate the level of battery charge and remaining time.

#ce --------------------------------------------------------------------------------------------------------------------
#Include <ProgressConstants.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include <GUIConstants.au3>
#include <Constants.au3>
#Include <WinAPIEx.au3>
#Include <String.au3>
#include <Misc.au3>
#Include <Date.au3>

Opt ( "TrayOnEventMode", 1 ) 
Opt ( "TrayMenuMode", 1 ) 

Global $_Timer = _NowCalc ( )
Global $_GuiHeight = ( @DesktopHeight/4 ) 
Global $_GuiWidth = 20
Global $_GuiXPos = ( @DesktopWidth - 20 -10 )
Global $_GuiYPos = ( @DesktopHeight - $_GuiHeight - _GetTaskbarHeight ( ) -10 ) 
Global $_Data[4], $_Font = "ARIAL", $_Init=1, $_XPos, $_StateLabel, $_ProgressBar, $_PercentLabel, $_Gui, $_StartItem, $_AboutItem
Global $_TitleKey = 'TinyBatterryBar', $_RegKeySettings

If Not _Singleton ( @ScriptName, 1 ) Then Exit 
OnAutoItExitRegister ( "_OnAutoItExit" )
If Not _IsLaptopPC ( ) Then Exit MsgBox ( 4096, "Error", "It's not a LapTop PC", 6 )
_Gui ( ) 
_SetTrayMenu ( )
_ReduceMemory ( )

While 1
    $_NowCalc = _NowCalc ( )
    If _DateDiff ( "s", $_Timer, $_NowCalc ) >= 10 Or $_Init Then 
        $_Timer = $_NowCalc
        _BatteryStatus ( )
            If IsArray ( $_Data ) Then
            If $_Data[2] < 10 Then
                TraySetIcon ( @ScriptFullPath, -5 )  
                TraySetState ( 4 )              
                GUICtrlSetColor ( $_StateLabel, 0xFF0000 )
                GUICtrlSetColor ( $_ProgressBar, 0xFF0000 )
            Else
                TraySetIcon ( @ScriptFullPath, 0 )  
                TraySetState ( 8 ) 
                GUICtrlSetColor ( $_StateLabel, 0x000000 )
                GUICtrlSetColor ( $_ProgressBar, 0x009300 )
            EndIf
            GUICtrlSetState ( $_StateLabel, $GUI_ENABLE )
            GUICtrlSetData ( $_ProgressBar, $_Data[2] )
            GUICtrlSetData ( $_PercentLabel, $_Data[2]  & "%" )
            GUICtrlSetData ( $_StateLabel, $_Data[0] )
            WinSetOnTop ( $_Gui, '', 1 )
            $_Init=0
        EndIf
    EndIf
    Sleep ( 20 )
    If _GetHoveredHwnd ( ) = $_Gui Then
        $_WinPos = WinGetPos ( $_Gui )
        If $_WinPos[0] = $_GuiXPos Then
            $_XPos = 10
        Else    
            $_XPos = $_GuiXPos          
        EndIf   
        WinMove ( $_Gui , "", $_XPos, $_GuiYPos )
    EndIf
WEnd

Func _Gui ( ) 
    $_Gui = GUICreate ( "", $_GuiWidth, $_GuiHeight, $_GuiXPos, $_GuiYPos, $WS_POPUP+$WS_THICKFRAME )
    GUISetFont ( 8, 400, 2, $_Font, $_Gui, 5 ) 
    $_StateLabel = GUICtrlCreateLabel ( "", 0, 3, $_GuiWidth, 20, $SS_CENTER )
    $_ProgressBar = GUICtrlCreateProgress ( 0, 22, $_GuiWidth, $_GuiHeight-40, $PBS_VERTICAL )
    DllCall ( "UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle ( $_ProgressBar ), "wstr", " ", "wstr", " " )
    GUICtrlSetStyle ( $_ProgressBar, 5 ) 
    GUICtrlSetColor ( $_ProgressBar, 0x009300 )
    $_PercentLabel = GUICtrlCreateLabel ( "", 0, $_GuiHeight-15, $_GuiWidth, 20, $SS_CENTER )
    GuiSetStyle ( $WS_POPUPWINDOW, $WS_EX_CLIENTEDGE + $WS_EX_TOOLWINDOW )
    GUISetState ( )
EndFunc ;==> _Gui ( ) 

Func _GetHoveredHwnd ( ) 
    Local $iRet = DllCall ( "user32.dll", "int", "WindowFromPoint", "long", MouseGetPos ( 0 ), "long", MouseGetPos ( 1 ) ) 
    If IsArray ( $iRet )  Then Return HWnd ( $iRet[0] ) 
    Return SetError ( 1, 0, 0 ) 
EndFunc ;==> _GetHoveredHwnd ( ) 

Func _GetTaskbarHeight ( ) 
    Local Const $SPI_GETWORKAREA = 48
    Local $WorkArea, $stRect = DllStructCreate ( "long left;long top;long right;long bottom" )
    Local $iResult = _WinAPI_SystemParametersInfo ( $SPI_GETWORKAREA, 0, DllStructGetPtr ( $stRect ), 0 )
    If $iResult = True Then
        $WorkArea = DllStructGetData ( $stRect, "bottom" ) - DllStructGetData ( $stRect, "top" ) 
        If Not @error Then Return @DesktopHeight - $WorkArea
    Else    
        Return 0
    EndIf
EndFunc ;==> _GetTaskbarHeight ( ) 

Func _BatteryStatus ( )
    $_Data = _WinAPI_GetSystemPowerStatus ( )
    If Not IsArray ( $_Data ) Then Return
    If BitAND ( $_Data[1], 128 ) Then
        $_Data[0] = 'Not present'
        For $i = 1 To 3
            $_Data[$i] = '?'
        Next
    Else
        Switch $_Data[2]
            Case 0 To 100
                $_Data[2] =$_Data[2]
            Case Else
                $_Data[2] = '?'
        EndSwitch
        Switch $_Data[3]
            Case -1
                $_Data[3] = '?'
            Case Else
                $H = ( $_Data[3] - Mod ( $_Data[3], 3600 ) ) / 3600
                $M = ( $_Data[3] - Mod ( $_Data[3], 60 ) ) / 60 - $H * 60
                $_Data[3] = StringFormat ( $H & ':%02d', $M )
        EndSwitch
        Switch $_Data[0]
            Case 0
                $_Data[0] = $_Data[3]
            Case 1
                $_Data[0] = 'Chg'
            Case Else
                $_Data[0] = '?'
        EndSwitch       
    EndIf
EndFunc ;==> _BatteryStatus ( )

Func _StartWithWindows ( )
    $_ItemGetState = TrayItemGetState ( $_StartItem ) 
    If $_ItemGetState = 64+1 Then
        RegWrite ( "HKCU\Software\Microsoft\Windows\CurrentVersion\Run", $_TitleKey, "REG_SZ", @ScriptFullPath )
    Else
        RegDelete ( "HKCU\Software\Microsoft\Windows\CurrentVersion\Run", $_TitleKey )
    EndIf
EndFunc ;==> _StartWithWindows ( )

Func _IsLaptopPC ( $_myComputer='.' )
    $_objWMIService = ObjGet ( "winmgmts://" & $_myComputer & "/root/cimv2" )
    $_colItems = $_objWMIService.ExecQuery ( "Select * from Win32_Battery" )
    For $_objItem in $_colItems
        If $_objItem <> '' Then Return True
    Next
    Return False
EndFunc ;==> _IsLaptopPC ( )

Func _ReduceMemory ( $i_PID=-1 )
    If $i_PID <> -1 Then
        Local $ai_Handle = DllCall ( "kernel32.dll", 'int', 'OpenProcess', 'int', 0x1f0fff, 'int', False, 'int', $i_PID )
        Local $ai_Return = DllCall ( "psapi.dll", 'int', 'EmptyWorkingSet', 'long', $ai_Handle[0] )
        DllCall ( 'kernel32.dll', 'int', 'CloseHandle', 'int', $ai_Handle[0] )
    Else
        Local $ai_Return = DllCall ( "psapi.dll", 'int', 'EmptyWorkingSet', 'long', -1 )
    EndIf
    Return $ai_Return[0]
EndFunc ;==> _ReduceMemory ( ) 

Func _About ( )
    MsgBox ( 64 + 8192, "About", "Informations" & @CRLF & @CRLF & StringTrimRight ( @ScriptName, 4 ) & @CRLF & @CRLF _
    & "This program is Freeware. It may be distributed and copied, and should be Changed and Distributed under a different Name or Author." & @CRLF _
    & @CRLF & @CRLF & "Thanks, To use " & StringTrimRight ( @ScriptName, 4 ) & " !" & @CRLF & @CRLF & "wakillon." )
    TrayItemSetState ( $_AboutItem , $TRAY_UNCHECKED )
EndFunc ;==> _About ( )

Func _SetTrayMenu ( )
                 TraySetToolTip ( "TinyBatteryBar v1.01" & " RightClick to Traymenu" ) 
                 TraySetIcon ( @ScriptFullPath, 0 )  
$_StartItem    = TrayCreateItem ( "Start With Windows" ) 
                 TrayItemSetOnEvent ( -1, "_StartWithWindows" )
                 $_RegRead = RegRead ( "HKCU\Software\Microsoft\Windows\CurrentVersion\Run", $_TitleKey )
                 If $_RegRead <> '' Then TrayItemSetState ( $_StartItem, $TRAY_CHECKED )
                 TrayCreateItem ( "" ) 
$_AboutItem    = TrayCreateItem ( "About" ) 
                 TrayItemSetOnEvent ( -1, "_About" )
                 TrayCreateItem ( "" ) 
$_ExitItem     = TrayCreateItem ( "Exit" ) 
                 TrayItemSetOnEvent ( -1, "_Exit" )      
                 TraySetClick ( 16 ) 
                 TraySetState ( ) 
EndFunc ;==> _SetTrayMenu ( )

Func _Exit ( )
    Exit
EndFunc ;==> _Exit ( ) 

Func _OnAutoItExit ( )
    Opt ( "TrayIconHide", 0 ) 
    Local $_Space=""
    If @OSVersion = "WIN_XP" Then $_Space = _StringRepeat ( " ", 8 )
    TrayTip ( "TinyBatteryBar", $_Space & "by wakillon...", 1, 1 )
    Sleep ( 2000 )
    TrayTip ( '', '', 1, 1 )
EndFunc ;==> _OnAutoItExit ( )
Edited by wakillon

AutoIt 3.3.14.2 X86 - SciTE 3.6.0WIN 8.1 X64 - Other Example Scripts

Share this post


Link to post
Share on other sites

Hi,

i'm missing the <WinAPIEx.au3>.

Where can i find it?

Thanks

Dizzy

Share this post


Link to post
Share on other sites

Where can i find it?

Really?! >>

_AdapterConnections()_AlwaysRun()_AppMon()_AppMonEx()_BinaryBin()_CheckMsgBox()_CmdLineRaw()_ContextMenu()_ConvertLHWebColor()/_ConvertSHWebColor()_DesktopDimensions()_DisplayPassword()_DotNet_Load()/_DotNet_Unload()_Fibonacci()_FileCompare()_FileCompareContents()_FileNameByHandle()_FilePrefix/SRE()_FindInFile()_GetBackgroundColor()/_SetBackgroundColor()_GetConrolID()_GetCtrlClass()_GetDirectoryFormat()_GetDriveMediaType()_GetFilename()/_GetFilenameExt()_GetHardwareID()_GetIP()_GetIP_Country()_GetOSLanguage()_GetSavedSource()_GetStringSize()_GetSystemPaths()_GetURLImage()_GIFImage()_GoogleWeather()_GUICtrlCreateGroup()_GUICtrlListBox_CreateArray()_GUICtrlListView_CreateArray()_GUICtrlListView_SaveCSV()_GUICtrlListView_SaveHTML()_GUICtrlListView_SaveTxt()_GUICtrlListView_SaveXML()_GUICtrlMenu_Recent()_GUICtrlMenu_SetItemImage()_GUICtrlTreeView_CreateArray()_GUIDisable()_GUIImageList_SetIconFromHandle()_GUIRegisterMsg()_GUISetIcon()_Icon_Clear()/_Icon_Set()_IdleTime()_InetGet()_InetGetGUI()_InetGetProgress()_IPDetails()_IsFileOlder()_IsGUID()_IsHex()_IsPalindrome()_IsRegKey()_IsStringRegExp()_IsSystemDrive()_IsUPX()_IsValidType()_IsWebColor()_Language()_Log()_MicrosoftInternetConnectivity()_MSDNDataType()_PathFull/GetRelative/Split()_PathSplitEx()_PrintFromArray()_ProgressSetMarquee()_ReDim()_RockPaperScissors()/_RockPaperScissorsLizardSpock()_ScrollingCredits_SelfDelete()_SelfRename()_SelfUpdate()_SendTo()_ShellAll()_ShellFile()_ShellFolder()_SingletonHWID()_SingletonPID()_Startup()_StringCompact()_StringIsValid()_StringRegExpMetaCharacters()_StringReplaceWholeWord()_StringStripChars()_Temperature()_TrialPeriod()_UKToUSDate()/_USToUKDate()_WinAPI_Create_CTL_CODE()_WinAPI_CreateGUID()_WMIDateStringToDate()/_DateToWMIDateString()Au3 script parsingAutoIt SearchAutoIt3 PortableAutoIt3WrapperToPragmaAutoItWinGetTitle()/AutoItWinSetTitle()CodingDirToHTML5FileInstallrFileReadLastChars()GeoIP databaseGUI - Only Close ButtonGUI ExamplesGUICtrlDeleteImage()GUICtrlGetBkColor()GUICtrlGetStyle()GUIEventsGUIGetBkColor()Int_Parse() & Int_TryParse()IsISBN()LockFile()Mapping CtrlIDsOOP in AutoItParseHeadersToSciTE()PasswordValidPasteBinPosts Per DayPreExpandProtect GlobalsQueue()Resource UpdateResourcesExSciTE JumpSettings INISHELLHOOKShunting-YardSignature CreatorStack()Stopwatch()StringAddLF()/StringStripLF()StringEOLToCRLF()VSCROLLWM_COPYDATAMore Examples...

Updated: 04/09/2015

Share this post


Link to post
Share on other sites

Hi,

i'm missing the <WinAPIEx.au3>.

Where can i find it?

Thanks

Dizzy

WinAPIEx.au3 is already include in the Icons.7z in the first post ! Posted Image


AutoIt 3.3.14.2 X86 - SciTE 3.6.0WIN 8.1 X64 - Other Example Scripts

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0