_GUICtrlListView_SetItemImage where set image ???

[faustf]

hi guy i have a problem

i want set in colum 4 in listview a image but automatically set my image in column one and after in colum 4

why ????

this is my code

$areturn3=StringRegExp($sHTML,'/web/images/status_upload.png',3)

For $i3 = 0 To UBound($areturn3) - 1

$hImage = _GUIImageList_Create(16, 16, 5, 3)
_GUIImageList_AddIcon($hImage,  @ScriptDir & "\icon\up1.ico")
_GUICtrlListView_SetImageList($list1, $hImage, 1)
    _GUICtrlListView_SetItemImage($list1, 0, 0,3)
;_GUICtrlListView_SetItemImage($list1, 2, 1, 1)
MsgBox(0, "de", "Totale: "&$areturn3[$i3]&" Torrent")
;_GUICtrlListView_AddSubItem($list1, $v, $areturn1[$i1], 2, 2) ; 1   1
Next

thankzz alot

[PhoenixXL]

~got corrupted when I edited, please check my next post..

Edited May 11, 2013 by PhoenixXL

[guinness]

Where is _GDIPlus_ScaleImage located?

[GreenCan]

i want set in colum 4 in listview a image but automatically set my image in column one and after in colum 4

why ????

faustf,

May I suggest to have a look at this example provided by KaFu

Image in Listview issue

It will clarify how to avoid seeing the image in Col 1 (zero in fact) and also how to get rid of the empty space remaining in this column.

GreenCan

Edited May 10, 2013 by GreenCan

[GreenCan]

Where is _GDIPlus_ScaleImage located?

in the example script...

[guinness]

in the example script...

I meant backlink. Backlinks a really important, as they stop duplicate code becoming stagnant on the Forum. I know for a fact that UEZ, myself and others update functions in old posts, so it's also good to link back to where you got the original code.

[faustf]

i have  the same problem  i want icon only in 4  colum  but  give me   icon also in 1 colum  why ??

expandcollapse popup

Func _popola_list()
$sGET = ''
$areturn=''
$i=''
$v=0
$areturn1=''
$i1=''
$1=1
$prog=1

$sGET = "/cgi-bin/p2p.cgi?cmd=p2p_get_list_by_priority&page=1&rp=10&query=&qtype=&f_field=0"
_login_dlink()

$areturn=StringRegExp($sHTML,"alt='(.*?)'>",3)
$areturn1=StringRegExp($sHTML,'</span>(.*?)<span class=',3)

$areturn3=StringRegExp($sHTML,'/web/images/status_upload.png',3)

For $i = 0 To UBound($areturn) - 1


_GUICtrlListView_AddItem($list1,$areturn[$i], $v)



Next


For $i1 = 0 To UBound($areturn1) - 1

;MsgBox(0, "de", "Totale: "&$areturn1[$i1]&" Torrent")
_GUICtrlListView_AddSubItem($list1, $v, $areturn1[$i1], $1, $prog) ; 1   1

Next


For $i3 = 0 To UBound($areturn3) - 1


$hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage,  @ScriptDir & "\icon\up1.ico")

_GUICtrlListView_SetImageList($list1, $hImage, 1)
    _GUICtrlListView_SetItemImage($list1, 0, 0,3)
;_GUICtrlListView_SetItemImage($list1, 2, 1, 1)
;MsgBox(0, "de", "Totale: "&$areturn3[$i3]&" Torrent")
;_GUICtrlListView_AddSubItem($list1, $v, $areturn1[$i1], 2, 2) ; 1   1
_GUICtrlListView_AddSubItem($list1, 2, "Test item 3", 1)

_GUICtrlListView_SetColumnOrder($list1, "1|0")



Next


    EndFunc

[PhoenixXL]

Here we go

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <GDIPlus.au3>
 
$Debug_LV = False ; Check ClassName being passed to ListView functions, set to True and use a handle to another control to see it work
 
_Main()
 
Func _Main()
Local $hImage, $hListView, $exStyles = BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES)
 
GUICreate("ListView Set Item Image", 400, 300)
$hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
_GUICtrlListView_SetExtendedListViewStyle($hListView, $exStyles)
GUISetState()
 
_GDIPlus_Startup()
$hBmp = _GDIPlus_ScaleImage(StringReplace(@AutoItExe, "Autoit3.exe", "Examples\GUI\msoobe.jpg"), 16, 16)
$hHbmp = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBmp)
 
; Load images
$hImage = _GUIImageList_Create()
_GUIImageList_Add($hImage, $hHbmp)
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
_GUICtrlListView_SetImageList($hListView, $hImage, 1)
 
; Add columns
_GUICtrlListView_AddColumn($hListView, "Column 1", 100)
_GUICtrlListView_AddColumn($hListView, "Column 2", 100)
_GUICtrlListView_AddColumn($hListView, "Column 3", 100)
 
; Add items
_GUICtrlListView_AddItem($hListView, "Row 1: Col 1", 0)
_GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 2", 1, 1)
_GUICtrlListView_AddSubItem($hListView, 0, "Row 1: Col 3", 2, 2)
_GUICtrlListView_AddItem($hListView, "Row 2: Col 1", 1)
_GUICtrlListView_AddSubItem($hListView, 1, "Row 2: Col 2", 1, 2)
_GUICtrlListView_AddItem($hListView, "Row 3: Col 1", 2)
 
; Set item 1, subitem 1 image
_GUICtrlListView_SetItemImage($hListView, 1, 1, 1)
MsgBox(4160, "Information", "Item 1, SubItem 1 Image: " & _GUICtrlListView_GetItemImage($hListView, 1, 1))
 
; Loop until user exits
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
 
_GDIPlus_ImageDispose($hBmp)
_WinAPI_DeleteObject($hHbmp)
_GDIPlus_Shutdown()
EndFunc   ;==>_Main
 
;http://www.autoitscript.com/forum/topic/146301-sloved-winapi-getobject-on-gdiplus-bitmapclonearea-am-i-on-the-right-track/#entry1035413
Func _GDIPlus_ScaleImage($sFile, $iW, $iH, $iInterpolationMode = 7) ;coded by UEZ 2012
 
If Not FileExists($sFile) Then Return SetError(1, 0, 0)
Local $hImage = _GDIPlus_ImageLoadFromFile($sFile)
If @error Then Return SetError(2, 0, 0)
Local $hBitmap = DllCall($ghGDIPDll, "uint", "GdipCreateBitmapFromScan0", "int", $iW, "int", $iH, "int", 0, "int", 0x0026200A, "ptr", 0, "int*", 0)
If @error Then Return SetError(3, 0, 0)
$hBitmap = $hBitmap[6]
Local $hBmpCtxt = _GDIPlus_ImageGetGraphicsContext($hBitmap)
DllCall($ghGDIPDll, "uint", "GdipSetInterpolationMode", "handle", $hBmpCtxt, "int", $iInterpolationMode)
_GDIPlus_GraphicsDrawImageRect($hBmpCtxt, $hImage, 0, 0, $iW, $iH)
_GDIPlus_ImageDispose($hImage)
_GDIPlus_GraphicsDispose($hBmpCtxt)
Return $hBitmap
EndFunc   ;==>_GDIPlus_ScaleImage

Regards

Edited May 11, 2013 by PhoenixXL