Get current tab domain in Mozilla Firefox

[RegiOween]

Hello, coders!

I would like to know if it's possible to get the domain of a current tab in Mozilla Firefox (version 115 ESR).
The controls are not available in AutoIt Window Info, so I can't rely on GUI Control functions.

Thanks in advance!

[SOLVE-SMART]

Hi @RegiOween,

my suggestion is to write a Firefox Browser Extension which copies automatically the URL to the clipboard.
This can be the behavior for each URL you load in the browser or for a specific range of URLs (filter).

Then you could parse the URL for the domain or other parts of the URL with AutoIt or other languages.
The browser extension can be published, so you could distribute the extension on multiple computers.

(It's not hard to write a browser extension - ask ChatGPT for examples. Requirements of this kind are widespread and there is a lot of data.)

-------------

Otherwise you can use the au3WebDriver project, aka WebDriver for AutoIt, to achieve this. What could be helpful is autoit-webdriver-boilerplate as a quick entry point to the WebDriver topic.

Those are the options that first came to my mind.

Best regards
Sven

Edited August 27, 2025 by SOLVE-SMART

[SOLVE-SMART]

Or a typical (and short) AutoIt approach:
Use functions like WinActivate() + Send() + ClipGet() to navigate to the address bar and copy the URL. Then do your parsing and you are good.

• CTRL+L
• CTRL+C
• ClipGet() ...

Best regards
Sven

[mLipok]

Maybe UIA ?
 

Quote

0000    Window: Pobierz Firefoksa na Androida i iOS — Mozilla Firefox
0001        ToolBar: Nawigacja
0002            Group
0003                ComboBox
0004                    Edit: Wprowadź adres lub szukaj w Google
0005                        Edit: www.mozilla.org/pl/firefox/142.0/whatsnew/?oldversion=141.0.3&utm_medium=firefox-desktop&utm_source=update&utm_campaign=142

 

[ioa747]

I slightly modified something I had ready, and here are the results

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>

Opt("TrayAutoPause", 0)

HotKeySet("{END}", "main") ; <- HotKeySet -<<

While 1
    Sleep(50)
WEnd

Exit

;---------------------------------------------------------------------------------------
Func main()
    Local $sDomain = GetDomain()
    MsgBox(4096, "Domain:", $sDomain)
EndFunc   ;==>main
;---------------------------------------------------------------------------------------
Func GetDomain($sFullUrl = "")
    Local $sDomain = "", $iError = 0
    If $sFullUrl = "" Then $sFullUrl = _ExtractLink()
    If Not @error Then ; Regex pattern to match the domain.
        Local $aMatch = StringRegExp($sFullUrl, '(?:https?:\/\/)?(?:[^@\n]+@)?(?:www\.)?([^:\/\n?]+)', 3)
        If Not @error Then
            $sDomain = $aMatch[0]
        Else
            $iError = @error
            $sDomain = "Could not extract domain."
        EndIf
    Else ; I can't recognize the Url
        $iError = @error
        $sDomain = "I can't recognize the Url"
    EndIf
    Return SetError($iError, 0, $sDomain)
EndFunc   ;==>GetDomain
;---------------------------------------------------------------------------------------
Func _ExtractLink() ; Extract Link
    Local $hWnd = WinGetHandle("[ACTIVE]")
    Local $sTitle = WinGetTitle($hWnd)
    Local $sResult
    If StringRegExp($sTitle, "(?i)(.* — Mozilla Firefox.*|.* - Google Chrome.*)") Then
        Local $ClipBak = ClipGet() ; backUp ClipData
        WinActivate($hWnd)
        Send("{F6}")       ; go in adresse bar
        Sleep(10)
        Send("{CTRLDOWN}") ; copy the link
        Send("c")
        Send("{CTRLUP}")
        Send("{F6}")       ; deselect the link
        Sleep(100)
        Local $sLnk = ClipGet()
        Sleep(100)

        $sResult = $sLnk
        ClipPut($ClipBak) ; Restore backUp ClipData

        Return $sResult
    EndIf

    Return SetError(1, 0, "")
EndFunc   ;==>_ExtractLink

 

Edited August 27, 2025 by ioa747

[RegiOween]

15 hours ago, SOLVE-SMART said:

Hi @RegiOween,

my suggestion is to write a Firefox Browser Extension which copies automatically the URL to the clipboard.
This can be the behavior for each URL you load in the browser or for a specific range of URLs (filter).

Then you could parse the URL for the domain or other parts of the URL with AutoIt or other languages.
The browser extension can be published, so you could distribute the extension on multiple computers.

(It's not hard to write a browser extension - ask ChatGPT for examples. Requirements of this kind are widespread and there is a lot of data.)

-------------

Otherwise you can use the au3WebDriver project, aka WebDriver for AutoIt, to achieve this. What could be helpful is autoit-webdriver-boilerplate as a quick entry point to the WebDriver topic.

Those are the options that first came to my mind.

Best regards
Sven

Hello, SOLVE-SMART!

I think au3WebDriver is the way to go. It seems powerful enough for my simple goal.
Thank you!

[RegiOween]

8 hours ago, ioa747 said:

I slightly modified something I had ready, and here are the results

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>

Opt("TrayAutoPause", 0)

HotKeySet("{END}", "main") ; <- HotKeySet -<<

While 1
    Sleep(50)
WEnd

Exit

;---------------------------------------------------------------------------------------
Func main()
    Local $sDomain = GetDomain()
    MsgBox(4096, "Domain:", $sDomain)
EndFunc   ;==>main
;---------------------------------------------------------------------------------------
Func GetDomain($sFullUrl = "")
    Local $sDomain = "", $iError = 0
    If $sFullUrl = "" Then $sFullUrl = _ExtractLink()
    If Not @error Then ; Regex pattern to match the domain.
        Local $aMatch = StringRegExp($sFullUrl, '(?:https?:\/\/)?(?:[^@\n]+@)?(?:www\.)?([^:\/\n?]+)', 3)
        If Not @error Then
            $sDomain = $aMatch[0]
        Else
            $iError = @error
            $sDomain = "Could not extract domain."
        EndIf
    Else ; I can't recognize the Url
        $iError = @error
        $sDomain = "I can't recognize the Url"
    EndIf
    Return SetError($iError, 0, $sDomain)
EndFunc   ;==>GetDomain
;---------------------------------------------------------------------------------------
Func _ExtractLink() ; Extract Link
    Local $hWnd = WinGetHandle("[ACTIVE]")
    Local $sTitle = WinGetTitle($hWnd)
    Local $sResult
    If StringRegExp($sTitle, "(?i)(.* — Mozilla Firefox.*|.* - Google Chrome.*)") Then
        Local $ClipBak = ClipGet() ; backUp ClipData
        WinActivate($hWnd)
        Send("{F6}")       ; go in adresse bar
        Sleep(10)
        Send("{CTRLDOWN}") ; copy the link
        Send("c")
        Send("{CTRLUP}")
        Send("{F6}")       ; deselect the link
        Sleep(100)
        Local $sLnk = ClipGet()
        Sleep(100)

        $sResult = $sLnk
        ClipPut($ClipBak) ; Restore backUp ClipData

        Return $sResult
    EndIf

    Return SetError(1, 0, "")
EndFunc   ;==>_ExtractLink

 

Hello, ioa747!

Your code works exactly the way I need, even on Firefox ESR (Extended Support Release) and also on Chrome.
Thank you very much, mate. I own you a virtual beer! 🍺🎃

[ioa747]

     cheers!