Colors and fonts in custom drawn ListViews - UDF version

[mLipok]

50 minutes ago, Nine said:

No.  It is not a solid example.  Maybe later.

I was planning to work on it a bit and propose something more tailored to HelpFile's needs, but I wanted to use your code as a base, and that's what I was asking about.

I apologize for not being as specific as possible earlier.

[Nine]

11 hours ago, mLipok said:

but I wanted to use your code as a base, and that's what I was asking about

Alright then. No problem.

[Nine]

15 hours ago, mLipok said:

My intention was to also set back ground color of each group

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
  Local $tItem = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)

  If _WinAPI_GetClassName($tItem.hWndFrom) = "SysListView32" And $tItem.Code = $NM_CUSTOMDRAW And $tItem.dwItemType = $LVCDI_GROUP And $tItem.dwDrawStage = $CDDS_PREPAINT Then
    Local $tRect = DllStructCreate($tagRECT, DllStructGetPtr($tItem, "left"))
    Local $aGroup = _GUICtrlListView_GetGroupInfoByIndex($tItem.hWndFrom, $tItem.dwItemSpec - 1)
    _WinAPI_SetBkColor($tItem.HDC, 0x0)
    _WinAPI_SetBkMode($tItem.HDC, 2)
    _WinAPI_SetTextColor($tItem.HDC, 0xFFFF)
    _WinAPI_DrawText($tItem.HDC, "   ─────  " & $aGroup[0] & "  ───────────────────", $tRect, $DT_LEFT)
    Return $CDRF_SKIPDEFAULT
  EndIf
EndFunc   ;==>WM_NOTIFY

Is that it ?

Edited Saturday at 12:49 PM by Nine

[Nine]

15 hours ago, mLipok said:

#HOW TO USE:  => _WinAPI_FillRect($tItem.HDC

Because $tRect covers all the region of title and included items under, you need to adapt the bottom to fill only title :

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
  Local $tItem = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
  If _WinAPI_GetClassName($tItem.hWndFrom) = "SysListView32" And $tItem.Code = $NM_CUSTOMDRAW And $tItem.dwItemType = $LVCDI_GROUP And $tItem.dwDrawStage = $CDDS_PREPAINT Then
    Local $tRect = DllStructCreate($tagRECT, DllStructGetPtr($tItem, "left"))
    $tRect.bottom = $tRect.top + 18
    Local $hBrush = _WinAPI_CreateSolidBrush(0)
    _WinAPI_FillRect($tItem.HDC, $tRect, $hBrush)
    _WinAPI_DeleteObject($hBrush)
    Return $CDRF_SKIPDEFAULT
  EndIf
EndFunc   ;==>WM_NOTIFY

 

Edited Saturday at 01:07 PM by Nine

[Nine]

Putting everything together, here a good example to use in help file :

expandcollapse popup

; From Nine
#include <GUIConstants.au3>
#include <GuiListView.au3>

Example()

Func Example()
  GUICreate("Example")
  Local $idListview = GUICtrlCreateListView("", 10, 10, 350, 200)
  GUISetState()

  GUIRegisterMsg($WM_NOTIFY, WM_NOTIFY)

  _GUICtrlListView_AddColumn($idListview, "Column 0", 100)
  _GUICtrlListView_AddColumn($idListview, "Column 1", 100)

  _GUICtrlListView_AddItem($idListview, "Row 0: Col 0", 0)
  _GUICtrlListView_AddSubItem($idListview, 0, "Row 0: Col 1", 1)
  _GUICtrlListView_AddItem($idListview, "Row 1: Col 0", 1)
  _GUICtrlListView_AddSubItem($idListview, 1, "Row 1: Col 1", 1)
  _GUICtrlListView_AddItem($idListview, "Row 2: Col 0", 2)

  _GUICtrlListView_EnableGroupView($idListview)
  _GUICtrlListView_InsertGroup($idListview, -1, 1, "Test 1")
  _GUICtrlListView_InsertGroup($idListview, -1, 2, "Test 2")
  _GUICtrlListView_SetItemGroupID($idListview, 0, 1)
  _GUICtrlListView_SetItemGroupID($idListview, 1, 1)
  _GUICtrlListView_SetItemGroupID($idListview, 2, 2)

  Do
  Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>Example

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
  Local $tItem = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
  If _WinAPI_GetClassName($tItem.hWndFrom) = "SysListView32" And $tItem.Code = $NM_CUSTOMDRAW And $tItem.dwItemType = $LVCDI_GROUP And $tItem.dwDrawStage = $CDDS_PREPAINT Then
    Local $tRect = DllStructCreate($tagRECT, DllStructGetPtr($tItem, "left"))
    $tRect.bottom = $tRect.top + 18
    Local $hBrush = _WinAPI_CreateSolidBrush(0)
    _WinAPI_FillRect($tItem.HDC, $tRect, $hBrush)
    _WinAPI_DeleteObject($hBrush)
    Local $hPen = _WinAPI_CreatePen($PS_SOLID, 1, 0xFFFF)
    Local $oOrig = _WinAPI_SelectObject($tItem.HDC, $hPen)
    _WinAPI_DrawLine($tItem.HDC, $tRect.left + 5, $tRect.top + 8 , $tRect.right - 5, $tRect.top + 8)
    _WinAPI_SelectObject($tItem.HDC, $oOrig)
    _WinAPI_DeleteObject($hPen)
    Local $aGroup = _GUICtrlListView_GetGroupInfoByIndex($tItem.hWndFrom, $tItem.dwItemSpec - 1)
    _WinAPI_SetBkColor($tItem.HDC, 0)
    _WinAPI_SetBkMode($tItem.HDC, $OPAQUE)
    _WinAPI_SetTextColor($tItem.HDC, 0xFFFF)
    $tRect.left += 20
    _WinAPI_DrawText($tItem.HDC, "  " & $aGroup[0] & "  ", $tRect, $DT_LEFT)
    Return $CDRF_SKIPDEFAULT
  EndIf
EndFunc   ;==>WM_NOTIFY

 

[mLipok]

@Nine your code works well.

I stick with:

If _WinAPI_GetClassName($tItem.hWndFrom) = "SysListView32" And $tItem.Code = $NM_CUSTOMDRAW And $tItem.dwItemType = $LVCDI_GROUP And $tItem.dwDrawStage = $CDDS_PREPAINT Then
        $tRect = DllStructCreate($tagRECT, DllStructGetPtr($tItem, "left"))
        Local $aGroup2 = _GUICtrlListView_GetGroupInfoByIndex($tItem.hWndFrom, $tItem.dwItemSpec - 1)
        _WinAPI_SetBkColor($tItem.HDC, 0x0AAAA0)
        _WinAPI_SetBkMode($tItem.HDC, $OPAQUE)
;~      _WinAPI_SetTextColor($tItem.HDC, 0xB40000)
        _WinAPI_SetTextColor($tItem.HDC, 0x0)
        _WinAPI_DrawText($tItem.HDC, "  " & $aGroup2[0] & "  ──────────────────────────────────────────────────────────────────────────────────────────────────────────────────", $tRect, $DT_LEFT)
        Return $CDRF_SKIPDEFAULT
    EndIf

but the color on listview differs from MsPaint colors.
Why is there a difference?

 

[argumentum]

#include <WinAPIGdi.au3> ; _WinAPI_SwitchColor ( $iColor ) ; Converts a color from BGR to RGB and vice versa

[mLipok]

After some additionall work at:

 

Here is my finall EXAMPLE proposal:

expandcollapse popup

#include <GUIConstants.au3>
#include <GuiListView.au3>

Global $_hGUI = 0, $_hListView = 00
Example()

Func Example()
    $_hGUI = GUICreate("Example")
    Local $idListview = GUICtrlCreateListView("", 10, 10, 350, 200)
    $_hListView = ControlGetHandle($_hGUI, '', $idListview)

    GUISetState()
    GUIRegisterMsg($WM_NOTIFY, WM_NOTIFY)

    _GUICtrlListView_AddColumn($idListview, "Column 0", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)

    _GUICtrlListView_AddItem($idListview, "Row 0: Col 0", 0)
    _GUICtrlListView_AddSubItem($idListview, 0, "Row 0: Col 1", 1)
    _GUICtrlListView_AddItem($idListview, "Row 1: Col 0", 1)
    _GUICtrlListView_AddSubItem($idListview, 1, "Row 1: Col 1", 1)
    _GUICtrlListView_AddItem($idListview, "Row 2: Col 0", 2)

    _GUICtrlListView_EnableGroupView($idListview)
    _GUICtrlListView_InsertGroup($idListview, -1, 1, "Test 1")
    _GUICtrlListView_InsertGroup($idListview, -1, 2, "Test 2")
    _GUICtrlListView_SetItemGroupID($idListview, 0, 1)
    _GUICtrlListView_SetItemGroupID($idListview, 1, 1)
    _GUICtrlListView_SetItemGroupID($idListview, 2, 2)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>Example

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $iMsg, $wParam

    If $hWnd = $_hGUI Then ; check if Our GUI - in case you create multiple GUI - Window
        Local $tItem = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
        If $tItem.hWndFrom = $_hListView Then ; check if our ListView - in case you have few ListView on the same GUI - Window
            Local $iItemSpec = $tItem.dwItemSpec ; ItemIndex for "RowElement", GroupID for "GroupElement"
            If $iItemSpec >= 0 And $tItem.Code = $NM_CUSTOMDRAW And $tItem.dwItemType = $LVCDI_GROUP And $tItem.dwDrawStage = $CDDS_PREPAINT Then
                Local $tRect = DllStructCreate($tagRECT, DllStructGetPtr($tItem, "left"))
                $tRect.bottom = $tRect.top + 18
                Local $hBrush = _WinAPI_CreateSolidBrush(0)
                _WinAPI_FillRect($tItem.HDC, $tRect, $hBrush)
                _WinAPI_DeleteObject($hBrush)
                Local $hPen = _WinAPI_CreatePen($PS_SOLID, 1, _WinAPI_SwitchColor(0xFF0000)) ; RGB to BGR
                Local $oOrig = _WinAPI_SelectObject($tItem.HDC, $hPen)
                _WinAPI_DrawLine($tItem.HDC, $tRect.left + 5, $tRect.top + 8, $tRect.right - 5, $tRect.top + 8)
                _WinAPI_SelectObject($tItem.HDC, $oOrig)
                _WinAPI_DeleteObject($hPen)
                Local $aGroup = _GUICtrlListView_GetGroupInfo($tItem.hWndFrom, $iItemSpec)
                _WinAPI_SetBkColor($tItem.HDC, _WinAPI_SwitchColor(0x55AAFF)) ; RGB to BGR
                _WinAPI_SetBkMode($tItem.HDC, $OPAQUE)
                _WinAPI_SetTextColor($tItem.HDC, _WinAPI_SwitchColor(0x0000FF)) ; RGB to BGR
                $tRect.left += 20
                _WinAPI_DrawText($tItem.HDC, "  " & $aGroup[0] & "  ", $tRect, $DT_LEFT)
                Return $CDRF_SKIPDEFAULT
            EndIf
        EndIf
    EndIf
EndFunc   ;==>WM_NOTIFY

 

Edited 14 hours ago by mLipok

[Nine]

3 hours ago, mLipok said:

Here is my finall EXAMPLE proposal:

Yep, good example.  Thanks.