Detect hover/unhover and push/release on components using GUIRegisterMsg (not only with buttons)

[ZDS]

Hi everyone (sorry if I don't speak well, I'm a frog eater ^^).

I'm looking for help in order to make a simple script able to detect hover/unhover a control with a GUIRegisterMsg command. Same thing with push/release the control (a button in my example). I'm avoiding the _IsPressed function (because of the possible false-positives with BitDefender and others, like with the UPX) and trying to make something short which will consume the minimum resources.

Here is my base-code : 

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


; Unknown constants
Global Const $UNKNOWN_VALUE_FOR_HOVERING   = 0x123456789ABCDEF
Global Const $UNKNOWN_VALUE_FOR_UNHOVERING = 0x123456789ABCDEF
Global Const $UNKNOWN_VALUE_FOR_PUSHING    = 0x123456789ABCDEF
Global Const $UNKNOWN_VALUE_FOR_RELEASING  = 0x123456789ABCDEF
Global Const $tagNMHDR = "struct; hwnd hWndFrom;uint_ptr IDFrom;INT Code; endstruct"


; Variables
Global $dimension[2] = [200, 80]
; Graphic components
Global $GUI = GUICreate("Essai de champ password", $dimension[0], $dimension[1], Default, Default, 0x80800000) ; $WS_POPUP = 0x80000000 ; $WS_BORDER = 0x00800000
Global $title  = GUICtrlCreateLabel("Password", 10, 10, $dimension[0]-55, 25, Default, 0x00100000) ; $GUI_WS_EX_PARENTDRAG = 0x00100000
Global $quit   = GUICtrlCreateButton("X", $dimension[0]-35, 10, 25, 25)
Global $input  = GUICtrlCreateInput("Passw0rd!", 10, 45, $dimension[0]-55, 25, 0x0020) ; $ES_PASSWORD = 0x0020
Global $input2 = GUICtrlCreateInput("Passw0rd!", 10, 45, $dimension[0]-55, 25)
Global $button = GUICtrlCreateButton("", $dimension[0]-35, 45, 25, 25)
; Mise à jour des composants graphiques
GUICtrlSetBkColor($title, -2) ; $GUI_BKCOLOR_TRANSPARENT = -2
GUICtrlSetFont($title, 15, 800)
GUICtrlSetState($input2, $GUI_HIDE)


GUIRegisterMsg($WM_NOTIFY, "notify")


GUISetState(@SW_SHOW, $GUI)


Local $stop = False, $previous = ""
Do
   ; Classic msg loop
Local $msg = GUIGetMsg()
If @error = 0 Then
Switch $msg
Case -3 ; $GUI_EVENT_CLOSE = -3
$stop = True
Case $quit
$stop = True
EndSwitch
EndIf
; Input has changed
If $previous <> GUICtrlRead($input) Then
$previous = GUICtrlRead($input)
GUICtrlSetData($input2, $previous)
EndIf
Until $stop
GUIDelete($GUI)


Func notify($hWnd, $Msg, $wParam, $lParam)
Local $info = DllStructCreate($tagNMHDR, $lParam)
If $Hwnd = $GUI Then ; TODO : Detect the $button component
Switch DllStructGetData($info, "Code")
Case $UNKNOWN_VALUE_FOR_HOVERING
hoveringButton()
Case $UNKNOWN_VALUE_FOR_UNHOVERING
unhoveringButton()
Case $UNKNOWN_VALUE_FOR_PUSHING
pushingButton()
Case $UNKNOWN_VALUE_FOR_RELEASING
releasingButton()
EndSwitch
EndIf
Return $GUI_RUNDEFMSG
EndFunc


Func hoveringButton()
ConsoleWrite(" => hoveringButton"&@CRLF)
GUICtrlSetColor($input, 0xFF0000) ; Red = 0xFF0000
EndFunc


Func unhoveringButton()
ConsoleWrite(" => unhoveringButton"&@CRLF)
GUICtrlSetColor($input, 0x000000) ; Black = 0x000000
EndFunc


Func pushingButton()
ConsoleWrite(" => pushingButton"&@CRLF)
GUICtrlSetState($input,  $GUI_HIDE)
GUICtrlSetState($input2, $GUI_SHOW)
EndFunc


Func releasingButton()
ConsoleWrite(" => releasingButton"&@CRLF)
GUICtrlSetState($input2, $GUI_HIDE)
GUICtrlSetState($input,  $GUI_SHOW)
EndFunc

The parts in red are the modification to make. (I don't know if it's really clear ^^) With the code tag, I can't colorize the code, so the parts to modify are the "Global Const" definitions and the "notify" function.

 

Many thanks for considering my request !

ZDS

PS: I have found many UDFs like TommyDDR's/MrCreatoR's one, but nothing like I'm looking for (I'm not sure it's possible, but there are things like the example in AutoIt's help specific to a button : _GUICtrlButton_GetSplitInfo )

Edited March 1, 2014 by ZDS

[JohnOne]

Can you put code in code tags?

[PhoenixXL]

There is an >UDF from MrCreatoR, for events of hover and unhover

[ZDS]

Hi everyone,

@JohnOne : Done, but I wanted to colorize some parts of the code, and it's not possible between

tags.

@PhoenixXL : this is not what I'm looking for, TommyDDR's UDF is in fact MrCreatoR's UDF.

[JohnOne]

Hi, generally you can draw attention to parts of code by commenting, thanks.

Not sure what's in the UDF you speak of, but you sometimes can detect a hover by getting cursor info in main loop.

[PhoenixXL]

SHORT AND SIMPLE

I would go this way

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


; Variables
Global $dimension[2] = [200, 80]
; Graphic components
Global $GUI = GUICreate("Essai de champ password", $dimension[0], $dimension[1], Default, Default, 0x80800000) ; $WS_POPUP = 0x80000000 ; $WS_BORDER = 0x00800000
Global $title = GUICtrlCreateLabel("Password", 10, 10, $dimension[0] - 55, 25, Default, 0x00100000) ; $GUI_WS_EX_PARENTDRAG = 0x00100000
Global $quit = GUICtrlCreateButton("X", $dimension[0] - 35, 10, 25, 25)
Global $input = GUICtrlCreateInput("Passw0rd!", 10, 45, $dimension[0] - 55, 25, 0x0020) ; $ES_PASSWORD = 0x0020
Global $input2 = GUICtrlCreateInput("Passw0rd!", 10, 45, $dimension[0] - 55, 25)
Global $button = GUICtrlCreateButton("", $dimension[0] - 35, 45, 25, 25)
; Mise à jour des composants graphiques
GUICtrlSetBkColor($title, -2) ; $GUI_BKCOLOR_TRANSPARENT = -2
GUICtrlSetFont($title, 15, 800)
GUICtrlSetState($input2, $GUI_HIDE)


GUISetState(@SW_SHOW, $GUI)

Local $stop = False, $previous = "", $aMouse, $hover = False
Do
    ; Classic msg loop
    Local $msg = GUIGetMsg()
    If @error = 0 Then
        Switch $msg
            Case -3 ; $GUI_EVENT_CLOSE = -3
                $stop = True
            Case $quit
                $stop = True

            Case $GUI_EVENT_MOUSEMOVE

                $aMouse = GUIGetCursorInfo($GUI)
                If @error Then ContinueLoop
                If $aMouse[4] = $button Then
                    If Not $hover Then hoveringButton()
                    $hover = True
                Else
                    If $hover Then
                        $hover = False
                        unhoveringButton()
                    EndIf
                EndIf

            Case $button
                releasingButton()

            Case $GUI_EVENT_PRIMARYDOWN
                If $aMouse[4] = $button Then pushingButton()


        EndSwitch
    EndIf
    ; Input has changed
    If $previous <> GUICtrlRead($input) Then
        $previous = GUICtrlRead($input)
        GUICtrlSetData($input2, $previous)
    EndIf
Until $stop
GUIDelete($GUI)

Func hoveringButton()
    ConsoleWrite(" => hoveringButton" & @CRLF)
    GUICtrlSetColor($input, 0xFF0000) ; Red = 0xFF0000
EndFunc   ;==>hoveringButton


Func unhoveringButton()
    ConsoleWrite(" => unhoveringButton" & @CRLF)
    GUICtrlSetColor($input, 0x000000) ; Black = 0x000000
EndFunc   ;==>unhoveringButton


Func pushingButton()
    ConsoleWrite(" => pushingButton" & @CRLF)
    GUICtrlSetState($input, $GUI_HIDE)
    GUICtrlSetState($input2, $GUI_SHOW)
EndFunc   ;==>pushingButton


Func releasingButton()
    ConsoleWrite(" => releasingButton" & @CRLF)
    GUICtrlSetState($input2, $GUI_HIDE)
    GUICtrlSetState($input, $GUI_SHOW)
EndFunc   ;==>releasingButton

Thumbs up if helped.

Regards

Phoenix XL

Edited March 2, 2014 by PhoenixXL

[mLipok]

@JohnOne : Done, but I wanted to colorize some parts of the code, and it's not possible between

tags.

 

Because you use Text "code tag", you need to use AutoIt "code tag",  look in my signature link to: "How to post code on the forum".

mLipok

Edited March 2, 2014 by mLipok