Rawox

Window Handle/Title under mouse pointer

8 posts in this topic

Hi there,

Is there a way to get the title / handle from the window (not control) your mouse pointer is currently hovering over. (Not only active windows but inactive too).

I know AutoIt Window Info can do it but that's written in C, right, not in AutoIt...

Any ideas on how to do this?

Thanks in advance,

Rawox

Share this post


Link to post
Share on other sites



#2 ·  Posted (edited)

A good place to start might be

Or have a look at _WinAPI_WindowFromPoint. The example returns a handle to the window at mouse coordinates.

Unfortunately this only works for active windows (according to the help file).

Edited by water

My UDFs and Tutorials:

Spoiler

UDFs:
Active Directory (NEW 2017-04-18 - Version 1.4.8.0) - Download - General Help & Support - Example Scripts - Wiki
OutlookEX (NEW 2017-02-27 - Version 1.3.1.0) - Download - General Help & Support - Example Scripts - Wiki
ExcelChart (2015-04-01 - Version 0.4.0.0) - Download - General Help & Support - Example Scripts
Excel - Example Scripts - Wiki
Word - Wiki
PowerPoint (2015-06-06 - Version 0.0.5.0) - Download - General Help & Support

Tutorials:
ADO - Wiki

 

Share this post


Link to post
Share on other sites

Rawox,

This should get you started. At the moment it gives you all the windows (i.e including controls) but as it gives you the class info as well I will leave sorting that out as an exercise for the student: :graduated:

#include <WinAPI.au3>

HotKeySet("{ESC}", "On_Exit")

Func On_Exit()
    Exit
EndFunc

$hCurr_HhWnd = 0

While 1

    If @AutoItX64 Then
        Local $tPoint = DllStructCreate("int X;int Y")
        DllStructSetData ( $tPoint, "X", MouseGetPos(0))
        DllStructSetData ( $tPoint, "Y", MouseGetPos(1))
        Local $tPoint64 = DllStructCreate("int64", DllStructGetPtr($tPoint))
        Local $aHwnd = DllCall("user32.dll", "hwnd", "WindowFromPoint", "int64", DllStructGetData($tPoint64, 1))
    Else
        Local $aHwnd = DllCall("user32.dll", "hwnd", "WindowFromPoint", "uint", MouseGetPos(0), "uint", MouseGetPos(1))
    EndIf

    If $aHwnd[0] <> $hCurr_HhWnd Then
        ConsoleWrite($aHwnd[0] & " - " & _WinAPI_GetClassName($aHwnd[0]) & @CRLF)
        $hCurr_HhWnd = $aHwnd[0]
    EndIf

WEnd

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

Here's an exercise for the advanced students; what would happen if every "int64" from Melba23's code would be replaced with "double"?

Extremely advanced students would run (hypothetical) code only in their advanced minds and still get the right answer. :graduated:

Melba23?


♡♡♡

.

eMyvnE

Share this post


Link to post
Share on other sites

trancexx,

As both "int64" and "double" use 64 bits to contain the value, I imagine that the code would be unaffected. :graduated:

But as I do not consider myself anywhere near "advanced" in this area I am probably completely wrong. :(

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

rawox, just combine WindowFromPoint and GetAncestor to get the window. The window/control you get from the first API would be passed to GetAncestor, with a flag of 2 (GA_ROOT). The second call will return the window, not the control, under the mouse (which in certain cases will match what you get from the WindowFromPoint call). Note that this window won't necessarily be the main application window (could be a popup messagebox for example), but it does match the AutoIt Window Info tool's behavior.

You can of course go further and use a flag of 3 (GA_ROOTOWNER) to find the application window.

Share this post


Link to post
Share on other sites

Thanks for all the replies!

Ascend4nt?

How would I call these functions? I'm not that advanced in AutoIt, can it be done by using DLL Calls? Which DLL should I call then?

Share this post


Link to post
Share on other sites

This is how to do it with the built-in UDF functions:

#include <WinAPI.au3>
#include <Misc.au3>
Local $stPoint=DllStructCreate($tagPOINT),$aPos,$hControl,$hWin,$aLastPos[2]=[-1,-1],$sLastStr='',$sStr

While Not _IsPressed('1B')
    $aPos=MouseGetPos()
    If $aPos[0]<>$aLastPos[0] Or $aPos[1]<>$aLastPos[1] Then
        DllStructSetData($stPoint,1,$aPos[0])
        DllStructSetData($stPoint,2,$aPos[1])
        $hControl=_WinAPI_WindowFromPoint($stPoint)
        $hWin=_WinAPI_GetAncestor($hControl,2)
        $sStr='Window at '&$aPos[0]&','&$aPos[1]&': "'&WinGetTitle($hWin)&'"'
        If $sLastStr<>$sStr Then
            ToolTip($sStr,0,@DesktopHeight-20)
            $sLastStr=$sStr
        EndIf
        $aLastPos=$aPos
    EndIf
    Sleep(15)
WEnd

On a side note - I'd just like to add that _WinAPI_WindowFromPoint() was poorly thought out - it should take x,y coordinates instead of a structure.

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now