Checks if a string contains a given substrings

[Nessie]

HI to all, it's my first post here, and unfortunately i am here to ask your help >_<

My question is: there is a way to check if a string contain a given substrings?

I know that there is StringInStr to check if a string contains a given substring. But for example if i have to check if a string contain a group of given substring how can i do?

I want to do something like an AND search with SQL.

I hope you will understand me, for example i have this string.

$string = look_how_much_cool_i_am_is_thatTrue?

Now i want know if this string contain this substrings: "look", "cool", "True".

Of course i can use something like

If StringInStr ($string, "look") AND StringInStr($string, "cool") AND AND StringInStr($string, "True") Then
;Do something
EndIf

But how i can do that dinamically? Of course i dont know what substrings the user want to seach.

I hope that you have understand me. Hi!

[water]

Looks like a job for regular expressions. Please see function StringRegExp.

[BrewManNH]

Maybe something like this?

$string = "look_how_much_cool_i_am_is_thatTrue?"
$searchstring1 = "look"
$searchstring2 = "cool"
$searchstring3 = "true"
If StringInStr($string, $searchstring1) And StringInStr($string, $searchstring2) And StringInStr($string, $searchstring3) Then
    ;Do something
EndIf
; or something like this
$searchstring1 = InputBox("Search string 1", "Enter the first search string")
$searchstring2 = InputBox("Search string 2", "Enter the second search string")
$searchstring3 = InputBox("Search string 3", "Enter the third search string")
If StringInStr($string, $searchstring1) And StringInStr($string, $searchstring2) And StringInStr($string, $searchstring3) Then
    ;Do something
EndIf

[czardas]

There are several ways to do this. If you know exactly which words to test, then you could use a simple approach by looping through an array of matches. If you use RegExp then you must realise that underscore is considered a word character. You could always replace it with a space character. I mention this because you should be careful to avoid finding unwanted substrings within words.

[iamtheky]

my effort:

$flag = 0
$string = "look_how_much_cool_i_am_is_thatTrue?"

$input = inputbox ("string search" , "seperate strings with commas" , "look,cool,true")

$sArray = stringsplit ($input , ",")

For $i = 1 to $sArray[0]
If stringinstr($string , $sArray[$i]) Then
$flag += 0
Else
$flag += 1
EndIf
Next


If $flag = 0 Then
msgbox (0, '' , "strings all match")
Else
msgbox (0, '' , $flag & " strings do not match")
EndIf

[Nessie]

Maybe something like this?

$string = "look_how_much_cool_i_am_is_thatTrue?"
$searchstring1 = "look"
$searchstring2 = "cool"
$searchstring3 = "true"
If StringInStr($string, $searchstring1) And StringInStr($string, $searchstring2) And StringInStr($string, $searchstring3) Then
    ;Do something
EndIf
; or something like this
$searchstring1 = InputBox("Search string 1", "Enter the first search string")
$searchstring2 = InputBox("Search string 2", "Enter the second search string")
$searchstring3 = InputBox("Search string 3", "Enter the third search string")
If StringInStr($string, $searchstring1) And StringInStr($string, $searchstring2) And StringInStr($string, $searchstring3) Then
    ;Do something
EndIf

@BrewManNH

Thanks for your help but of course there is not so simple. I don't know how much search strings the user want to compare with the "main string". So i can't hardwrite a function with:

If StringInStr($string, $searchstring1) And StringInStr($string, $searchstring2) And StringInStr($string, $searchstring3) Then
;Do what you want
EndIf

Hi!

Edited February 11, 2013 by Nessie

[guinness]

A regular expression would be easy.

[BrewManNH]

Well, the search routine would have to do something depending upon whether you want it to do something on 1 or more matches or if you want it to only do something if all search strings are found.

[water]

With regular expressions it could look like the following code. The first example just returns 0 or 1 if none or any of the search words were found. The second example returns an array of all found words.

#include <Array.au3>
Global $sString = "This is the string I want to test for multiple words"
Global $sWords = "(string|text|words)"
Global $iResult = StringRegExp($sString, $sWords, 0)
ConsoleWrite($iResult & " " & @error)
Global $aResult = StringRegExp($sString, $sWords, 3)
_ArrayDisplay($aResult)

Just concatenate all the search words and give it a try. Edited February 11, 2013 by water

[guinness]

water's example is case-sensitive (by default) so it won't match String but it will match string. Though you can't turn this off if you so wish.

[water]

To make it case insensitive use the following line:

Global $sWords = "(?i)String|Text|WORDS"

[Nessie]

With regular expressions it could look like the following code. The first example just returns 0 or 1 if none or any of the search words were found. The second example returns an array of all found words.

#include <Array.au3>
Global $sString = "This is the string I want to test for multiple words"
Global $sWords = "(string|text|words)"
Global $iResult = StringRegExp($sString, $sWords, 0)
ConsoleWrite($iResult & " " & @error)
Global $aResult = StringRegExp($sString, $sWords, 3)
_ArrayDisplay($aResult)

Just concatenate all the search words and give it a try.

Your regex give me only the search string included in the "main string". But i want that if all the search string are included in the "main string" then do something. So for example if i have 4 search words, i need that all the search worlds were found in the "main string", and so on.

By the way thanks for your help!

Hi!

[czardas]

I tweaked water's code a bit. I imagine the syntax can be improved.

#include <Array.au3>
Global $sString = "This_is_the_string_I_want_to_test_for_multiple_Words_excluding_the_substring_in_pretext"
$sString = StringReplace($sString, "_", " ") ; Get rid of underscore
Global $sWords = "(?i)\b(string|text|words)\b" ; Case insensitive search between word boundries.
Global $iResult = StringRegExp($sString, $sWords, 0)
ConsoleWrite($iResult & " " & @error & @LF)
Global $aResult = StringRegExp($sString, $sWords, 3)
_ArrayDisplay($aResult)

[guinness]

I'm confused as to what the OP wants? What water created was how I understood the OP's problem.

[Nessie]

Another example:

I have this string:

$string = "This_is_the_string_I_want_to_test_for_multiple_Words_excluding_the_substring_in_pretext"

Now the user want to know if all these string (for example: "This", "string", "multiple", "Words") are contain in the $string.

Now if all the strings are contained in the $string do something, so give a warning.

All clear now?

Hi!

Edited February 11, 2013 by Nessie

[czardas]

...i want that if all the search string are included in the "main string" then do something. So for example if i have 4 search words, i need that all the search worlds were found in the "main string", and so on.

I understand what you want. You can test the number of returned strings by testing the size of the array using Ubound. This method may not be best. Thinking!

[guinness]

I re-read it again.

Local $sString = 'This_is_the_string_I_want_to_test_for_multiple_Words_excluding_the_substring_in_pretext'
$sString = StringReplace($sString, '_', ' ') ; Get rid of underscore
Local Const $sWords = '(?i)\b(string|text|words)\b' ; Case-insensitive search between word boundries.

Local Const $WORD_MAX = 3
Local Const $fResult = UBound(StringRegExp($sString, $sWords, 3)) = $WORD_MAX ; Number of words.
ConsoleWrite($fResult & @LF)

[czardas]

Global $sTest = "This_is_the_string_I_want_to_test_for_multiple_Words_excluding_the_substring_in_pretext"
Global $sPattern = "string|text|words"

If _AllWordsExist($sTest, $sPattern, 3) Then
    MsgBox(0, "", "All words found")
Else
    MsgBox(0, "", "Not all words were found")
EndIf

Func _AllWordsExist($sString, $sWords, $iTrigger)
    $sString = StringReplace($sString, "_", " ") ; Get rid of underscore
    $sWords = "(?i)\b(" & $sWords & ")\b" ; Case insensitive search between word boundries.
    Local $aResult = StringRegExp($sString, $sWords, 3)

    Local $bReturn = False
    If UBound($aResult) >= $iTrigger Then $bReturn = True
    Return $bReturn
EndFunc

[guinness]

Global $sTest = "This_is_the_string_I_want_to_test_for_multiple_Words_excluding_the_substring_in_pretext"
Global $sPattern = "string|text|words"

If _AllWordsExist($sTest, $sPattern, 3) Then
    MsgBox(0, "", "All words found")
Else
    MsgBox(0, "", "Not all words were found")
EndIf

Func _AllWordsExist($sString, $sWords, $iTrigger)
    $sString = StringReplace($sString, "_", " ") ; Get rid of underscore
    $sWords = "(?i)\b(" & $sWords & ")\b" ; Case insensitive search between word boundries.
    Local $aResult = StringRegExp($sString, $sWords, 3)

    Local $bReturn = False
    If UBound($aResult) >= $iTrigger Then $bReturn = True
    Return $bReturn
EndFunc

That can be optimised to this ...

#include <Constants.au3>

; Though these are in "Global scope" they are actually used as Local. $sText isn't found anywhere else apart from where it was defined. Same for $sPattern.
Global $sTest = "This_is_the_string_I_want_to_test_for_multiple_Words_excluding_the_substring_in_pretext"
Global $sPattern = "string|text|words"

If _AllWordsExist($sTest, $sPattern, 3) Then
    MsgBox($MB_SYSTEMMODAL, "", "All words found")
Else
    MsgBox($MB_SYSTEMMODAL, "", "Not all words were found")
EndIf

Func _AllWordsExist($sString, $sWords, $iTrigger)
    $sString = StringReplace($sString, "_", " ") ; Get rid of underscore
    $sWords = "(?i)\b(" & $sWords & ")\b" ; Case insensitive search between word boundries.
    Return UBound(StringRegExp($sString, $sWords, 3)) >= $iTrigger
EndFunc   ;==>_AllWordsExist

But if the string is this...

Global $sTest = "This_is_the_string_string_I_want_to_test_for_multiple_Words_excluding_the_substring_in_pretext"

then it will return True when it's false.

[Nessie]

But if the string is this...

Global $sTest = "This_is_the_string_string_I_want_to_test_for_multiple_Words_excluding_the_substring_in_pretext"

then it will return True when it's false.

So this function is buggy? For you what is the best way to do what i want?

Hi! and thanks for the help!