MSDN OpenPrinter Function - how to use this

[mLipok]

http://msdn.microsoft.com/en-us/library/windows/desktop/dd162751(v=vs.85).aspx

Anybody can show me a way how to use this function in AutoIt ?

[Danyfirex]

Hi mLipok. You can do something like this:

Local $hwinspool = DllOpen("winspool.drv")


Local $bRet = DllCall($hwinspool, "bool", "GetDefaultPrinterW", "ptr", 0, "dword*", 0)
Local $pcchBuffer = $bRet[2]


Local $tBuffer = DllStructCreate("wchar[" & $pcchBuffer & "]")
Local $pBuffer = DllStructGetPtr($tBuffer, 1)

$bRet = DllCall($hwinspool, "bool", "GetDefaultPrinterW", "ptr", $pBuffer, "dword*", $pcchBuffer)


Local $sPrinter = DllStructGetData($tBuffer, 1)

MsgBox(0, $pcchBuffer, "Default Printer Name: " & $sPrinter)


$bRet = DllCall($hwinspool, "bool", "OpenPrinterW", "wstr", $sPrinter, "handle*", 0, "ptr", 0)
Local $hPrinter = $bRet[2]

MsgBox(0, "Printer Handle:", $hPrinter)


$bRet = DllCall($hwinspool, "bool", "ClosePrinter", "handle", $hPrinter)

DllClose($hwinspool)

Saludos

[mLipok]

Muchas gracias

mLipok