Jump to content
water

ObjGet is slow when using index parameter

Recommended Posts

water

Lets say I open 12 Excel workbooks and use _Excel_BookList to get a list of this open workbooks. It can take the function up to 45 seconds to return the result.
Each call to ObjGet takes longer then the previous one while incrementing the index:

Quote

--> Press Ctrl+Alt+Break to Restart or Ctrl+Break to Stop
ObjGet for instance 1: 382.251450162039
ObjGet for instance 2: 777.418685971442
ObjGet for instance 3: 1019.9805791774
ObjGet for instance 4: 1438.43658964894
ObjGet for instance 5: 1813.44021612065
ObjGet for instance 6: 2252.33544777966
ObjGet for instance 7: 2624.21945529542
ObjGet for instance 8: 3459.48036500224
ObjGet for instance 9: 3805.80542656693
ObjGet for instance 10: 4110.24388662199
ObjGet for instance 11: 5074.12806820839
ObjGet for instance 12: 5631.12553735778
Runtime for _Excel_BookList: 37838.0588392901
+>14:41:47 AutoIt3.exe ended.rc:0
+>14:41:47 AutoIt3Wrapper Finished.
>Exit code: 0    Time: 42.32

I searched the forum but only found some threads from 2008 discussing the processing of the ROT (Running Objects Table).
Does someone have an idea how to enhance this function (some miraculous WinAPI calls ...)?

#include <Excel.au3>

Local $oExcel = _Excel_Open()
Global $iTimer = TimerInit()
Global $aWorkbooks = _Excel_BookListEX()
ConsoleWrite("Runtime for _Excel_BookList: " & TimerDiff($iTimer) & @CRLF)

Func _Excel_BookListEX($oExcel = Default)
    ; Error handler, automatic cleanup at end of function
    Global $oError = ObjEvent("AutoIt.Error", "__Excel_COMErrFunc_RT")
    #forceref $oError
    Local $aBooks[1][3], $iIndex = 0
    If IsObj($oExcel) Then
        If ObjName($oExcel, 1) <> "_Application" Then Return SetError(1, 0, 0)
        Local $iTemp = $oExcel.Workbooks.Count
        ReDim $aBooks[$iTemp][3]
        For $iIndex = 0 To $iTemp - 1
            $aBooks[$iIndex][0] = $oExcel.Workbooks($iIndex + 1)
            $aBooks[$iIndex][1] = $oExcel.Workbooks($iIndex + 1).Name
            $aBooks[$iIndex][2] = $oExcel.Workbooks($iIndex + 1).Path
        Next
    Else
        If $oExcel <> Default Then Return SetError(1, 0, 0)
        Local $oWorkbook, $sCLSID_Workbook = "{00020819-0000-0000-C000-000000000046}"
        While True
            $iTimerList = TimerInit()
            $oWorkbook = ObjGet("", $sCLSID_Workbook, $iIndex + 1)
            If @error Then ExitLoop
            ConsoleWrite("ObjGet for instance " & $iIndex + 1 & ": " & TimerDiff($iTimerList) & @CRLF)
            ReDim $aBooks[$iIndex + 1][3]
            $aBooks[$iIndex][0] = $oWorkbook
            $aBooks[$iIndex][1] = $oWorkbook.Name
            $aBooks[$iIndex][2] = $oWorkbook.Path
            $iIndex += 1
            $oWorkbook = 0
        WEnd
    EndIf
    Return $aBooks
EndFunc   ;==>_Excel_BookListEX

 


My UDFs and Tutorials:

Spoiler

UDFs:
Active Directory (2018-06-01 - Version 1.4.9.0) - Download - General Help & Support - Example Scripts - Wiki
OutlookEX (NEW 2018-09-01 - Version 1.3.4.0) - Download - General Help & Support - Example Scripts - Wiki
ExcelChart (2017-07-21 - Version 0.4.0.1) - Download - General Help & Support - Example Scripts
PowerPoint (2017-06-06 - Version 0.0.5.0) - Download - General Help & Support
Excel - Example Scripts - Wiki
Word - Wiki
 
Tutorials:

ADO - Wiki

 

Share this post


Link to post
Share on other sites
Subz

Probably not what you're after but I've always just use ObjGet("...\ExcelPath.xlsx") for example:

#include <Excel.au3>

Local $aWorkBook, $aWorkBooks[] = [ _
@ScriptDir & "\Test1.xlsx", _
@ScriptDir & "\Test2.xlsx", _
@ScriptDir & "\Test3.xlsx", _
@ScriptDir & "\Test4.xlsx", _
@ScriptDir & "\Test5.xlsx", _
@ScriptDir & "\Test6.xlsx", _
@ScriptDir & "\Test7.xlsx", _
@ScriptDir & "\Test8.xlsx", _
@ScriptDir & "\Test9.xlsx", _
@ScriptDir & "\Test10.xlsx", _
@ScriptDir & "\Test11.xlsx", _
@ScriptDir & "\Test12.xlsx", _
@ScriptDir & "\Test13.xlsx", _
@ScriptDir & "\Test14.xlsx"]

For $i = 0 To UBound($aWorkBooks) - 1
    $aWorkBooks[$i] = ObjGet($aWorkBooks[$i])
    $aWorkBook = $aWorkBooks[$i]
    ConsoleWrite("Workbook Name: " & $aWorkBook.Name & @CRLF)
    ConsoleWrite("Workbook Path: " & $aWorkBook.Path & @CRLF)
Next

 

Share this post


Link to post
Share on other sites
water

Thanks for your code snippet.
That could be a solution for the "FilePath" mode.
But for "FileName" and "Title" the current solution is still too slow when there are multiple open workbooks to check.


My UDFs and Tutorials:

Spoiler

UDFs:
Active Directory (2018-06-01 - Version 1.4.9.0) - Download - General Help & Support - Example Scripts - Wiki
OutlookEX (NEW 2018-09-01 - Version 1.3.4.0) - Download - General Help & Support - Example Scripts - Wiki
ExcelChart (2017-07-21 - Version 0.4.0.1) - Download - General Help & Support - Example Scripts
PowerPoint (2017-06-06 - Version 0.0.5.0) - Download - General Help & Support
Excel - Example Scripts - Wiki
Word - Wiki
 
Tutorials:

ADO - Wiki

 

Share this post


Link to post
Share on other sites
Danyfirex

Hello you could do this: (tested with Excel 2013)

 

#include <Array.au3>
#include <WinAPI.au3>

Local $aBooks[0][3]
Local Const $OBJID_NATIVEOM = 0xFFFFFFF0
Local $hExcelControl = ControlGetHandle("[CLASS:XLMAIN]", "", "EXCEL71")
Local $tGUID = _WinAPI_GUIDFromString('{00020400-0000-0000-C000-000000000046}') ;IID_IDispatch
Local $pGUID = DllStructGetPtr($tGUID)
Local $aCall = DllCall("Oleacc.dll", "long", "AccessibleObjectFromWindow", "hwnd", $hExcelControl, "dword", $OBJID_NATIVEOM, "ptr", $pGUID, "idispatch*", 0)
If $aCall[0] = $S_OK Then
    Local $oExcel = $aCall[4].Application
    ReDim $aBooks[$oExcel.Workbooks.Count][3]
    Local $iIndex = 0
    For $oWorkbook In $oExcel.Workbooks
        $aBooks[$iIndex][0] = $oWorkbook
        $aBooks[$iIndex][1] = $oWorkbook.Name
        $aBooks[$iIndex][2] = $oWorkbook.Path
        $iIndex += 1
    Next
    _ArrayDisplay($aBooks)
EndIf

Tested with 100 workbooks. It takes about 500 milliseconds for listing in my machine.

 

Saludos

  • Like 3

Share this post


Link to post
Share on other sites
water

That's perfect!

Additional question: How would you handle multiple instances of the Excel application? With the code you posted you just get the last active application.
Thanks for taking the time to speed up this Excel UDF functions :)


My UDFs and Tutorials:

Spoiler

UDFs:
Active Directory (2018-06-01 - Version 1.4.9.0) - Download - General Help & Support - Example Scripts - Wiki
OutlookEX (NEW 2018-09-01 - Version 1.3.4.0) - Download - General Help & Support - Example Scripts - Wiki
ExcelChart (2017-07-21 - Version 0.4.0.1) - Download - General Help & Support - Example Scripts
PowerPoint (2017-06-06 - Version 0.0.5.0) - Download - General Help & Support
Excel - Example Scripts - Wiki
Word - Wiki
 
Tutorials:

ADO - Wiki

 

Share this post


Link to post
Share on other sites
Danyfirex
Posted (edited)

You're right, here is a mod.

#include <Excel.au3>
#include <Array.au3>
#include <WinAPI.au3>


Local $oExcel1 = _Excel_Open()
Local $oExcel2 = _Excel_Open(True, False, True, True, True)
Local $oExcel3 = _Excel_Open(True, False, True, True, True)

For $i = 1 To 5
    _Excel_BookNew($oExcel1, 1)
    _Excel_BookNew($oExcel2, 1)
    _Excel_BookNew($oExcel3, 1)
Next

Local $hTimer = TimerInit()
Local $aWorkBooks = _Excel_BookList()
_ArrayDisplay($aWorkBooks, " _Excel_BookList Time: " & TimerDiff($hTimer))

$hTimer = TimerInit()
Local $aWorkBooks = _Excel_BookListEx()
_ArrayDisplay($aWorkBooks, " _Excel_BookListEx Time: " & TimerDiff($hTimer))


_Excel_Close($oExcel1)
_Excel_Close($oExcel2)
_Excel_Close($oExcel3)

Func _Excel_BookListEx($oExcel = Default)
    Local Const $OBJID_NATIVEOM = 0xFFFFFFF0
    Local $aBooks[0][3], $iIndex = 0
    If IsObj($oExcel) Then
        If ObjName($oExcel, 1) <> "_Application" Then Return SetError(1, 0, 0)
        Local $iTemp = $oExcel.Workbooks.Count
        ReDim $aBooks[$iTemp][3]
        For $iIndex = 0 To $iTemp - 1
            $aBooks[$iIndex][0] = $oExcel.Workbooks($iIndex + 1)
            $aBooks[$iIndex][1] = $oExcel.Workbooks($iIndex + 1).Name
            $aBooks[$iIndex][2] = $oExcel.Workbooks($iIndex + 1).Path
        Next
    Else
        If $oExcel <> Default Then Return SetError(1, 0, 0)
        Local $aExcelInstances = __GetExcelInstances()
        Local $tGUID = _WinAPI_GUIDFromString('{00020400-0000-0000-C000-000000000046}') ;IID_IDispatch
        Local $pGUID = DllStructGetPtr($tGUID)
        Local $hExcelControl = 0
        Local $aCall = 0
        For $i = 0 To UBound($aExcelInstances) - 1
            $hExcelControl = ControlGetHandle($aExcelInstances[$i], "", "EXCEL71")
            $aCall = DllCall("Oleacc.dll", "long", "AccessibleObjectFromWindow", "hwnd", $hExcelControl, "dword", $OBJID_NATIVEOM, "ptr", $pGUID, "idispatch*", 0)
            If $aCall[0] = $S_OK Then
                $oExcel = $aCall[4].Application
                ReDim $aBooks[UBound($aBooks) + $oExcel.Workbooks.Count][3]
                For $oWorkbook In $oExcel.Workbooks
                    $aBooks[$iIndex][0] = $oWorkbook
                    $aBooks[$iIndex][1] = $oWorkbook.Name
                    $aBooks[$iIndex][2] = $oWorkbook.Path
                    $iIndex += 1
                Next
            EndIf
        Next
    EndIf
    Return ($iIndex > 0 ? SetError(0, $iIndex, $aBooks) : SetError(1, 0, $aBooks))
EndFunc   ;==>_Excel_BookListEx

Func __GetExcelInstances()
    Local $aIntances[0]
    Local $aWindowIntances[0]
    Local $aWindows = WinList("[CLASS:XLMAIN]")
    If IsArray($aWindows) Then
        Local $iFind = 0
        Local $iPID = 0
        For $i = 1 To $aWindows[0][0]
            $iPID = WinGetProcess($aWindows[$i][1])
            $iFind = _ArraySearch($aIntances, $iPID)
            If $iFind = -1 Then
                _ArrayAdd($aIntances, $iPID)
                _ArrayAdd($aWindowIntances, $aWindows[$i][1])
            EndIf
        Next
    EndIf
    Return $aWindowIntances
EndFunc   ;==>__GetExcelInstances

Saludos

Edited by Danyfirex
  • Like 1

Share this post


Link to post
Share on other sites
water

Thanks for the extended version :)
Will test as soon as I can reach a Windows PC :)


My UDFs and Tutorials:

Spoiler

UDFs:
Active Directory (2018-06-01 - Version 1.4.9.0) - Download - General Help & Support - Example Scripts - Wiki
OutlookEX (NEW 2018-09-01 - Version 1.3.4.0) - Download - General Help & Support - Example Scripts - Wiki
ExcelChart (2017-07-21 - Version 0.4.0.1) - Download - General Help & Support - Example Scripts
PowerPoint (2017-06-06 - Version 0.0.5.0) - Download - General Help & Support
Excel - Example Scripts - Wiki
Word - Wiki
 
Tutorials:

ADO - Wiki

 

Share this post


Link to post
Share on other sites
water

BTW: Does anyone know why looping through the ROT by ObjGet is so slow?
Could this be a bug?


My UDFs and Tutorials:

Spoiler

UDFs:
Active Directory (2018-06-01 - Version 1.4.9.0) - Download - General Help & Support - Example Scripts - Wiki
OutlookEX (NEW 2018-09-01 - Version 1.3.4.0) - Download - General Help & Support - Example Scripts - Wiki
ExcelChart (2017-07-21 - Version 0.4.0.1) - Download - General Help & Support - Example Scripts
PowerPoint (2017-06-06 - Version 0.0.5.0) - Download - General Help & Support
Excel - Example Scripts - Wiki
Word - Wiki
 
Tutorials:

ADO - Wiki

 

Share this post


Link to post
Share on other sites
Danyfirex
Posted (edited)

I'm no sure how is designed ObjGet internally but probably a minor bug because I did a test using ROT which is fast enough.

Test Script:

#include <Excel.au3>
#include <Array.au3>
#include <WinAPI.au3>



Global Const $sIID_IEnumMoniker = '{00000102-0000-0000-c000-000000000046}'
Global Const $sTagIEnumMoniker = "Next hresult(dword;ptr*;dword*);" & _
        "Skip hresult(dword);" & _
        "Reset hresult();" & _
        "Clone hresult(ptr*);"

Global Const $sIID_IMoniker = '{0000000f-0000-0000-C000-000000000046}'
Global Const $sTagIMoniker = "GetClassID hresult( clsid )" & _
        "IsDirty hresult(  );" & _
        "Load hresult( ptr );" & _
        "Save hresult( ptr, bool );" & _
        "GetSizeMax hresult( uint64 );" & _
        "BindToObject hresult( ptr;ptr;clsid;idispatch*);" & _
        "BindToStorage hresult( ptr;ptr;clsid;ptr*);" & _
        "Reduce hresult( ptr;dword;ptr*;ptr*);" & _
        "ComposeWith hresult( ptr;bool;ptr*);" & _
        "Enum hresult( bool;ptr*);" & _
        "IsEqual hresult( ptr);" & _
        "Hash hresult( dword*);" & _
        "IsRunning hresult( ptr;ptr;ptr);" & _
        "GetTimeOfLastChange hresult( ptr;ptr;int64*);" & _
        "Inverse hresult( ptr*);" & _
        "CommonPrefixWith hresult( ptr;ptr*);" & _
        "RelativePathTo hresult( ptr;ptr*);" & _
        "GetDisplayName hresult( ptr;ptr;wstr*);" & _
        "ParseDisplayName hresult( ptr;ptr;wstr;ulong*;ptr*);" & _
        "IsSystemMoniker hresult( dword*);"


Global Const $IID_IRunningObjectTable = "{00000010-0000-0000-C000-000000000046}"
Global Const $sTagIRunningObjectTable = "Register HRESULT(DWORD;PTR;PTR;DWORD*);" & _
        "Revoke HRESULT(DWORD);" & _
        "IsRunning HRESULT(PTR*);" & _
        "GetObject HRESULT(PTR;PTR*);" & _
        "NoteChangeTime HRESULT(DWORD;PTR*);" & _
        "GetTimeOfLastChange HRESULT(PTR*;PTR*);" & _
        "EnumRunning HRESULT(PTR*);"

Global Const $IID_IDispatch = "{00020400-0000-0000-C000-000000000046}"


Local $oExcel1 = _Excel_Open()
Local $oExcel2 = _Excel_Open(True, False, True, True, True)
Local $oExcel3 = _Excel_Open(True, False, True, True, True)

For $i = 1 To 5
    _Excel_BookNew($oExcel1, 1)
    _Excel_BookNew($oExcel2, 1)
    _Excel_BookNew($oExcel3, 1)
Next


Local $hTimer = TimerInit()
Local $aWorkBooks = _Excel_BookListEx()
_ArrayDisplay($aWorkBooks, " _Excel_BookListEx Time: " & TimerDiff($hTimer))

_Excel_Close($oExcel1)
_Excel_Close($oExcel2)
_Excel_Close($oExcel3)


Func _Excel_BookListEx($oExcel = Default)
    Local $aBooks[0][3], $iIndex = 0
    If IsObj($oExcel) Then
        If ObjName($oExcel, 1) <> "_Application" Then Return SetError(1, 0, 0)
        Local $iTemp = $oExcel.Workbooks.Count
        ReDim $aBooks[$iTemp][3]
        For $iIndex = 0 To $iTemp - 1
            $aBooks[$iIndex][0] = $oExcel.Workbooks($iIndex + 1)
            $aBooks[$iIndex][1] = $oExcel.Workbooks($iIndex + 1).Name
            $aBooks[$iIndex][2] = $oExcel.Workbooks($iIndex + 1).Path
        Next
    Else
        If $oExcel <> Default Then Return SetError(1, 0, 0)
        Local $aCall = DllCall("Ole32.dll", "LONG", "GetRunningObjectTable", "DWORD", 0, "PTR*", 0)
        Local $pIRunningObjectTable = $aCall[2]
        Local $oRunningObjectTable = ObjCreateInterface($pIRunningObjectTable, $IID_IRunningObjectTable, $sTagIRunningObjectTable)
        Local $pIEnumMoniker = 0
        $oRunningObjectTable.EnumRunning($pIEnumMoniker)
        Local $oEnumMoniker = ObjCreateInterface($pIEnumMoniker, $sIID_IEnumMoniker, $sTagIEnumMoniker)
        Local $pMoniker = 0
        Local $iFetched = 0
        Local $oMoniker = 0
        Local $pCTX = 0
        Local $oWorkBook = 0
        $aCall = DllCall("Ole32.dll", "long", "CreateBindCtx", "dword", 0, "ptr*", 0)
        $pCTX = $aCall[2]
        While $oEnumMoniker.Next(1, $pMoniker, $iFetched) = 0
            $oMoniker = ObjCreateInterface($pMoniker, $sIID_IMoniker, $sTagIMoniker)
            $oMoniker.BindToObject($pCTX, 0, $IID_IDispatch, $oWorkBook)
            If IsObj($oWorkBook) Then
                ReDim $aBooks[UBound($aBooks)+1][3]
                $aBooks[$iIndex][0] = $oWorkBook
                $aBooks[$iIndex][1] = $oWorkBook.Name
                $aBooks[$iIndex][2] = $oWorkBook.Path
                $iIndex+=1
            EndIf
        WEnd
    EndIf
    Return ($iIndex > 0 ? SetError(0, $iIndex, $aBooks) : SetError(1, 0, $aBooks))
EndFunc   ;==>_Excel_BookListEx

Saludos

Edited by Danyfirex
  • Like 2

Share this post


Link to post
Share on other sites
water

Fantastic!
Takes 63ms to process :)


My UDFs and Tutorials:

Spoiler

UDFs:
Active Directory (2018-06-01 - Version 1.4.9.0) - Download - General Help & Support - Example Scripts - Wiki
OutlookEX (NEW 2018-09-01 - Version 1.3.4.0) - Download - General Help & Support - Example Scripts - Wiki
ExcelChart (2017-07-21 - Version 0.4.0.1) - Download - General Help & Support - Example Scripts
PowerPoint (2017-06-06 - Version 0.0.5.0) - Download - General Help & Support
Excel - Example Scripts - Wiki
Word - Wiki
 
Tutorials:

ADO - Wiki

 

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now

  • Similar Content

    • WoodGrain
      By WoodGrain
      Hi All,
      I've coded the small script below, but it can't seem to get the instance of Windows Media player as it keeps going to @error, I've not used com objects before so any assistance would be appreciate. I already have WMP open and minimised. I retrieved "WMPlayerApp" from the AutoIT info tool, I've included a copy below.
      I'm using these sources:
      https://msdn.microsoft.com/en-us/library/dd564085.aspx
      https://msdn.microsoft.com/en-us/library/dd564018.aspx
      $oWMP = ObjGet("", "WMPlayerApp") If @error Then MsgBox(0, "Can't get WMP", "Couldn't connect to the WMP instance") Exit EndIf $wmpPlayState = $oWMP.playState MsgBox(0, "Play State", $wmpPlayState) $wmpSongName = $oWMP.currentMedia.name MsgBox(0, "Play State", $wmpSongName) I've also seen references to the below, but I want to get an existing open WMP:
      ObjCreate("wmplayer.OCX") and have looked at the WMP.udf but can't see how it will do either of the functions I've coded above.
       
    • kingjacob90
      By kingjacob90
      HI
      I am wanting to know what my CPU temp is but don't know what object to use. I don't relay know how objget works so would not know where to start. I have seen people integrate things like windows speech to text into their scripts but don't know how they know what object to use! How do I find the right object? And how dose it work?
       
      Thanks Jacob
    • jaja714
      By jaja714
      For years, I have been running a script using ObjGet to open an Excel workbook but, after upgrading from Win7 to Win10, ObjGet is now returning with an error.  The only way I can get it to work on Win10 is to actually open the workbook manually myself and then run the script.
    • souldjer777
      By souldjer777
      Good Morning Everyone and Happy Friday!
      First - of course: Thanks to everyone in AutoIT - You help systems administrators and programmers everywhere get help to folks that need it with fluid automation I can personally say that you've helped literally thousands of people I've distribute exe's too. Amazing work, you've saved so many of us all time, redundancy and pain. You've quite honestly given many folks their time back... 

      On with the questions then...
      Having real trouble getting this OutlookEX UDF to work... getting "Error creating a connection to Outlook. @error = 1, @extended = -2147221164"
      I see from previous issues that means
      "The error code stands for '80040154 Class not registered'.
      Means: The class is unknown to the user running the script. I assume you use the system account to run the script in the task scheduler?"
      I'm running the script from SciTE
      #AutoIt3Wrapper_AU3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 #AutoIt3Wrapper_AU3Check_Stop_OnWarning=Y #RequireAdmin #include <OutlookEX.au3> Global $oOutlook = _OL_Open() If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF", "Error creating a connection to Outlook. @error = " & @error & ", @extended = " & @extended) ; ***************************************************************************** ; Example 1 ; Send a html mail to the current user. ; Add an attachment and set importance to high. ; ***************************************************************************** Global $sCurrentUser = $oOutlook.GetNameSpace("MAPI").CurrentUser.Name _OL_Wrapper_SendMail($oOutlook, $sCurrentUser, "", "", "TestSubject", "Body<br><b>fett</b> normal.", @ScriptDir & "\_OL_Wrapper_SendMail.au3", $olFormatHTML, $olImportanceHigh) If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF: _OutlookSendMail Wrapper Script", "Error sending mail. @error = " & @error & ", @extended: " & @extended) MsgBox(64, "OutlookEX UDF: _OutlookSendMail Wrapper Script", "Mail successfully sent to user '" & $sCurrentUser & "'!") _OL_Close($oOutlook) Using Windows 7 x64 and Outlook 2013.
      Thanks Everyone!
      Also... getting error...
      Global $sCurrentUser = $oOutlook.GetNameSpace("MAPI").CurrentUser.Name
      Global $sCurrentUser = $oOutlook^ ERROR
      ...using the following sample code taken from this forum.
      #AutoIt3Wrapper_AU3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 #AutoIt3Wrapper_AU3Check_Stop_OnWarning=N #include <File.au3> #include <GUIConstants.au3> #include <GuiButton.au3> #include <GUIConstantsEx.au3> #include <GUIToolTip.au3> #include <Array.au3> #include <Constants.au3> #include <Date.au3> #include <WinAPIFiles.au3> #include <ScreenCapture.au3> #include <OutlookEX.au3> #include <WinAPIFiles.au3> Global $iFileName, $Form1_1 Global $oOutlook = _OL_Open() GLobal $sTo = "emailaddress@gmail.com;" $Form1_1 = GUICreate("System Information", 1083, 638, 182, 114) GUISetState(@SW_SHOW) If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF", "Error creating a connection to Outlook. @error = " & @error & ", @extended = " & @extended) $iFileName = @DesktopDir & "\Utility Screenshot - " & @MON & "." & @MDAY & "." & @YEAR & " - (" & @HOUR & "." & @MIN & "." & @SEC & ").jpg" _ScreenCapture_CaptureWnd($iFileName, $Form1_1) Global $sCurrentUser = $oOutlook.GetNameSpace("MAPI").CurrentUser.Name _OL_Wrapper_SendMail($oOutlook, $sTo, "", "", "Configuration Utility Screenshot", "Attached please find the Configuration Utilty Screenshot.<br>Automatically sent via the Configuration Utlity<br>Thank you, <br>" & $sCurrentUser, $iFileName, $olFormatHTML, $olImportanceHigh) If @error <> 0 Then Exit MsgBox(16, "OutlookEX UDF: _OutlookSendMail Wrapper Script", "Error sending mail. @error = " & @error & ", @extended: " & @extended) MsgBox(64, "OutlookEX UDF: _OutlookSendMail Wrapper Script", "Mail successfully sent to user '" & $sCurrentUser & "'!") _OL_Close($oOutlook) *** I have a separate login for MS Outlook 2013 because I have multiple ID's *** Do I have to run it as the current mailbox user???
      Thanks again!
    • Shane0000
      By Shane0000
      The below code  will cause AutoIt to hard crash  after 18+/- seconds with the error: -1073741819
      Sometimes the method succeeds 2+/- seconds, most the time not.
      I just updated to AutoCAD2016 and I am getting a high failure rate with my scripts.
      Class ID of the target application is AfxMDIFrame110u
      I updated SciTE to see if that would help but it did not.
       
      ConsoleWrite("AutoIt Ver: " & @AutoItVersion & @CRLF) ConsoleWrite(@OSVersion& " " & @OSArch & @CRLF) ConsoleWrite("Build: " & @OSBuild & @CRLF) ConsoleWrite(@OSServicePack & @CRLF) ConsoleWrite(@OSType & @CRLF) $oMyError = ObjEvent("AutoIt.Error","MyErrFunc") $oAcad = ObjGet("","AutoCAD.application") If @error Then MsgBox( 0 , "" , "Failed") Exit Else ConsoleWrite("-Line: " & @ScriptLineNumber & @CRLF & "$oAcad: " & IsObj($oAcad) & @CRLF) EndIf Func MyErrFunc() ; Msgbox(0,"AutoItCOM Test","We intercepted a COM Error !" & @CRLF & @CRLF & _ ; "err.description is: " & @TAB & $oMyError.description & @CRLF & _ ; "err.windescription:" & @TAB & $oMyError.windescription & @CRLF & _ ; "err.number is: " & @TAB & hex($oMyError.number,8) & @CRLF & _ ; "err.lastdllerror is: " & @TAB & $oMyError.lastdllerror & @CRLF & _ ; "err.scriptline is: " & @TAB & $oMyError.scriptline & @CRLF & _ ; "err.source is: " & @TAB & $oMyError.source & @CRLF & _ ; "err.helpfile is: " & @TAB & $oMyError.helpfile & @CRLF & _ ; "err.helpcontext is: " & @TAB & $oMyError.helpcontext _ ; ) ConsoleWrite(@CRLF & @CRLF & "We intercepted a COM Error !" & @CRLF & @CRLF & _ "err.description is: " & @TAB & $oMyError.description & @CRLF & _ "err.windescription:" & @TAB & $oMyError.windescription & @CRLF & _ "err.number is: " & @TAB & hex($oMyError.number,8) & @CRLF & _ "err.lastdllerror is: " & @TAB & $oMyError.lastdllerror & @CRLF & _ "err.scriptline is: " & @TAB & $oMyError.scriptline & @CRLF & _ "err.source is: " & @TAB & $oMyError.source & @CRLF & _ "err.helpfile is: " & @TAB & $oMyError.helpfile & @CRLF & _ "err.helpcontext is: " & @TAB & $oMyError.helpcontext & @CRLF & @CRLF _ ) Local $err = $oMyError.number If $err = 0 Then $err = -1 $g_eventerror = $err ; to check for after this function returns Endfunc AutoIt Ver: 3.3.12.0 WIN_7 X64 Build: 7601 Service Pack 1 WIN32_NT !>23:21:10 AutoIt3.exe ended.rc:-1073741819 +>23:21:10 AutoIt3Wrapper Finished. >Exit code: 3221225477 Time: 18.86 AutoIt Ver: 3.3.12.0 WIN_7 X64 Build: 7601 Service Pack 1 WIN32_NT -Line: 14 $oAcad: 1 +>23:23:50 AutoIt3.exe ended.rc:0 +>23:23:50 AutoIt3Wrapper Finished. >Exit code: 0 Time: 1.995  
×