Incremental search in owner and custom drawn ListViews

[LarsJ]

Incremental search is usually implemented by drawing the background of the substrings that matches the search string with a specific color eg. yellow. Incremental in this context means that the search is performed dynamically after each character while the search string is typed.

In a listview this can be implemented by owner drawing through the LVS_OWNERDRAWFIXED flag and WM_DRAWITEM messages. (A custom drawn listview supports coloring of fields. However, the coloring works best for whole fields. This doesn't make it applicable to incremental search.)

Inspiration for the example is found in these two questions: Search box for names and Search In ListView (Redraw with matching string).

Examples
The zip file below contains three examples. Listview items are strings of random characters with different lengths. In all examples a global $iItems = 1000 in top of script specifies the number of rows. There are no performance issues up till 10,000 rows. Note that the search is performed in an array and not directly in the listview.

A regular expression can be entered in the search box. Search strings like "m........." with a varying number of dots will result in a varying number of matches.

To keep it simple only one occurrence of the search string in each item is tested. As soon as one occurrence is found the search loop moves on to next item.

1) Incremental text search.au3
The first example is a simple demonstration of basic functionality:

F3 and Shift+F3 can be used instead of Next and Prev buttons.

2) Show matching rows only.au3
An owner drawn listview can easily be combined with a virtual listview to extend the functionality of the incremental search. A virtual listview is especially interesting if you want to dynamically update the listview to only display the rows that matches the search string. Such an update is very fast in a virtual listview.

This example is useful if the listview contains a set of file names and you are searching for a specific file eg. to open the file. In this situation you are probably not interested in the files that doesn't match.

Because the listview only contains matching rows "Next match" and "Prev match" buttons are disabled.

Clear the search field to display all items.

3) Standard search dialog.au3
The last example is a demonstration of a standard search dialog as the search box in Notepad.

FindText function in comdlg32.dll creates the standard search box. The function is implemented as _WinAPI_FindTextDlg in WinAPIDlg.au3. In the Microsoft documentation you can read:

Note that the FINDREPLACE structure and the buffer for the search string should be a global or static variable so it does not go out of scope before the dialog box closes.

Because the FINDREPLACE structure is created as a local variable in _WinAPI_FindTextDlg it goes out of scope as soon as the function returns.

This implementation of FindText is used in the example:

;Func _WinAPI_FindTextDlg($hOwner, $sFindWhat = '', $iFlags = 0, $pFindProc = 0, $lParam = 0)
Func _WinAPI_FindTextDlgEx(ByRef $tFR, $hOwner, $sFindWhat = '', $iFlags = 0, $pFindProc = 0, $lParam = 0)
  $__g_pFRBuffer = __HeapReAlloc($__g_pFRBuffer, 2 * $__g_iFRBufferSize)
  If @error Then Return SetError(@error + 20, @extended, 0)

  DllStructSetData(DllStructCreate('wchar[' & $__g_iFRBufferSize & ']', $__g_pFRBuffer), 1, StringLeft($sFindWhat, $__g_iFRBufferSize - 1))
  ;Local $tFR = DllStructCreate($tagFINDREPLACE)
  $tFR = DllStructCreate($tagFINDREPLACE)
  DllStructSetData($tFR, 'Size', DllStructGetSize($tFR))
  DllStructSetData($tFR, 'hOwner', $hOwner)
  DllStructSetData($tFR, 'hInstance', 0)
  DllStructSetData($tFR, 'Flags', $iFlags)
  DllStructSetData($tFR, 'FindWhat', $__g_pFRBuffer)
  DllStructSetData($tFR, 'ReplaceWith', 0)
  DllStructSetData($tFR, 'FindWhatLen', $__g_iFRBufferSize * 2)
  DllStructSetData($tFR, 'ReplaceWithLen', 0)
  DllStructSetData($tFR, 'lParam', $lParam)
  DllStructSetData($tFR, 'Hook', $pFindProc)
  DllStructSetData($tFR, 'TemplateName', 0)

  Local $Ret = DllCall('comdlg32.dll', 'hwnd', 'FindTextW', 'struct*', $tFR)
  If @error Or Not $Ret[0] Then
    Local $Error = @error + 30
    __HeapFree($__g_pFRBuffer)
    If IsArray($Ret) Then
      Return SetError(10, _WinAPI_CommDlgExtendedErrorEx(), 0)
    Else
      Return SetError($Error, @extended, 0)
    EndIf
  EndIf

  Return $Ret[0]
EndFunc

Then it's ensured that the local variable that is used for $tFR in the script, does not go out of scope, while the search box is open.

ListviewIncrSearch.7z

• 1) Incremental text search.au3
• 2) Show matching rows only.au3
• 3) Standard Find text dialog.au3
• DrawItem.au3
• GuiListViewEx.au3
• WinAPIDlgEx.au3

You need AutoIt 3.3.14 or later. Tested on Windows 7 32/64 bit and Windows XP 32 bit.

Comments are welcome. Let me know if there are any issues.

(Set tab width = 2 in SciTE to line up comments by column.)

ListviewIncrSearch.7zFetching info...

Edited May 22, 2021 by LarsJ
Topic title

[mLipok]

Awesome.

Can you also make example how to automatically Hide/Show ListView Items with relation to this search string ?

EDIT:
oops i see

 2) Show matching rows only.au3

+5

 

Edited December 7, 2015 by mLipok

[mLipok]

Third example 3) Standard Find text dialog.au3  showing errors:

  Quote

>Running AU3Check (3.3.14.2)  from:C:\Program Files (x86)\AutoIt3  input:C:\Users\user\Downloads\ListviewIncrSearch\3) Standard Find text dialog.au3
"C:\Users\user\Downloads\ListviewIncrSearch\WinAPIDlgEx.au3"(10,43) : warning: $__pFRBuffer: possibly used before declaration.
    $__pFRBuffer = __HeapReAlloc($__pFRBuffer,
    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^
"C:\Users\user\Downloads\ListviewIncrSearch\WinAPIDlgEx.au3"(10,65) : warning: $__iFRBufferSize: possibly used before declaration.
    $__pFRBuffer = __HeapReAlloc($__pFRBuffer, 2 * $__iFRBufferSize)
    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^
"C:\Users\user\Downloads\ListviewIncrSearch\WinAPIDlgEx.au3"(10,65) : error: $__iFRBufferSize: undeclared global variable.
    $__pFRBuffer = __HeapReAlloc($__pFRBuffer, 2 * $__iFRBufferSize)
    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^
C:\Users\user\Downloads\ListviewIncrSearch\3) Standard Find text dialog.au3 - 1 error(s), 2 warning(s)

 

[LarsJ]

Oops, sorry, I'm still on 3.3.10. It must be the cause of the errors. I will take the opportunity to upgrade. And fix the errors. But I do not have time until tomorrow.

[mLipok]

No hurry up.
Thanks for the effort.

mLipok

[LarsJ]

Error in example 3 is addressed. New zip in the first post.

[mLipok]

Well written code 

[Digisoul]

Awesome. Thanks for sharing.

[dmob]

Thank you, I've always wanted this trickery 

[LarsJ]

You are welcome.

Thank you for feedback. Always nice.

I would have preferred to implement it in a custom drawn listview. But there was a lot of flicker. I've made a note about that. I'll look into it. And it would have been easier with some kind of UDF. I'm working on that.

[Lion66]

Hello.
Sorry to bring up the old topic.
I liked the example " 2) Show matching rows only.au3 ".
Added in "#include <WinAPI.au3>" for function "_WinAPI_SetWindowsHookEx".
Everything seemed to work, but when I try to write in a search with something in big letters (where caps look is on ) with unchecked "Use regular expression..." ,

the program crashes with an error.
Can somebody help me?
Thank.

[LarsJ]

Replace

If StringInStr( $aItems[$i], $sSearch ) Then ; Normal search

with

If StringInStr( $aItems[$i], $sSearch, $STR_CASESENSE ) Then ; Normal search

It should be done in all three examples.

 

The Hook functions were moved to WinAPISys.au3 last year.

[Lion66]

Thanks for the answer.
I need to use non-sensitive mode. I added

$STR_NOCASESENSEBASIC

Also I change some array fill letters to upper case.

The script crashes when I type the missing small letter. 😦

Edited July 8, 2019 by Lion66
edit

[Lion66]

LarsJ,

I'm not even sure the error occurs in the search or in the marking operation in yellow...

Edited July 16, 2019 by Lion66

[RAMzor]

Hello all!

First of all thanks LarsJ for awesome examples! It's really cool!

On the russian forum, I found a slightly modified (by Lion66) one of your examples. But, unfortunately, it seems it's a dead topic.
In the modified code several columns were added, but the search still on the first '0' column.
I tried to do a more advanced search with column select to search. In attached zip file you can find the code with and without marking!

Only without marking works 😜

And now my problem:
I tried to do the same with search and marking example code and it does't work. Crashes with an error and I have no idea how to fix it.

Anybody can help me with this? 😕

ListView Incremental Search Modified .zipFetching info...

Edited October 2, 2019 by RAMzor

[LarsJ]

Under what circumstances does the code fail? Windows version, 32/64 bit code, etc. What is the error when the code crashes?

I briefly tested "Search Example 2 - With Column Select And Marking.au3" under Windows 7 both 32 and 64 bit. It works fine with yellow background marking of the search text and without crashing.

[LarsJ]

Here is an example of search in several columns:

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7

#AutoIt3Wrapper_UseX64=y

Opt( "MustDeclareVars", 1 )

#include <WindowsConstants.au3>
#include <GUIConstants.au3>
#include <Array.au3>
#include "DrawItem.au3"
#include "GuiListViewEx.au3"

Global Const $tagMSG = "hwnd hwnd;uint message;wparam wParam;lparam lParam;dword time;int X;int Y"

Global $hGui, $idListView, $hListView, $fListViewHasFocus = 0, $iItems = 1000, $iCols = 4, $iCol = 0, $aItems[$iItems][$iCols]
Global $idSearch, $hSearch, $idSearchAction, $aSearch[$iItems], $iSearch = 0, $sSearch = ""

Example()


Func Example()
  ; Create GUI
  $hGui = GUICreate( "Show matching rows only - multiple columns", 1060, 330 )

  ; Create search group
  GUICtrlCreateGroup( "Search", 10, 5, 1060-20, 120 )

  ; Create Checkbox
  Local $idRegExp = GUICtrlCreateCheckbox( "Use regular expression as search string", 20, 25, 260, 20 )
  GUICtrlSetState( $idRegExp, $GUI_CHECKED )

  ; Create Edit control
  $idSearch = GUICtrlCreateEdit( "", 20, 55, 200, 20, $GUI_SS_DEFAULT_EDIT-$ES_AUTOVSCROLL-$WS_HSCROLL-$WS_VSCROLL )
  GUICtrlSetData( $idSearch, "Enter search string - possibly as reg. exp." )
  $hSearch = GUICtrlGetHandle( $idSearch )
  $idSearchAction = GUICtrlCreateDummy()

  ; Create read only Edit control for number of matches
  Local $idCount = GUICtrlCreateEdit( "0", 230, 55, 50, 20, $GUI_SS_DEFAULT_EDIT+$ES_READONLY+$ES_RIGHT-$WS_HSCROLL-$WS_VSCROLL )
  GUICtrlSetBkColor( $idCount, 0xFFFFFF )

  ; Create Buttons
  Local $idNext = GUICtrlCreateButton( "Next match",  20, 85, 125, 25 )
  Local $idPrev = GUICtrlCreateButton( "Prev match", 155, 85, 125, 25 )
  GUICtrlSetState( $idNext, $GUI_DISABLE )
  GUICtrlSetState( $idPrev, $GUI_DISABLE )

  ; Search column
  Local $idComboBox = GUICtrlCreateCombo( "Search column 0", 350, 25, 200, 20 )
  GUICtrlSetData( $idComboBox, "Search column 1|Search column 2|Search column 3" )

  ; Close group
  GUICtrlCreateGroup( "", -99, -99, 1, 1 )

  ; Create ListView
  $idListView = GUICtrlCreateListView( "", 10, 140, 1060-20, 180, $GUI_SS_DEFAULT_LISTVIEW+$LVS_OWNERDATA+$LVS_OWNERDRAWFIXED, $WS_EX_CLIENTEDGE+$LVS_EX_DOUBLEBUFFER )
  $hListView = GUICtrlGetHandle( $idListView )                                          ; Virtual        Owner drawn                            Reduces flicker
  _GUICtrlListView_AddColumn( $hListView, "Column 0",  250 )
  _GUICtrlListView_AddColumn( $hListView, "Column 1",  250 )
  _GUICtrlListView_AddColumn( $hListView, "Column 2",  250 )
  _GUICtrlListView_AddColumn( $hListView, "Column 3",  250 )

  ; Fill array
  FillArray( $aItems )
  _ArraySort( $aItems, 0, 0, 0, $iCol ) ; $iCol is the search column

  ; Set search array to display all items
  For $i = 0 To $iItems - 1
    $aSearch[$i] = $i
  Next
  $iSearch = $iItems

  ; Initialize ListView
  GUICtrlSendMsg( $idListView, $LVM_SETITEMCOUNT, $iSearch, 0 )

  ; Adjust height of GUI and ListView to fit 15 rows
  Local $iLvHeight = _GUICtrlListView_GetHeightToFitRows( $hListView, 15 )
  WinMove( $hGui, "", Default, Default, Default, WinGetPos( $hGui )[3] - WinGetClientSize( $hGui )[1] + $iLvHeight + 150 )
  WinMove( $hListView, "", Default, Default, Default, $iLvHeight )

  ; Register WM_ACTIVATE message handler
  ; To check when GUI receives/loses focus
  GUIRegisterMsg( $WM_ACTIVATE, "WM_ACTIVATE" )

  ; Register WM_COMMAND message handler
  ; To read search string from Edit control while it's typed in
  GUIRegisterMsg( $WM_COMMAND, "WM_COMMAND" )

  ; Register WM_DRAWITEM message handler
  ; To display items in an owner drawn ListView
  GUIRegisterMsg( $WM_DRAWITEM, "WM_DRAWITEM" )

  ; Register message handler to test ListView focus
  Local $hMessageHandler = DllCallbackRegister( "MessageHandler", "long", "int;wparam;lparam" )
  Local $hMessageHook = _WinAPI_SetWindowsHookEx( $WH_MSGFILTER, DllCallbackGetPtr( $hMessageHandler ), 0, _WinAPI_GetCurrentThreadId() )

  ; Show GUI
  GUISetState( @SW_SHOW )

  ; Message loop
  While 1
    Switch GUIGetMsg()
      Case $idSearchAction, $idRegExp
        $sSearch = GUICtrlRead( $idSearch )
        If $sSearch = "" Then
          ; Empty search string, display all items
          For $i = 0 To $iItems - 1
            $aSearch[$i] = $i
          Next
          $iSearch = $iItems
          GUICtrlSetData( $idCount, 0 )
        Else
          ; Find rows matching search string
          $iSearch = 0
          If GUICtrlRead( $idRegExp ) = $GUI_CHECKED Then
            For $i = 0 To $iItems - 1
              If StringRegExp( $aItems[$i][$iCol], $sSearch ) Then ; Reg. exp. search
                $aSearch[$iSearch] = $i
                $iSearch += 1
              EndIf
            Next
          Else
            For $i = 0 To $iItems - 1
              If StringInStr( $aItems[$i][$iCol], $sSearch ) Then ; Normal search
                $aSearch[$iSearch] = $i
                $iSearch += 1
              EndIf
            Next
          EndIf
          GUICtrlSetData( $idCount, $iSearch )
        EndIf
        GUICtrlSendMsg( $idListView, $LVM_SETITEMCOUNT, $iSearch, 0 )

      Case $idComboBox
        ; New search column
        $iCol = Int( StringRight( GUICtrlRead( $idComboBox ), 1 ) )
        _ArraySort( $aItems, 0, 0, 0, $iCol )
        GUICtrlSetData( $idSearch, "" )
        GUICtrlSendToDummy( $idSearchAction )

      Case $GUI_EVENT_CLOSE
        ExitLoop
    EndSwitch
  WEnd

  ; Cleanup
  _WinAPI_UnhookWindowsHookEx( $hMessageHook )
  GUIDelete()
EndFunc

; Check when GUI receives/loses focus
Func WM_ACTIVATE( $hWnd, $iMsg, $wParam, $lParam )
  #forceref $iMsg, $lParam
  If $hWnd = $hGui Then _
    $fListViewHasFocus += BitAND( $wParam, 0xFFFF ) ? 1 : -1
  Return $GUI_RUNDEFMSG
EndFunc

; Read search string from Edit control while it's typed in
Func WM_COMMAND( $hWnd, $iMsg, $wParam, $lParam )
  #forceref $hWnd, $iMsg
  Local Static $bEditClear = True
  Local $hWndFrom = $lParam
  Local $iCode = BitShift( $wParam, 16 ) ; High word
  Switch $hWndFrom
    Case $hSearch
      Switch $iCode
        Case $EN_CHANGE
          GUICtrlSendToDummy( $idSearchAction )
        Case $EN_SETFOCUS
          If $bEditClear Then
            GUICtrlSetData( $idSearch, "" )
            $bEditClear = False
          EndIf
      EndSwitch
  EndSwitch
  Return $GUI_RUNDEFMSG
EndFunc

; Display items in an owner drawn ListView
Func WM_DRAWITEM( $hWnd, $iMsg, $wParam, $lParam )
  Local Static $tRect = DllStructCreate( $tagRECT ), $pRect = DllStructGetPtr( $tRect ), $tSize = DllStructCreate( $tagSIZE )
  Local Static $hBrushYellow = _WinAPI_CreateSolidBrush( 0x00FFFF ), $hBrushCyan = _WinAPI_CreateSolidBrush( 0xFFFF00 ) ; Yellow and cyan, BGR
  Local Static $hBrushHighLight = _WinAPI_GetSysColorBrush( $COLOR_HIGHLIGHT ), $hBrushButtonFace = _WinAPI_GetSysColorBrush( $COLOR_BTNFACE )

  ; We can optimize code by removing Switch statements because the ListView is the only ownerdrawn control and only $ODA_DRAWENTIRE actions are present

  Local $tDrawItem = DllStructCreate( $tagDRAWITEM, $lParam ), $itemID = DllStructGetData( $tDrawItem, "itemID" ), $iState = DllStructGetData( $tDrawItem, "itemState" ), $hDC = DllStructGetData( $tDrawItem, "hDC" ), $sItemText

  ; Loop through columns
  ; $i is the column index
  For $i = 0 To $iCols - 1
    ; Subitem rectangle
    DllStructSetData( $tRect, 2, $i ) ; Top
    DllStructSetData( $tRect, 1, $LVIR_BOUNDS ) ; Left
    GUICtrlSendMsg( $idListView, $LVM_GETSUBITEMRECT, $itemID, $pRect )
    DllStructSetData( $tRect, 1, DllStructGetData( $tRect, 1 ) + 6 ) ; Left margin
    DllStructSetData( $tRect, 2, DllStructGetData( $tRect, 2 ) + 2 ) ; Top  margin

    ; Subitem background and text color
    If BitAND( $iState, $ODS_SELECTED ) Then _
      DllCall( "user32.dll", "int", "FillRect", "handle", $hDC, "struct*", $tRect, "handle", $fListViewHasFocus = 1 ? $hBrushHighLight : $hBrushButtonFace ) ; _WinAPI_FillRect
    DllCall( "gdi32.dll", "int", "SetTextColor", "handle", $hDC, "int", BitAND( $iState, $ODS_SELECTED ) ? $fListViewHasFocus = 1 ? 0xFFFFFF : 0x000000 : 0x000000 ) ; _WinAPI_SetTextColor

    ; Draw subitem text
    $sItemText = $aItems[$aSearch[$itemID]][$i]
    DllCall( "user32.dll", "int", "DrawTextW", "handle", $hDC, "wstr", $sItemText, "int", StringLen( $sItemText ), "struct*", $tRect, "uint", 0 ) ; _WinAPI_DrawText

    ; $i is column index
    ; $iCol is the search column
    ; Mark matching substring only if column index = search column
    If $i <> $iCol Then ContinueLoop

    ; Matching substring?
    If $sSearch Then
      Local $sMatch = StringRegExp( $sItemText, $sSearch, 1 ), $extended = @extended, $iLen = StringLen( $sMatch[0] )

      ; Rectangle for matching substring
      DllCall( "gdi32.dll", "bool", "GetTextExtentPoint32W", "handle", $hDC, "wstr", $sItemText, "int", $extended - $iLen - 1, "struct*", $tSize ) ; _WinAPI_GetTextExtentPoint32
      DllStructSetData( $tRect, "Left", DllStructGetData( $tRect, "Left" ) + DllStructGetData( $tSize, "X" ) )
      DllCall( "gdi32.dll", "bool", "GetTextExtentPoint32W", "handle", $hDC, "wstr", $sMatch[0], "int", $iLen, "struct*", $tSize ) ; _WinAPI_GetTextExtentPoint32
      DllStructSetData( $tRect, "Right", DllStructGetData( $tRect, "Left" ) + DllStructGetData( $tSize, "X" ) )

      ; Fill rectangle with yellow or cyan (selected) background color
      DllCall( "user32.dll", "int", "FillRect", "handle", $hDC, "struct*", $tRect, "handle", BitAND( $iState, $ODS_SELECTED ) ? $hBrushCyan : $hBrushYellow ) ; _WinAPI_FillRect

      ; Draw matching substring in rectangle
      DllCall( "gdi32.dll", "int", "SetTextColor", "handle", $hDC, "int", 0x000000 ) ; _WinAPI_SetTextColor
      DllCall( "user32.dll", "int", "DrawTextW", "handle", $hDC, "wstr", $sMatch[0], "int", $iLen, "struct*", $tRect, "uint", 0 ) ; _WinAPI_DrawText
    EndIf
  Next

  Return $GUI_RUNDEFMSG
  #forceref $hWnd, $iMsg, $wParam
EndFunc

; Message handler to test ListView focus
Func MessageHandler( $nCode, $wParam, $lParam )
  #forceref $nCode, $wParam
  Local $tMsg = DllStructCreate( $tagMSG, $lParam ), $iMsg = DllStructGetData( $tMsg, "message" )
  If $iMsg = $WM_LBUTTONDOWN Or $iMsg = $WM_RBUTTONDOWN Then $fListViewHasFocus = DllStructGetData( $tMsg, "hwnd" ) = $hListView ? 1 : 0
EndFunc

; Fill array with random strings
Func FillArray( ByRef $aItems )
  Local $aLetters[26] = [ 'a', 'b', 'c', 'd', 'e', 'f', 'g', 'h', 'i', 'j', 'k', 'l', 'm', _
                          'n', 'o', 'p', 'q', 'r', 's', 't', 'u', 'v', 'w', 'x', 'y', 'z' ], $s
  For $i = 0 To $iCols - 1
    For $j = 0 To $iItems - 1
      $s = $aLetters[Random(0,25,1)]
      For $k = 1 To Random(10,30,1)
        $s &= $aLetters[Random(0,25,1)]
      Next
      $aItems[$j][$i] = $s
    Next
  Next
EndFunc

2.2) Show matching rows only - multiple columns.au3Fetching info...

The include files in the zip in first post are needed.

Edited October 3, 2019 by LarsJ
Include files

[RAMzor]

Wow! 🤪

Thanks a lot! It was very helpful!

I make it case-insensitive by adding "(?i)". I'm not sure  if it best solution but it works

StringRegExp( $aItems[$i][$iCol], "(?i)" & $sSearch )

 

I'm confused and can't understand how to update the ListView after manipulation on data in array $aItems?

For example after add, delete or sorting rows. Only GUICtrlSendToDummy( $idSearchAction ) not make a sense

 

[LarsJ]

If you add or delete rows in the array, you must inform the listview of the new number of rows: GUICtrlSendMsg( $idListView, $LVM_SETITEMCOUNT, $iRows, 0 ). This command also redraws all visible listview items.

To redraw all visible listview items: GUICtrlSendMsg( $idListView, $LVM_REDRAWITEMS, 0, $iRows - 1 )

To redraw a single listview item: GUICtrlSendMsg( $idListView, $LVM_REDRAWITEMS, $iRow, $iRow )

[RAMzor]

I have implemented  yous recommendation and played with it. Unfortunately it still make me a hard life.
 

the sequence is (in my included file):

1. Start to type something in search box
2. Click 'Ascending Sort' button > crash because StringRegExp return non-array variable in $sMatch

 

Show matching rows only - multiple columns - Copy.au3Fetching info...