ADO.au3 UDF - BETA - Support Topic

[FMS]

Maybe I'm doing it wrong, but i get an error.
(I'm ratter new whit ADO :))

==> Variable must be of type "Object".:

Local $sDriver = 'SQL Server'
            Local $sDatabase = 'DB name'
            Local $sServer = 'X.X.X.X'
            Local $sUser = 'root'
            Local $sPassword = ''

            Local $sConnectionString = 'DRIVER={' & $sDriver & '};SERVER=' & $sServer & ';DATABASE=' & $sDatabase & ';UID=' & $sUser & ';PWD=' & $sPassword & ';'

            ; Create connection object
            Local $oConnection = _ADO_Connection_Create()
            Local $sQuery = Read_from_ini("settings",$cqueryset,"filialen","err_no_IP")
            ; Open connection with $sConnectionString
            _ADO_Connection_OpenConString($oConnection, $sConnectionString)
            If @error Then Return SetError(@error, @extended, $ADO_RET_FAILURE)

            ; Executing some query directly to Array of Arrays (instead to $oRecordset)
            Local $aRecordset = _ADO_Execute($oConnection, $sQUERY, True)

            Local $iColumnsCount = $aRecordset.Fields.Count
            Local $iRowsCount = $aRecordset.RecordCount
            MsgBox($MB_SYSTEMMODAL, "Test", "$iRowsCount = " & $iRowsCount & "$iColumnsCount = " & $iColumnsCount)

            ; Clean Up
            _ADO_Connection_Close($oConnection)
            $oConnection = Null

            ; Display Array Content with column names as headers
            _ADO_Recordset_Display($aRecordset, 'Recordset content')

 

[mLipok]

; Executing some query directly to Array of Arrays (instead to $oRecordset)
            ; Local $aRecordset = _ADO_Execute($oConnection, $sQUERY, True)

            ; Executing some query directly to $oRecordset
            Local $oRecordset = _ADO_Execute($oConnection, $sQUERY, False)

            Local $iColumnsCount = $oRecordset.Fields.Count
            Local $iRowsCount = $oRecordset.RecordCount

 

[ViciousXUSMC]

On ‎4‎/‎21‎/‎2016 at 4:19 AM, mLipok said:

Show your script, or at least snippet.

expandcollapse popup

#include "ADO.au3"
#Tidy_Parameters=/sort_funcs /reel
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w 7

#include <Array.au3>
#include <MsgBoxConstants.au3>
#include <AutoItConstants.au3>

; SetUP internal ADO.au3 UDF COMError Handler
_ADO_ComErrorHandler_UserFunction(_ADO_COMErrorHandler)

; Uncomment one of the following examples
;
;~ _Example_MSAccess()
 _Example_MSExcel()
;~ _Example_MSSQL()
;~ _Example_MySQL()
;~ _Example_PostgreSQL()

Func _Example_MSAccess()

    Local $sMDB_FileFullPath = 'Here put FileFullPath to your Access File'
    Local $sDriver = Default
    Local $sUser = Default
    Local $sPassword = Default

    Local $sConnectionString = _ADO_ConnectionString_Access($sMDB_FileFullPath, $sUser, $sPassword, $sDriver)

    _Example_1_RecordsetToConsole($sConnectionString, "Select * from SOME_TABLE")
    _Example_2_RecordsetDisplay($sConnectionString, "Select * from SOME_TABLE")
    _Example_3_ConnectionProperties($sConnectionString)

EndFunc    ;==>_Example_MSAccess

Func _Example_MSExcel()

    Local $sFileFullPath = Default  ; Here put FileFullPath to your Access File or use Default to open FileOpenDialog
    Local $sProvider = Default
    Local $sExtProperties = Default
    Local $HDR = Default
    Local $IMEX = Default

    Local $sConnectionString = _ADO_ConnectionString_Excel($sFileFullPath = Default, $sProvider , $sExtProperties , $HDR , $IMEX)

    _Example_1_RecordsetToConsole($sConnectionString, "select * from [Sheet1$]")
    _Example_2_RecordsetDisplay($sConnectionString, "select * from [Sheet1$]")
    _Example_3_ConnectionProperties($sConnectionString)

EndFunc    ;==>_Example_MSAccess

Func _Example_MSSQL()

    Local $sDriver = 'SQL Server'
    Local $sDatabase = 'YourBASENAME'
    Local $sServer = 'localhost\SQLExpress'
    Local $sUser = 'YourUserName'
    Local $sPassword = 'YourPassword'

    Local $sConnectionString = 'DRIVER={' & $sDriver & '};SERVER=' & $sServer & ';DATABASE=' & $sDatabase & ';UID=' & $sUser & ';PWD=' & $sPassword & ';'

    _Example_1_RecordsetToConsole($sConnectionString, "Select * from SOME_TABLE")
    _Example_2_RecordsetDisplay($sConnectionString, "Select * from SOME_TABLE")
    _Example_3_ConnectionProperties($sConnectionString)

    _Example_4_MSSQL($sServer, $sDatabase, $sUser, $sPassword, "Select * from SOME_TABLE")

EndFunc    ;==>_Example_MSSQL

Func _Example_MySQL()
    ; Link to Windows MySQL ODBC drivers
    ; https://dev.mysql.com/downloads/connector/odbc/

    Local $sDriver = 'MySQL ODBC 5.3 ANSI Driver' ; 'MySQL ODBC 5.3 UNICODE Driver'
    Local $sServer = 'localhost' ; change this string to YourServerLocation
    Local $sDatabase = 'world' ; change this string to YourDatabaseName
    Local $sPort = '3306' ; change this string to If your Server use non standard PORT
    Local $sUser = 'AutoIt' ; change this string to YourUserName
    Local $sPassword = 'AutoIt' ; change this string to YourPassword

    ; Local $sConnectionString = 'Driver={' & $sDriver & '};SERVER=' & $sServer & ';PORT=' & $sPort & ';DATABASE=' & $sDatabase & ';User=' & $sUser & ';Passwd=' & $sPassword & ';'
    Local $sConnectionString = _ADO_ConnectionString_MySQL($sUser , $sPassword , $sDatabase, $sDriver , $sServer , $sPort )

    _Example_1_RecordsetToConsole($sConnectionString, "SELECT * FROM city ")
    _Example_2_RecordsetDisplay($sConnectionString, "SELECT * FROM country WHERE Continent = 'Europe'")
    _Example_3_ConnectionProperties($sConnectionString)

EndFunc    ;==>_Example_PostgreSQL

Func _Example_PostgreSQL()
    Local $sDSN = 'PostgreSQL35W'
    Local $sDatabase = 'YourBASENAME'
    Local $sServer = ''
    Local $sPort = ''
    Local $sUser = 'YourUserName'
    Local $sPassword = 'YourPassword'

    Local $sConnectionString = 'DSN=' & $sDSN & ';DATABASE=' & $sDatabase & ';SERVER=' & $sServer & ';PORT=' & $sPort & ';UID=' & $sUser & ';PWD=' & $sPassword & ';'

    _Example_1_RecordsetToConsole($sConnectionString, "Select * from SOME_TABLE")
    _Example_2_RecordsetDisplay($sConnectionString, "Select * from SOME_TABLE")
    _Example_3_ConnectionProperties($sConnectionString)

EndFunc    ;==>_Example_PostgreSQL
#Region Common / internal

Func _Example_1_RecordsetToConsole($sConnectionString, $sQUERY)

    ; Create connection object
    Local $oConnection = _ADO_Connection_Create()

    ; Open connection with $sConnectionString
    _ADO_Connection_OpenConString($oConnection, $sConnectionString)
    If @error Then Return SetError(@error, @extended, $ADO_RET_FAILURE)

    ; Executing some query
    Local $oRecordset = _ADO_Execute($oConnection, $sQUERY)

    ; Get recordset to array of arrays (Conent and ColumnNames)
    Local $aRecordsetArray = _ADO_Recordset_ToArray($oRecordset, False)

    ; Get inner array - only conent of Recordset
    Local $aRecordsetContent = _ADO_RecordsetArray_GetContent($aRecordsetArray)

    ; Go through the array variable (Recorset Conent)
    Local $iColumn_count = UBound($aRecordsetContent, $UBOUND_COLUMNS)
    For $iRecord_idx = 0 To UBound($aRecordsetContent) - 1
        ConsoleWrite('==================================================================' & @CRLF)
        For $iColumn_idx = 0 To $iColumn_count - 1
            ConsoleWrite($aRecordsetContent[$iRecord_idx][$iColumn_idx] & @CRLF)
        Next
    Next

    ; Clean Up
    $oRecordset = Null
    _ADO_Connection_Close($oConnection)
    $oConnection = Null

EndFunc    ;==>_Example_1_RecordsetToConsole

Func _Example_2_RecordsetDisplay($sConnectionString, $sQUERY)

    ; Create connection object
    Local $oConnection = _ADO_Connection_Create()

    ; Open connection with $sConnectionString
    _ADO_Connection_OpenConString($oConnection, $sConnectionString)
    If @error Then Return SetError(@error, @extended, $ADO_RET_FAILURE)

    ; Executing some query directly to Array of Arrays (instead to $oRecordset)
    Local $aRecordset = _ADO_Execute($oConnection, $sQUERY, True)

    ; Clean Up
    _ADO_Connection_Close($oConnection)
    $oConnection = Null

    ; Display Array Content with column names as headers
    _ADO_Recordset_Display($aRecordset, 'Recordset content')

EndFunc    ;==>_Example_2_RecordsetDisplay

Func _Example_3_ConnectionProperties($sConnectionString)

    ; Create connection object
    Local $oConnection = _ADO_Connection_Create()

    ; Open connection with $sConnectionString
    _ADO_Connection_OpenConString($oConnection, $sConnectionString)
    If @error Then Return SetError(@error, @extended, $ADO_RET_FAILURE)

    ; Get all connection properties to Array
    Local $aProperties = _ADO_Connection_PropertiesToArray($oConnection)

    ; Clean Up
    _ADO_Connection_Close($oConnection)
    $oConnection = Null

    ; Show connection properties
    _ArrayDisplay($aProperties, "ADO connection - List of properties", "", 0, Default, "Name|Type|Value|Attributes")

EndFunc    ;==>_Example_3_ConnectionProperties

Func _Example_4_MSSQL($sServer, $sDatabase, $sUser, $sPassword, $sQUERY)

    ; Create connection object
    Local $oConnection = _ADO_Connection_Create()

    ; Open connection with $sConnectionString
    _ADO_Connection_OpenMSSQL($oConnection, $sServer, $sDatabase, $sUser, $sPassword, 'YourAppName', @ComputerName & '_' & 'YourProgram_UID')
    If @error Then Return SetError(@error, @extended, $ADO_RET_FAILURE)

    ; Executing some query directly to Array of Arrays (instead to $oRecordset)
    Local $aRecordset = _ADO_Execute($oConnection, $sQUERY, True)

    ; Clean Up
    _ADO_Connection_Close($oConnection)
    $oConnection = Null

    ; Display Array Content with column names as headers
    _ADO_Recordset_Display($aRecordset, 'Recordset content')

EndFunc    ;==>_Example_4_MSSQL
#EndRegion  Common / internal

 

[mLipok]

And what you see in SciTE console output pane ?
Please copy it here.

[mLipok]

oops

I see bug here:

Local $sConnectionString = _ADO_ConnectionString_Excel($sFileFullPath = Default, $sProvider , $sExtProperties , $HDR , $IMEX)

it should be like this:

Local $sConnectionString = _ADO_ConnectionString_Excel($sFileFullPath, $sProvider, $sExtProperties, $HDR, $IMEX)

 

Edited April 25, 2016 by mLipok

[ViciousXUSMC]

That looks to have fixed it, thought I even tried that already.

Now I just need to figure out how to take those results and work with them.

It looks like a standard array display so there should be an array I can work with somewhere, but its not something I have found yet.

I should be able to figure it out looking at the RecordsetToConsole code and reversing parts of it.

[mLipok]

Local $aRecordsetAsArray = _ADO_Execute($oConnection, $sQUERY1, True)
_ADO_Recordset_Display($aRecordsetAsArray)
Local $aRecordsetContent = _ADO_RecordsetArray_GetContent($aRecordsetAsArray)
For $iRecord_idx = 0 To UBound($aRecordsetContent) - 1
  ....
  ....
  ....
  ....
Next

or like you say from example: RecordsetToConsole

; Executing some query
    Local $oRecordset = _ADO_Execute($oConnection, $sQUERY)

    ; Get recordset to array of arrays (Conent and ColumnNames)
    Local $aRecordsetAsArray = _ADO_Recordset_ToArray($oRecordset, False)

    ; Get inner array - only conent of Recordset
    Local $aRecordsetContent = _ADO_RecordsetArray_GetContent($aRecordsetAsArray)

    ; Go through the array variable (Recorset Conent)
    Local $iColumn_count = UBound($aRecordsetContent, $UBOUND_COLUMNS)
    For $iRecord_idx = 0 To UBound($aRecordsetContent) - 1
        ....
        ....
        ....
    Next

 

[Vitorio]

Hi.

I'm using ADO.au3 in my script for inserting rows from website to Oracle:

...
; SetUP internal ADO.au3 UDF COMError Handler
_ADO_ComErrorHandler_UserFunction(_ADO_COMErrorHandler)
...
For $x=0 To UBound($arez) - 1
$sSQL = "insert into mytab_oper values(to_date('" & $arez[$x][0] & "','DD.MM.YYYY HH24:MI')," & _
                                             "'" & StringStripWS($arez[$x][1],1) & "'," & _
                                             "'" & StringStripWS($arez[$x][2],1) & "'," & _
                                             "to_date('" & $arez[$x][3] & "','DD.MM.YYYY')," & _
                                             "to_number('" & StringStripWS($arez[$x][4],8) & "')," & _
                                             "'" & StringRegExpReplace(StringStripWS($arez[$x][5],1),"'","''") & "'," & _
                                             "to_number('" & StringStripWS($arez[$x][6],8) & "')," & _
                                             "'" & StringRegExpReplace(StringStripWS($arez[$x][7],1),"'","''") & "'," & _
                                             "to_number('" & StringRegExpReplace($arez[$x][8],",",".") & "')," & _
                                             "to_number('" & StringRegExpReplace($arez[$x][9],",",".") & "')," & _
                                             "to_number('" & StringRegExpReplace($arez[$x][10],",",".") & "')," & _
                                             "to_number('" & StringRegExpReplace($arez[$x][11],",",".") & "')," & _
                                             "to_number('" & StringRegExpReplace($arez[$x][12],",",".") & "')," & _
                                             "to_number('" & StringRegExpReplace($arez[$x][13],",",".") & "')," & _
                                             "to_number('" & StringRegExpReplace($arez[$x][14],",",".") & "')," & _
                                             "to_number('" & StringRegExpReplace($arez[$x][15],",",".") & "')," & _
                                             "to_number('" & StringRegExpReplace($arez[$x][16],",",".") & "')," & _
                                             "to_number('" & StringRegExpReplace($arez[$x][17],",",".") & "')," & _
                                             "to_number('" & StringRegExpReplace($arez[$x][18],",",".") & "')," & _
                                             "to_number('" & StringRegExpReplace($arez[$x][19],",",".") & "')," & _
                                              "'" & StringStripWS($arez[$x][20],1) & "')"
;ConsoleWrite('$sSQL = '&$sSQL & @CRLF)
_ADO_Execute($oConnection, $sSQL)
Next
...

and receive an error message:

###############################
ADO.au3 v.2.1.13 BETA (1155) : ==> COM Error intercepted !
$oADO_Error.description is:    [Oracle][ODBC][Ora]ORA-01438: value larger than specified precision allowed for this column

$oADO_Error.windescription:    Ошибка.

$oADO_Error.number is:    80020009
$oADO_Error.lastdllerror is:    0
$oADO_Error.scriptline is:    1155
$oADO_Error.source is:    Microsoft OLE DB Provider for ODBC Drivers
$oADO_Error.helpfile is:    
$oADO_Error.helpcontext is:    0
###############################

How do I display only the description of an error, ie, value $ oADO_Error.description in a log file, or at least in a variable?

 

[mLipok]

; You can use your own COMErrorHandler instead internal ADO.au3 UDF COMError Handler - _ADO_COMErrorHandler
_ADO_ComErrorHandler_UserFunction(_ErrFunc)
MsgBox(0, 'Last COM Error description:', _ErrDescription())

Func _ErrFunc($oError)
    ConsoleWrite( _
            @ScriptName & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & _
            "$oError.description is: " & @TAB & $oError.description & @CRLF & _
            "$oError.windescription: " & @TAB & $oError.windescription & @CRLF & _
            "$oError.number is: " & @TAB & Hex($oError.number, 8) & @CRLF & _
            "$oError.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            "$oError.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            "$oError.source is : " & @TAB & $oError.source & @CRLF & _
            "$oError.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            "$oError.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF _
            )
    _ErrDescription($oError.description) ; store description to use it outsided UDF in your own function
EndFunc   ;==>_ErrFunc

Func _ErrDescription($sDescription = Default)
    Local Static $sDescription_static = ''
    If $sDescription <> Default Then $sDescription_static = $sDescription
    Return $sDescription_static
EndFunc

 

EDIT:
Welcome to the fourm @Vitorio.

Edited April 28, 2016 by mLipok
Fixed issue in:  Func _ErrFunc($oError)

[Vitorio]

Thanks! All runing!!!

[mLipok]

Nice to hear that

 

[FMS]

Hello,

I have here a snippet that is not running at the moment because (as mentioned before in this thread) $iRowsCountisn't working.(output is -1)
Maybe I'm using ADO wrong , I'm rather new at using ADO and I'm open for sugestions
code :

expandcollapse popup

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <GuiComboBoxEx.au3> ; for _GUICtrlComboBoxEx_ResetContent
#include <Array.au3>
#include "ADO.au3"

#Tidy_Parameters=/sort_funcs /reel
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w 7

_ADO_ComErrorHandler_UserFunction(_ADO_COMErrorHandler)

$Form1 = GUICreate("Form1", 330, 86, 192, 124)
   $cmb_1 = GUICtrlCreateCombo("Combo1", 16, 16, 145, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
   $cmb_2 = GUICtrlCreateCombo("Combo2", 176, 16, 145, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
   $btn_fill = GUICtrlCreateButton("fill combo", 40, 48, 75, 25)
   $btn_clc = GUICtrlCreateButton("clear combo", 200, 48, 75, 25)
GUISetState(@SW_SHOW)


While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
      Case $GUI_EVENT_CLOSE
         Exit
      Case $btn_fill
         get_from_db()
      Case $btn_clc
         _GUICtrlComboBoxEx_ResetContent(GUICtrlGetHandle($cmb_1))
         _GUICtrlComboBoxEx_ResetContent(GUICtrlGetHandle($cmb_2))
   EndSwitch
WEnd


Func get_from_db()

   Local $sDriver = 'SQL Server'
   Local $sDatabase = "db_name"
   Local $sServer = "127.0.0.1"
   Local $sUser = "username"
   Local $sPassword = "pass"

   Local $sConnectionString = 'DRIVER={' & $sDriver & '};SERVER=' & $sServer & ';DATABASE=' & $sDatabase & ';UID=' & $sUser & ';PWD=' & $sPassword & ';'

   Local $oConnection = _ADO_Connection_Create()

   _ADO_Connection_OpenConString($oConnection, $sConnectionString)
   If @error Then Return SetError(@error, @extended, $ADO_RET_FAILURE)

   Local $aRecordset = _ADO_Execute($oConnection, "SELECT TOP 10 ID,username,email FROM users;", False)
   Local $aRecordsetArray = _ADO_Recordset_ToArray($aRecordset, False)
   Local $aresult = $aRecordsetArray[2]
   Local $iColumnsCount = $aRecordset.Fields.Count
   Local $iRowsCount = $aRecordset.RecordCount
   ; Clean Up
   _ADO_Connection_Close($oConnection)
   $oConnection = Null

   MsgBox($MB_SYSTEMMODAL, "Test", "$iRowsCount = " & $iRowsCount & " $iColumnsCount = " & $iColumnsCount)

   Dim $username_array[0]
   Dim $email_array[0]

   Local $r = 0
   Do
      _ArrayAdd($username_array, $aresult[$r][1])
      _ArrayAdd($email_array, $aresult[$r][2])
      $r = $r + 1
   Until $r = 10;should been $iRowsCount  but this is -1

   $username_string = _ArrayToString($username_array, "|")
   $email_string = _ArrayToString($email_array, "|")

   GuiCtrlSetData($cmb_1, $username_string)
   GuiCtrlSetData($cmb_2, $email_string)
EndFunc

Is there somebody that can help me whit making this snippet work properly?

Edited April 29, 2016 by FMS

[mLipok]

1. Why you are using ; char in SQL Statement ?

2. What you see in SciTE console output pane ?

3.

Try to use some more error checking

Local $aRecordset = _ADO_Execute($oConnection, "SELECT TOP 10 ID,username,email FROM users;", False)
   If @error Then MsgBox($MB_ICONERROR, 'EXECUTE', '@error = ' & @error & @CRLF & '@extended = ' & @extended)

   Local $aRecordsetArray = _ADO_Recordset_ToArray($aRecordset, False)
   If @error Then MsgBox($MB_ICONERROR, 'RS To ARRAY', '@error = ' & @error & @CRLF & '@extended = ' & @extended)

   Local $aresult = $aRecordsetArray[2]
   Local $iColumnsCount = $aRecordset.Fields.Count
   Local $iRowsCount = $aRecordset.RecordCount

 

Edited April 29, 2016 by mLipok

[FMS]

1 minute ago, mLipok said:

Why you are using ; char in SQL Statement ?

 

force of habbit , but isn't the problem and is working well whit it.

[mLipok]

I made a test on my base:

Local $oRecordset = _ADO_Execute($oConnection, "SELECT TOP 10 * from [baza].dbo.sprawy;", False)
   Local $aRecordsetArray = _ADO_Recordset_ToArray($oRecordset, False)
   Local $aresult = $aRecordsetArray[2]
   Local $iColumnsCount = $oRecordset.Fields.Count
   MsgBox(0, '$iColumnsCount', $iColumnsCount)
   Local $iRowsCount = $oRecordset.RecordCount
    ; Clean Up
   _ADO_Connection_Close($oConnection)
   $oConnection = Null

All works well.

You should show SciTE console output pane then I think be able to help.

 

[FMS]

5 minutes ago, mLipok said:

I made a test on my base:

Local $oRecordset = _ADO_Execute($oConnection, "SELECT TOP 10 * from [baza].dbo.sprawy;", False)
   Local $aRecordsetArray = _ADO_Recordset_ToArray($oRecordset, False)
   Local $aresult = $aRecordsetArray[2]
   Local $iColumnsCount = $oRecordset.Fields.Count
   MsgBox(0, '$iColumnsCount', $iColumnsCount)
   Local $iRowsCount = $oRecordset.RecordCount
    ; Clean Up
   _ADO_Connection_Close($oConnection)
   $oConnection = Null

All works well.

You should show SciTE console output pane then I think be able to help.

 

sorry sorry,....... i made a crusial typo :S
I meant that $iRowsCount has a output of -1

(i edited the question sorry again)

Edited April 29, 2016 by FMS

[mLipok]

Trying to figure this out.

Now I found this:

https://msdn.microsoft.com/en-us/library/ms676701(v=vs.85).aspx

Use the RecordCount property to find out how many records are in a Recordset object. The property returns -1 when ADO cannot determine the number of records or if the provider or cursor type does not support RecordCount. 

 

[mLipok]

You can use:

Local $aRecordsetArray = _ADO_Recordset_ToArray($oRecordset, False)
   Local $iRowsCount = @extended

or:

;~    Local $aresult = $aRecordsetArray[2]
;~    Local $aresult = $aRecordsetArray[$ADO_RS_ARRAY_RSCONTENT]
   Local $aresult = _ADO_RecordsetArray_GetContent($aRecordsetArray)
   Local $iColumnsCount = UBound($aresult,$UBOUND_COLUMNS)
   Local $iRowsCount = UBound($aresult,$UBOUND_ROWS)

 

[FMS]

16 minutes ago, mLipok said:

You can use:

Local $aRecordsetArray = _ADO_Recordset_ToArray($oRecordset, False)
   Local $iRowsCount = @extended

or:

;~    Local $aresult = $aRecordsetArray[2]
;~    Local $aresult = $aRecordsetArray[$ADO_RS_ARRAY_RSCONTENT]
   Local $aresult = _ADO_RecordsetArray_GetContent($aRecordsetArray)
   Local $iColumnsCount = UBound($aresult,$UBOUND_COLUMNS)
   Local $iRowsCount = UBound($aresult,$UBOUND_ROWS)

 

THANKS!!! both working like a charm!!!!
But , correct me iff I'm wrong ;
both codes work but it's better to use the second because @extended could also something else iff a error occurs????

[mLipok]

Any script should always check for @error from any function that set @error

Here you have example for this case:

Local $iRowsCount = 0
Local $aRecordsetArray = _ADO_Recordset_ToArray($oRecordset, False)
If @error Then
    ....
Else    
    $iRowsCount = @extended
    ......
EndIf