what function to use?

[tempman]

$IP = "100.200.50.25"
$IP1 = ; result need to be 100
$IP2 = ; result need to be 200
$IP3 = ; result need to be 50
$IP4 = ; result need to be 25
$decIP = ($IP1*256*256*256)+($IP2*256*256)+($IP3*256)+$IP4
MsgBox(0, "Decimal IP is:", $decIP)

[guinness]

StringSplit or StringRegExp.

[tempman]

I was afraid that someone will answer me like that.

Any similar example , please...

[Eugenii]

You need something like this

#include <Array.au3>

$IP = "100.200.50.25"
$temp=StringRegExp($IP,"(\d{0,3})\.(\d{0,3})\.(\d{0,3})\.(\d{0,3})",3)
_ArrayDisplay($temp,"")
$IP1 =$temp[0] ; result need to be 100
$IP2 =$temp[1] ; result need to be 200
$IP3 =$temp[2] ; result need to be 50
$IP4 =$temp[3] ; result need to be 25
$decIP = ($IP1*256*256*256)+($IP2*256*256)+($IP3*256)+$IP4
MsgBox(0, "Decimal IP is:", $decIP)

Exit

Or maybe next example will be more simple

#include <Array.au3>
#include <String.au3>

$IP = "100.200.50.25"
$temp=StringSplit($IP,'.')
_ArrayDisplay($temp,"")
$IP1 =$temp[1] ; result need to be 100
$IP2 =$temp[2] ; result need to be 200
$IP3 =$temp[3] ; result need to be 50
$IP4 =$temp[4] ; result need to be 25
$decIP = ($IP1*256*256*256)+($IP2*256*256)+($IP3*256)+$IP4
MsgBox(0, "Decimal IP is:", $decIP)

Exit

Edited January 15, 2013 by Eugenii

[tempman]

thanks

[water]

Why do you need an example for StringSplit or StringRegExp? Have a look in the help file and you will see how the function works (means: example included)!

[guinness]

I was afraid that someone will answer me like that.

Any similar example , please...

Answer you with the correct answer! Sorry about that, my fault! Edited January 15, 2013 by guinness

[guinness]

Took me 5 seconds to find >>

Edited January 15, 2013 by guinness

[JohnOne]

expandcollapse popup

; http://www.autoitscript.com/forum/topic/124279-ipv4toint/
; Example 1. use google IP
$_Ipv4ToInt = _Ipv4ToInt("173.194.66.94")
MsgBox(0,"_Ipv4ToInt",$_Ipv4ToInt)
ShellExecute("http://" & $_Ipv4ToInt)

; Example 2. Use int generated from _Ipv4ToInt
$_IntToIpv4 = _IntToIpv4($_Ipv4ToInt)
MsgBox(0,"_IntToIpv4",$_IntToIpv4)
ShellExecute("http://" & $_IntToIpv4)
;=============================================================================
;                        Converts an Int into an IP
;=============================================================================
Func _IntToIpv4($_Int)
    $oct1 = $_Int / 16777216
    $_Int = Mod($_Int, 16777216)
    $oct2 = Int($_Int) / 65536
    $_Int = Mod($_Int, 65536)
    $oct3 = $_Int / 256
    $_Int = Mod($_Int, 256)
    $oct4 = $_Int
    $sIP = Int($oct1) & "." & Int($oct2) & "." & Int($oct3) & "." & Int($oct4)
    Return String($sIP)
EndFunc   ;==>_IntToIpv4


;=============================================================================
;                         Converts an IP into an int
;=============================================================================
Func _Ipv4ToInt($_IP)
    $aIP = StringSplit($_IP, ".", 3)
    $oct1 = Int($aIP[0]) * (256 ^ 3)
    $oct2 = Int($aIP[1]) * (256 ^ 2)
    $oct3 = Int($aIP[2]) * (256)
    $oct4 = Int($aIP[3])
    $iInt = $oct1 + $oct2 + $oct3 + $oct4
    ConsoleWrite ($iInt & @CRLF)
    Return $iInt
EndFunc   ;==>_Ipv4ToInt

Edited January 15, 2013 by JohnOne

[PhoenixXL]

Yet another example with StringRegExp

$IP = "100.200.50.25"
$Array_IP = StringRegExp($IP, '([^.]+)', 3)
$IP_Dec = 0
For $i = 0 To 3
$IP_Dec += $Array_IP[$i] * (256 ^ (3 - $i))
Next

MsgBox(64, "Decimal IP is:", $IP_Dec)

[BrewManNH]

Or use this function from the Wiki that converts the IP address into an array with each octet in its own element and the hexidecimal value of the IP in another.