Jump to content

AppCompatFlags UDF

mLipok

By mLipok
in AutoIt Example Scripts

 Share

Recommended Posts

mLipok Universalist

mLipok

Posted
Posted 

#include <FileConstants.au3>
#include <MsgBoxConstants.au3>

#Region AppCompatFlags Constants

;~ HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\Layers
;~ HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\Layers

; #CONSTANTS# ===================================================================================================================
; Privilege level value
Global Const $__sACF_RUNASADMIN = 'RUNASADMIN' ; Run this program as an Administrator

; Settings value
Global Const $__sACF_HIGHDPIWARE = 'HIGHDPIWARE' ; Disable display scaling on high DPI settings
Global Const $__sACF_256COLOR = '256COLOR' ; Reduce color mode (8-bit 256)
Global Const $__sACF_16BITCOLOR = '16BITCOLOR' ; Reduce color mode (16-bit 65536)
Global Const $__sACF_640X480 = '640X480' ; Run in 640 x 480 screen resolution
Global Const $__sACF_PLACEHOLDERFILES = 'PLACEHOLDERFILES' ; Enable this program to work on SkyDrive files

; Compatibility mode value
Global Const $__sACF_WIN95 = 'WIN95' ; Windows 95
Global Const $__sACF_WIN98 = 'WIN98' ; Windows 98 / Windows ME
Global Const $__sACF_WINXPSP2 = 'WINXPSP2' ; Windows XP (Service Pack 2)
Global Const $__sACF_WINXPSP3 = 'WINXPSP3' ; Windows XP (Service Pack 3)
Global Const $__sACF_VISTARTM = 'VISTARTM' ; Windows Vista
Global Const $__sACF_VISTASP1 = 'VISTASP1' ; Windows Vista (Service Pack 1)
Global Const $__sACF_VISTASP2 = 'VISTASP2' ; Windows Vista (Service Pack 2)
Global Const $__sACF_WIN7RTM = 'WIN7RTM' ; Windows 7
Global Const $__sACF_WIN8RTM = 'WIN8RTM' ; Windows 8
Global Const $__sACF_WINSRV08SP1 = 'WINSRV08SP1' ; Windows Server 2008 SP1
Global Const $__sACF_REGEXP_Compability = '(WIN95|WIN98|WINXPSP2|WINXPSP3|VISTARTM|VISTASP1|VISTASP2|WIN7RTM|WIN8RTM|WINSRV08SP1)'

#Region EXAMPLE
Func Example()
    MsgBox($MB_SYSTEMMODAL, 'TEST', '_IsProgramInCompabilityMode() = ' & _IsProgramInCompabilityMode(@AutoItExe))
    MsgBox($MB_SYSTEMMODAL, 'TEST', '_IsProgramRunWithSetting() = ' & _
            _IsProgramRunWithSetting( _
            FileOpenDialog('Chose file to test', '', 'Program (*.exe)', $FD_FILEMUSTEXIST), _
            $__sACF_RUNASADMIN) _
            )
EndFunc   ;==>Example
#EndRegion EXAMPLE

#Region CURRENT
Func _IsProgramInCompabilityMode($sFileFullPath)
    Local $sRegKey = 'HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\Layers'
    Local $sValue
    For $i = 1 To 1000
        $sValueName = RegEnumVal($sRegKey, $i)
        If @error <> 0 Then ExitLoop
        If $sFileFullPath = $sValueName Then
            If StringRegExp(RegRead($sRegKey, $sValueName), $__sACF_REGEXP_Compability) Then
                Return True
            EndIf
        EndIf
    Next
    Return False
EndFunc   ;==>_IsProgramInCompabilityMode

Func _IsProgramRunWithSetting($sFileFullPath, $sSetting)
    Local $sRegKey = 'HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\Layers'
    Local $sValue
    For $i = 1 To 1000
        $sValueName = RegEnumVal($sRegKey, $i)
        If @error <> 0 Then ExitLoop
        If $sFileFullPath = $sValueName Then
            If StringInStr(RegRead($sRegKey, $sValueName), $sSetting) Then
                Return True
            EndIf
        EndIf
    Next
    Return False
EndFunc   ;==>_IsProgramRunWithSetting
#EndRegion CURRENT

HOWTO:

Example()

ps.

Not finished jet.

Signature beginning:
* Please remember: "AutoIt"..... *  Wondering who uses AutoIt and what it can be used for ? * Forum Rules *
* ADO.au3 UDF * POP3.au3 UDF * XML.au3 UDF * IE on Windows 11 * How to ask ChatGPT for AutoIt Code * for other useful stuff click the following button:

  Reveal hidden contents

Signature last update: 2023-04-24

z3r0c00l12 Seeker

z3r0c00l12

Posted
Posted

Nice work. Haven't tried it out yet, but it looks good. Are you working on a function to set the flags? I found that sometimes setting the registry key will change the settings but they don't take effect unless I manually interact with the compatibility tab.

mLipok Universalist

mLipok

Posted
  • Author
Posted

Check later ;)

Signature beginning:
* Please remember: "AutoIt"..... *  Wondering who uses AutoIt and what it can be used for ? * Forum Rules *
* ADO.au3 UDF * POP3.au3 UDF * XML.au3 UDF * IE on Windows 11 * How to ask ChatGPT for AutoIt Code * for other useful stuff click the following button:

  Reveal hidden contents

Signature last update: 2023-04-24

jguinch Universalist

jguinch

Posted
Posted (edited)

great !

Just to make it cleaner, you could replace your For loop by a While in both functions :

Func _IsProgramInCompabilityMode($sFileFullPath)
    Local $sRegKey = 'HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\Layers'
    Local $sValue
    Local $i = 0
    While 1
        $i += 1
        $sValueName = RegEnumVal($sRegKey, $i)
        If @error <> 0 Then ExitLoop
        If $sFileFullPath = $sValueName Then
            If StringRegExp(RegRead($sRegKey, $sValueName), $__sACF_REGEXP_Compability) Then
                Return True
            EndIf
        EndIf
    Next
    Return False
EndFunc   ;==>_IsProgramInCompabilityMode

Func _IsProgramRunWithSetting($sFileFullPath, $sSetting)
    Local $sRegKey = 'HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\Layers'
    Local $sValue
    Local $i = 0
    While 1
        $i += 1
        $sValueName = RegEnumVal($sRegKey, $i)
        If @error <> 0 Then ExitLoop
        If $sFileFullPath = $sValueName Then
            If StringInStr(RegRead($sRegKey, $sValueName), $sSetting) Then
                Return True
            EndIf
        EndIf
    Next
    Return False
EndFunc   ;==>_IsProgramRunWithSetting
Edited by jguinch
  Reveal hidden contents

 

mLipok Universalist

mLipok

Posted
  • Author
Posted

Good point.

Thanks.

mLipok

ps.

I was using code from HelpFile.

Signature beginning:
* Please remember: "AutoIt"..... *  Wondering who uses AutoIt and what it can be used for ? * Forum Rules *
* ADO.au3 UDF * POP3.au3 UDF * XML.au3 UDF * IE on Windows 11 * How to ask ChatGPT for AutoIt Code * for other useful stuff click the following button:

  Reveal hidden contents

Signature last update: 2023-04-24

mLipok Universalist

mLipok

Posted
  • Author
Posted

New Version:

#include <FileConstants.au3>
#include <MsgBoxConstants.au3>
#AutoIt3Wrapper_ShowProgress=n

#Region AppCompatFlags.au3 Constants

; #CONSTANTS# ===================================================================================================================
; Privilege level value
Global Const $__sACF_RUNASADMIN = 'RUNASADMIN' ; Run this program as an Administrator
Global Const $sRegKey = 'HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\Layers'

; Display Settings value
Global Const $__sACF_DISABLETHEMES = 'DISABLETHEMES' ; Disable Visual Themes
Global Const $__sACF_DISABLEDWM = 'DISABLEDWM' ; Disable Desktop Composition
Global Const $__sACF_HIGHDPIWARE = 'HIGHDPIWARE' ; Disable display scaling on high DPI settings
Global Const $__sACF_256COLOR = '256COLOR' ; Reduce color mode (8-bit 256)
Global Const $__sACF_16BITCOLOR = '16BITCOLOR' ; Reduce color mode (16-bit 65536)
Global Const $__sACF_640X480 = '640X480' ; Run in 640 x 480 screen resolution
Global Const $__sACF_PLACEHOLDERFILES = 'PLACEHOLDERFILES' ; Enable this program to work on SkyDrive files

; Compatibility mode value
Global Const $__sACF_WIN95 = 'WIN95' ; Windows 95
Global Const $__sACF_WIN98 = 'WIN98' ; Windows 98 / Windows ME
Global Const $__sACF_WIN4SP5 = 'WIN4SP5' ; Windows NT 4.0 SP5
Global Const $__sACF_WIN2000 = 'WIN2000' ; Windows 2000
Global Const $__sACF_WINXPSP2 = 'WINXPSP2' ; Windows XP (Service Pack 2)
Global Const $__sACF_WINXPSP3 = 'WINXPSP3' ; Windows XP (Service Pack 3)
Global Const $__sACF_VISTARTM = 'VISTARTM' ; Windows Vista
Global Const $__sACF_VISTASP1 = 'VISTASP1' ; Windows Vista (Service Pack 1)
Global Const $__sACF_VISTASP2 = 'VISTASP2' ; Windows Vista (Service Pack 2)
Global Const $__sACF_WIN7RTM = 'WIN7RTM' ; Windows 7
Global Const $__sACF_WIN8RTM = 'WIN8RTM' ; Windows 8
Global Const $__sACF_WINSRV03SP1 = 'WINSRV03SP1' ; Windows Server 2003 SP1
Global Const $__sACF_WINSRV08SP1 = 'WINSRV08SP1' ; Windows Server 2008 SP1

Global Const $__sACF_REGEXP_Compability = '(WIN95|WIN98|WIN4SP5|WIN2000|WINXPSP2|WINXPSP3|VISTARTM|VISTASP1|VISTASP2|WIN7RTM|WIN8RTM|WINSRV03SP1|WINSRV08SP1)'
#EndRegion AppCompatFlags.au3 Constants

#Region AppCompatFlags.au3 EXAMPLE
;~ Example()
Func Example()
    MsgBox($MB_SYSTEMMODAL, @AutoItExe, '_IsProgramInCompabilityMode() = ' & _IsProgramInCompabilityMode(@AutoItExe))
    MsgBox($MB_SYSTEMMODAL, @AutoItExe, '_GetProgramRunWithSetting() = ' & _GetProgramRunWithSetting(@AutoItExe))

    Local $sFileFullPath = FileOpenDialog('Chose file to test', '', 'Program (*.exe)', $FD_FILEMUSTEXIST)
    MsgBox($MB_SYSTEMMODAL, $sFileFullPath, '_IsProgramRunWithSetting() = ' & _IsProgramRunWithSetting($sFileFullPath, $__sACF_RUNASADMIN))
    MsgBox($MB_SYSTEMMODAL, $sFileFullPath, '_GetProgramRunWithSetting() = ' & _GetProgramRunWithSetting($sFileFullPath))
    MsgBox($MB_SYSTEMMODAL, $sFileFullPath, '_SetProgramRunWithSetting() = ' & _SetProgramRunWithSetting($sFileFullPath, $__sACF_640X480))
    MsgBox($MB_SYSTEMMODAL, $sFileFullPath, '_GetProgramRunWithSetting() = ' & _GetProgramRunWithSetting($sFileFullPath))
    MsgBox($MB_SYSTEMMODAL, $sFileFullPath, '_DeleteProgramRunWithSetting() = ' & _DeleteProgramRunWithSetting($sFileFullPath, $__sACF_640X480))
    MsgBox($MB_SYSTEMMODAL, $sFileFullPath, '_GetProgramRunWithSetting() = ' & _GetProgramRunWithSetting($sFileFullPath))
EndFunc   ;==>Example

#EndRegion AppCompatFlags.au3 EXAMPLE

#Region AppCompatFlags.au3 CURRENT

Func _IsProgramInCompabilityMode($sFileFullPath)
    Local $sValueName = ''
    Local $iInstance = 0
    If FileExists($sFileFullPath) Then
        Do
            If $sFileFullPath = $sValueName Then
                If StringRegExp(RegRead($sRegKey, $sValueName), $__sACF_REGEXP_Compability) Then
                    Return True
                EndIf
            EndIf
            $iInstance += 1
            $sValueName = RegEnumVal($sRegKey, $iInstance)
        Until @error
    EndIf
    Return False
EndFunc   ;==>_IsProgramInCompabilityMode

Func _IsProgramRunWithSetting($sFileFullPath, $sSetting)
    Local $sValueName = ''
    Local $iInstance = 0
    If FileExists($sFileFullPath) Then
        Do
            If $sFileFullPath = $sValueName Then
                If StringInStr(RegRead($sRegKey, $sValueName), $sSetting) Then
                    Return True
                EndIf
            EndIf
            $iInstance += 1
            $sValueName = RegEnumVal($sRegKey, $iInstance)
        Until @error
    EndIf
    Return False
EndFunc   ;==>_IsProgramRunWithSetting

Func _SetProgramRunWithSetting($sFileFullPath, $sSetting)
    Local $sValueName = '', $sValueCurrent = ''
    Local $iInstance = 0
    If FileExists($sFileFullPath) Then
        Do
            If $sFileFullPath = $sValueName Then
                $sValueCurrent = RegRead($sRegKey, $sValueName)
                If @error Then
                    Return SetError(@error, 0, 0)
                EndIf
                If Not StringInStr($sValueCurrent, $sSetting) Then
                    RegWrite($sRegKey, $sValueName, 'REG_SZ', $sValueCurrent & ' ' & $sSetting)
                    Return 1
                Else
                    Return 2
                EndIf
            EndIf
            $iInstance += 1
            $sValueName = RegEnumVal($sRegKey, $iInstance)
        Until @error
    Else
        Return SetError(-10, 0, 0)
    EndIf
EndFunc   ;==>_SetProgramRunWithSetting

Func _DeleteProgramRunWithSetting($sFileFullPath, $sSetting)
    Local $sValueName = '', $sValueCurrent = ''
    Local $iInstance = 0
    If FileExists($sFileFullPath) Then
        Do
            If $sFileFullPath = $sValueName Then
                $sValueCurrent = RegRead($sRegKey, $sValueName)
                If StringInStr($sValueCurrent, $sSetting) Then
                    $sValueCurrent = StringRegExpReplace($sValueCurrent, '( ' & $sSetting & '|' & $sSetting & ' |' & $sSetting & ')', '')
                    RegWrite($sRegKey, $sValueName, 'REG_SZ', $sValueCurrent)
                    Return 1
                EndIf
            EndIf
            $iInstance += 1
            $sValueName = RegEnumVal($sRegKey, $iInstance)
        Until @error
    EndIf
EndFunc   ;==>_DeleteProgramRunWithSetting

Func _GetProgramRunWithSetting($sFileFullPath)
    Local $sValueName = ''
    Local $iInstance = 0
    If FileExists($sFileFullPath) Then
        Do
            If $sFileFullPath = $sValueName Then
                Return RegRead($sRegKey, $sValueName)
            EndIf
            $iInstance += 1
            $sValueName = RegEnumVal($sRegKey, $iInstance)
        Until @error
    EndIf
    Return ''
EndFunc   ;==>_GetProgramRunWithSetting
#EndRegion AppCompatFlags.au3 CURRENT


#Region AppCompatFlags.au3 HELP DOC INFO
;~ HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\Layers
;~ HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\Layers

; Thanks to orbs; http://www.autoitscript.com/forum/user/47848-orbs/
; for this link:
;~ http://www.autoitscript.com/forum/topic/160016-change-properties-of-shortcut-lnk-file/

;~ http://www.robvanderwoude.com/files/appcompat_w7.txt
;~ http://msdn.microsoft.com/en-us/library/windows/desktop/dd371771(v=vs.85).aspx

;~ http://download.microsoft.com/download/1/f/e/1fe476f5-2b7a-4af1-a0ed-768454a0b5b1/Writing%20DPI%20Aware%20Applications.pdf
;~ http://msdn.microsoft.com/en-us/library/windows/desktop/dd464646(v=vs.85).aspx

#EndRegion AppCompatFlags.au3 HELP DOC INFO

Have fun.

Cheers

mLipok

Signature beginning:
* Please remember: "AutoIt"..... *  Wondering who uses AutoIt and what it can be used for ? * Forum Rules *
* ADO.au3 UDF * POP3.au3 UDF * XML.au3 UDF * IE on Windows 11 * How to ask ChatGPT for AutoIt Code * for other useful stuff click the following button:

  Reveal hidden contents

Signature last update: 2023-04-24

mLipok Universalist

mLipok

Posted
  • Author
Posted
  On 6/25/2014 at 12:21 PM, z3r0c00l12 said:

I found that sometimes setting the registry key will change the settings but they don't take effect unless I manually interact with the compatibility tab.

 

Did you check LogOut and LogIn to Windows ?

Signature beginning:
* Please remember: "AutoIt"..... *  Wondering who uses AutoIt and what it can be used for ? * Forum Rules *
* ADO.au3 UDF * POP3.au3 UDF * XML.au3 UDF * IE on Windows 11 * How to ask ChatGPT for AutoIt Code * for other useful stuff click the following button:

  Reveal hidden contents

Signature last update: 2023-04-24

mLipok Universalist

mLipok

Posted
  • Author
Posted

Thanks

I will check this tomorow.

Btw.

Any comments about Function Names , Variable Names, Constants Names, Algorithms and any other comments related to this UDF

are welcome.

I will do a CleanUp in few days.

Cheers

mLipok

Signature beginning:
* Please remember: "AutoIt"..... *  Wondering who uses AutoIt and what it can be used for ? * Forum Rules *
* ADO.au3 UDF * POP3.au3 UDF * XML.au3 UDF * IE on Windows 11 * How to ask ChatGPT for AutoIt Code * for other useful stuff click the following button:

  Reveal hidden contents

Signature last update: 2023-04-24

mLipok Universalist

mLipok

Posted
  • Author
Posted

request for a favor to Win8/Win8.1 users:

please check all Compability option manualy in any file and then use

Local $sFileFullPath = FileOpenDialog('Chose file to test', '', 'Program (*.exe)', $FD_FILEMUSTEXIST)
ClipPut(_GetProgramRunWithSetting($sFileFullPath))

and paste here a results from clipboard.

Thanks

mLipok

Signature beginning:
* Please remember: "AutoIt"..... *  Wondering who uses AutoIt and what it can be used for ? * Forum Rules *
* ADO.au3 UDF * POP3.au3 UDF * XML.au3 UDF * IE on Windows 11 * How to ask ChatGPT for AutoIt Code * for other useful stuff click the following button:

  Reveal hidden contents

Signature last update: 2023-04-24

  • 3 weeks later...
mLipok Universalist

mLipok

Posted
  • Author
Posted (edited)

a mistake ...  not related content...

  Reveal hidden contents

 

Edited by mLipok

Signature beginning:
* Please remember: "AutoIt"..... *  Wondering who uses AutoIt and what it can be used for ? * Forum Rules *
* ADO.au3 UDF * POP3.au3 UDF * XML.au3 UDF * IE on Windows 11 * How to ask ChatGPT for AutoIt Code * for other useful stuff click the following button:

  Reveal hidden contents

Signature last update: 2023-04-24

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
 Share
Go to topic listing
×
×
  • Create New...