HotKeySet in Help File is Broke?

[l3ill]

Hi,

  been searching for a way to Pause a HotKeySet and it would seem that the Help File has one beautifully prepared.

But it turns out that Pause does not stop the HotKeySet from working.

  Anyone know why? And/Or how to fix it?

Thanks,

Bill

[water]

The example script doesn't pause the HotKeySet but the script itself by executing a Sleep statement until the Pause key is pressed again.

[BrewManNH]

What do you mean by "pause a hotkeyset"? The example in the Help file is showing how to pause a script using the Pause button in a hotkeyset statement, and it pauses the script as written.

[l3ill]

Yo,   Thats sort of what I said....

Any way to actually pause a HKS (cause the script not to react to input) ?

 

What do you mean by "pause a hotkeyset"? The example in the Help file is showing how to pause a script using the Pause button in a hotkeyset statement, and it pauses the script as written.

 If you Pause the script you can still use the scripts functions. Not really a pause IMO

Edited October 27, 2013 by billo

[Melba23]

billo,

Are you talking about the example script for HotKeySet itself?

If so, then the TogglePause function is not designed to "pause" the other HotKeys (obviously the HotKey to toggle the pause must remain active. If you wanted to prevent the Shift-Alt-d HotKey from working when the script was paused then you need to set/unset the HotKey like this:

#include <MsgBoxConstants.au3>

; Press Esc to terminate script, Pause/Break to "pause"

Global $fPaused = False

HotKeySet("{PAUSE}", "TogglePause")
HotKeySet("{ESC}", "Terminate")
HotKeySet("+!d", "ShowMessage") ;Shift-Alt-d

While 1
    Sleep(100)
WEnd

Func TogglePause()
    $fPaused = Not $fPaused
    If $fPaused Then
        HotKeySet("+!d") ; Unset HotKey <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
    Else
        HotKeySet("+!d", "ShowMessage") ; Set HotKey <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
    EndIf
    While $fPaused
        Sleep(100)
        ToolTip('Script is "Paused"', 0, 0)
    WEnd
    ToolTip("")
EndFunc   ;==>TogglePause

Func Terminate()
    Exit
EndFunc   ;==>Terminate

Func ShowMessage()
    MsgBox($MB_SYSTEMMODAL, "", "This is a message.")
EndFunc   ;==>ShowMessage

M23

[BrewManNH]

Please explain, in detail, what you want to do. Because right now, I'm still not understanding what pause a hotkeyset means in your thoughts, because it makes no sense in mine.

[l3ill]

li'l help ? :-)  could not find on the fly

ERROR: can't open include file <MsgBoxConstants.au3

A download link would be sweet

 

Nevermind...it works without it.

Thanks Melba !!!

Edited October 27, 2013 by billo

[l3ill]

 

Please explain, in detail, what you want to do. Because right now, I'm still not understanding what pause a hotkeyset means in your thoughts, because it makes no sense in mine.

If you test the HKS from the helpfile there are three functions:

TogglePause, Exit and Pop up message

Normally it should be assumable that pausing would cause the script itself to stop receiving commands or FUNCtioning.

But if you push <pause> the popup function still works.

[guinness]

MsgBoxConstants.au3 is only the AutoIt beta and not the stable. We decided it would be best to place MsgBox() constants from Constants.au3 to a new include file. Though it's still included in Constants.au3 for backwards compatibility.

[l3ill]

NP, on second look I realized it wasn't necessary for the code to work. Thanks for the info!