Windows Update KB3078601

[mLipok]

how to check if this  Update KB3078601  is instaled or not ?

 

[Jon]

PowerShell, but you get the idea:

http://www.purestorage.com/blog/get-quick-fix-engineering-qfe-information/

 

[mLipok]

Thanks.

 

[Danyfirex]

I think is better use Windows Updates Agent API.

 

Local $oMUS=objCreate('Microsoft.Update.Session');
Local $oSearch=$oMUS.CreateUpdateSearcher


$oSearch.online=False

local $SearchResult= $oSearch.Search("IsInstalled = 1");
local $UpdateCollection  = $SearchResult.Updates

Local $Update =0
Local $IsInstalled=0
For $Update in $UpdateCollection
    ConsoleWrite($Update.Title & @CRLF)
if StringInStr($Update.Title,"KB3078601") Then
    $IsInstalled=1
    ExitLoop
EndIf

Next

MsgBox(0,"",($IsInstalled = 1) ? "KB3078601 is IsInstalled!" : "KB3078601 is not IsInstalled!")

Saludos

[Jon]

Oh that's nicer. Good write up here too using those APIs : http://blogs.technet.com/b/heyscriptingguy/archive/2009/03/09/how-can-i-list-all-updates-that-have-been-added-to-a-computer.aspx 

[JLogan3o13]

It's another way to skin the cat (and how I do it, incidentally), just curious what makes your way "better"?

[Danyfirex]

@JLogan3o13  compatibility.

Jon's suggestion (Minimum supported client Windows Vista)

mine (Windows XP)

As you're checking for a Windows 7 update you can use Jon's suggestion.

Edit: lol fixed Jon name.

Saludos

Edited September 10, 2015 by Danyfirex

[mLipok]

  On 9/10/2015 at 2:03 PM, Danyfirex said:

@JLogan3o13  compatibility.

Jos's suggestion

You mean Jon not Jos ?

 

[Danyfirex]

Si(yes). Sorry.

Saludos

[iamtheky]

ps from cli

$sKB = "KB3078601"
$iPid = run('powershell Get-CimInstance -ClassName Win32_QuickFixEngineering -property * | where HotFixID -like ' & $sKB , "" , @SW_HIDE , 0x2)

 

in use:

msgbox(0, '"KB3078601"' , _CheckKB("KB3078601"))
msgbox(0, '"*078*"' , _CheckKB("*078*"))


Func _CheckKB($sKB)

$iPid = run('powershell Get-CimInstance -ClassName Win32_QuickFixEngineering -property * | where HotFixID -like ' & $sKB , "" , @SW_HIDE , 0x2)

$sOutput = ""

 While 1
        $sOutput &= StdoutRead($iPID)
        If @error Then
            ExitLoop
        EndIf
     WEnd

     If $sOutput = "" then $sOutput = $sKB & " Not Found"

return $sOutput
EndFunc ;CheckKB

 

 

Edited September 10, 2015 by boththose
changed the query to -like so wildcards are accepted

[mLipok]

@Danyfirex

Funny at my home notebook it's not working properly.

after 30 minutes it's still on 

local $SearchResult= $oSearch.Search("IsInstalled = 1");

and going on.....

 

Edited September 10, 2015 by mLipok
typo

[Danyfirex]

Thry this instead:

Local $oMUS = ObjCreate('Microsoft.Update.Session');
Local $oSearch = $oMUS.CreateUpdateSearcher
Local $iCount = $oSearch.GetTotalHistoryCount()
Local $oHistoryCollection = $oSearch.QueryHistory(0, $iCount)

Local $Update = 0
Local $IsInstalled = 0

For $Update In $oHistoryCollection
    If StringInStr($Update.Title, "KB3078601") Then
        $IsInstalled = 1
        ExitLoop
    EndIf
Next

MsgBox(0, "", ($IsInstalled = 1) ? "KB3078601 is IsInstalled!" : "KB3078601 is not IsInstalled!")

Saludos

Edited September 10, 2015 by Danyfirex

[Danyfirex]

@boththose not need to use powershell use objget

local $objWMIService = ObjGet("winmgmts:" & "{impersonationLevel=impersonate}!\\" & "." & "\root\cimv2")
local $oQueryFixes = $objWMIService.ExecQuery("Select * from Win32_QuickFixEngineering")
Local $IsInstalled = 0
For $objFix in $oQueryFixes
    If $objFix.HotFixID= "KB3078601" Then
        $IsInstalled = 1
        ExitLoop
    EndIf
Next

MsgBox(0, "", ($IsInstalled = 1) ? "KB3078601 is IsInstalled!" : "KB3078601 is not IsInstalled!")

Saludos

[kylomas]

Danyfirex,

I was trying to get the code you post above to work using a where clause on the select stmt.  No objects were returned.  Can't post the code cause I'm on a stupid "smart" phone.

Kylomas

 

[Danyfirex]

@kylomas windows phone?  I really did not understand you.

 

Saludos

[mLipok]

  On 9/10/2015 at 4:19 PM, Danyfirex said:

Thry this instead:

Local $oMUS = ObjCreate('Microsoft.Update.Session');
Local $oSearch = $oMUS.CreateUpdateSearcher
Local $iCount = $oSearch.GetTotalHistoryCount()
Local $oHistoryCollection = $oSearch.QueryHistory(0, $iCount)

Local $Update = 0
Local $IsInstalled = 0

For $Update In $oHistoryCollection
    If StringInStr($Update.Title, "KB3078601") Then
        $IsInstalled = 1
        ExitLoop
    EndIf
Next

MsgBox(0, "", ($IsInstalled = 1) ? "KB3078601 is IsInstalled!" : "KB3078601 is not IsInstalled!")

Saludos

now this is super fast

 

[trancexx]

You could just check:

$sKB = "KB3078601"
$iInstalled = ObjGet("winmgmts:\\.\root\cimv2").ExecQuery('SELECT HotFixID FROM Win32_QuickFixEngineering WHERE HotFixID LIKE "' & $sKB & '"').Count()

One liner is possible because with WQL (SQL for WMI) keywords/operators can be used to refine queries.

[kylomas]

@trancexx - you nailed it...I was using "=", d'oh!