Cormin

Adjusting the volume of beep() ?

6 posts in this topic

#1 ·  Posted (edited)

I use the beeps for something I use on a daily basis but the volume seems a bit high.  I can't seem to find a way to adjust the volume of only this script.  It does not show in my windows 10 volume mixer. SoundSetWaveVolume() doesn't seem to work.

Edited by Cormin
1 person likes this

Share this post


Link to post
Share on other sites



You can't adjust volume of Beep. Probably you need to write your own beep function. 

 

Saludos

Share this post


Link to post
Share on other sites

I did this just for fun.

 

#include <WinAPI.au3>
#include <WinAPIEx.au3>
#include <WinAPIMisc.au3>

Beep()

_Beep(500,1000,50)
_Beep(500,1000,30)
_Beep(500,1000,10)
_Beep(500,1000,5)
_Beep(500,1000,3)
_Beep(500,1000,1)


;~ Traslated from http://stackoverflow.com/a/19772815
Func _Beep($iFrequency = 500, $imsDuration = 1000, $iVolume = 100);Volume 1 to 100


    Local Const $PI = 3.141592653589
    Local Const $TAU = 2 * $PI
    Local Const $iFormatChunkSize = 16
    Local Const $iHeaderSize = 8
    Local Const $iFormatType = 1
    Local Const $iTracks = 1
    Local Const $iSamplesPerSecond = 44100
    Local Const $iBitsPerSample = 16
    Local Const $iFrameSize = Floor($iTracks * (($iBitsPerSample + 7) / 8))
    Local Const $iBytesPerSecond = $iSamplesPerSecond * $iFrameSize
    Local Const $iWaveSize = 4
    Local Const $iSamples = Floor($iSamplesPerSecond * $imsDuration / 1000)
    Local Const $iDataChunkSize = Int($iSamples * $iFrameSize)
    Local Const $iFileSize = ($iWaveSize + $iHeaderSize + $iFormatChunkSize + $iHeaderSize + $iDataChunkSize)
    Local Const $sTagWAVHeader = "char ChunkID[4];int ChunkSize;char Format[4];char Subchunk1ID[4];" & _
            "int Subchunk1Size;short AudioFormat;short NumChannels;int SampleRate;" & _
            "int ByteRate;short BlockAlign;short BitsPerSample;char Subchunk2ID[4];" & _
            "int Subchunk2Size;"

    Local $sTagWAVHeaderAndData = $sTagWAVHeader & "short AudioWave[" & $iDataChunkSize / 2 & "]"
    Local $tWAVHeader_Data = DllStructCreate($sTagWAVHeaderAndData)

    $tWAVHeader_Data.ChunkID = "RIFF"
    $tWAVHeader_Data.ChunkSize = $iFileSize
    $tWAVHeader_Data.Format = "WAVE"
    $tWAVHeader_Data.Subchunk1ID = "fmt "
    $tWAVHeader_Data.Subchunk1Size = $iFormatChunkSize
    $tWAVHeader_Data.AudioFormat = $iFormatType
    $tWAVHeader_Data.NumChannels = $iTracks
    $tWAVHeader_Data.SampleRate = $iSamplesPerSecond
    $tWAVHeader_Data.ByteRate = $iBytesPerSecond;
    $tWAVHeader_Data.BlockAlign = $iFrameSize
    $tWAVHeader_Data.BitsPerSample = $iBitsPerSample
    $tWAVHeader_Data.Subchunk2ID = "data"
    $tWAVHeader_Data.Subchunk2Size = $iDataChunkSize

    Local $iAmplitude = 16383 / (100 / $iVolume)
    Local $iShort = 0
    $iTheta = $iFrequency * $TAU / $iSamplesPerSecond
    For $iStep = 0 To $iSamples - 1
        $iShort = Int($iAmplitude * Sin($iTheta * ($iStep)))
        DllStructSetData($tWAVHeader_Data, "AudioWave", $iShort, $iStep + 1)
    Next


    _WinAPI_PlaySound(DllStructGetPtr($tWAVHeader_Data), $SND_MEMORY)


EndFunc   ;==>_Beep

Saludos

4 people like this

Share this post


Link to post
Share on other sites
7 minutes ago, Danyfirex said:

I did this just for fun.
Saludos

:) very nice fun.

 

1 person likes this

Signature beginning:   Wondering who uses AutoIT and what it can be used for ?
* GHAPI UDF - modest begining - comunication with GitHub REST API *
ADO.au3 UDF     POP3.au3 UDF     XML.au3 UDF    How to use IE.au3  UDF with  AutoIt v3.3.14.x  for other useful stuff click the following button

Spoiler

Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind. 

My contribution (my own projects): * Debenu Quick PDF Library - UDF * Debenu PDF Viewer SDK - UDF * Acrobat Reader - ActiveX Viewer * UDF for PDFCreator v1.x.x * XZip - UDF * AppCompatFlags UDF * CrowdinAPI UDF * _WinMergeCompare2Files() * _JavaExceptionAdd() * _IsBeta() * Writing DPI Awareness App - workaround * _AutoIt_RequiredVersion() * Chilkatsoft.au3 UDF * TeamViewer.au3 UDF * JavaManagement UDF * VIES over SOAP * WinSCP UDF * GHAPI UDF - modest begining - comunication with GitHub REST API *

My contribution to others projects or UDF based on  others projects: * _sql.au3 UDF  * POP3.au3 UDF *  RTF Printer - UDF * XML.au3 - BETA * ADO.au3 UDF SMTP Mailer UDF *

Useful links: * Forum Rules * Forum etiquette *  Forum Information and FAQs * How to post code on the forum * AutoIt Online Documentation * AutoIt Online Beta Documentation * SciTE4AutoIt3 getting started * Convert text blocks to AutoIt code * Games made in Autoit * Programming related sites * Polish AutoIt Tutorial * DllCall Code Generator * 

Wiki: Expand your knowledge - AutoIt Wiki * Collection of User Defined Functions * How to use HelpFile * Best coding practices * 

IE Related:  * How to use IE.au3  UDF with  AutoIt v3.3.14.x * Why isn't Autoit able to click a Javascript Dialog? * Clicking javascript button with no ID * IE document >> save as MHT file * IETab Switcher (by LarsJ ) * HTML Entities * _IEquerySelectorAll() (by uncommon) * 

I encourage you to read: * Global Vars * Best Coding Practices * Please explain code used in Help file for several File functions * OOP-like approach in AutoIt * UDF-Spec Questions *  EXAMPLE: How To Catch ConsoleWrite() output to a file or to CMD *

"Homo sum; humani nil a me alienum puto" - Publius Terentius Afer
"Program are meant to be read by humans and only incidentally for computers and execute" - Donald Knuth, "The Art of Computer Programming"
:naughty:  :ranting:, be  :) and       \\//_.

Anticipating Errors :  "Any program that accepts data from a user must include code to validate that data before sending it to the data store. You cannot rely on the data store, ...., or even your programming language to notify you of problems. You must check every byte entered by your users, making sure that data is the correct type for its field and that required fields are not empty."

Signature last update: 2017-06-04

Share this post


Link to post
Share on other sites
On 8/24/2016 at 2:16 PM, Danyfirex said:

I did this just for fun.

 

#include <WinAPI.au3>
#include <WinAPIEx.au3>
#include <WinAPIMisc.au3>

Beep()

_Beep(500,1000,50)
_Beep(500,1000,30)
_Beep(500,1000,10)
_Beep(500,1000,5)
_Beep(500,1000,3)
_Beep(500,1000,1)


;~ Traslated from http://stackoverflow.com/a/19772815
Func _Beep($iFrequency = 500, $imsDuration = 1000, $iVolume = 100);Volume 1 to 100


    Local Const $PI = 3.141592653589
    Local Const $TAU = 2 * $PI
    Local Const $iFormatChunkSize = 16
    Local Const $iHeaderSize = 8
    Local Const $iFormatType = 1
    Local Const $iTracks = 1
    Local Const $iSamplesPerSecond = 44100
    Local Const $iBitsPerSample = 16
    Local Const $iFrameSize = Floor($iTracks * (($iBitsPerSample + 7) / 8))
    Local Const $iBytesPerSecond = $iSamplesPerSecond * $iFrameSize
    Local Const $iWaveSize = 4
    Local Const $iSamples = Floor($iSamplesPerSecond * $imsDuration / 1000)
    Local Const $iDataChunkSize = Int($iSamples * $iFrameSize)
    Local Const $iFileSize = ($iWaveSize + $iHeaderSize + $iFormatChunkSize + $iHeaderSize + $iDataChunkSize)
    Local Const $sTagWAVHeader = "char ChunkID[4];int ChunkSize;char Format[4];char Subchunk1ID[4];" & _
            "int Subchunk1Size;short AudioFormat;short NumChannels;int SampleRate;" & _
            "int ByteRate;short BlockAlign;short BitsPerSample;char Subchunk2ID[4];" & _
            "int Subchunk2Size;"

    Local $sTagWAVHeaderAndData = $sTagWAVHeader & "short AudioWave[" & $iDataChunkSize / 2 & "]"
    Local $tWAVHeader_Data = DllStructCreate($sTagWAVHeaderAndData)

    $tWAVHeader_Data.ChunkID = "RIFF"
    $tWAVHeader_Data.ChunkSize = $iFileSize
    $tWAVHeader_Data.Format = "WAVE"
    $tWAVHeader_Data.Subchunk1ID = "fmt "
    $tWAVHeader_Data.Subchunk1Size = $iFormatChunkSize
    $tWAVHeader_Data.AudioFormat = $iFormatType
    $tWAVHeader_Data.NumChannels = $iTracks
    $tWAVHeader_Data.SampleRate = $iSamplesPerSecond
    $tWAVHeader_Data.ByteRate = $iBytesPerSecond;
    $tWAVHeader_Data.BlockAlign = $iFrameSize
    $tWAVHeader_Data.BitsPerSample = $iBitsPerSample
    $tWAVHeader_Data.Subchunk2ID = "data"
    $tWAVHeader_Data.Subchunk2Size = $iDataChunkSize

    Local $iAmplitude = 16383 / (100 / $iVolume)
    Local $iShort = 0
    $iTheta = $iFrequency * $TAU / $iSamplesPerSecond
    For $iStep = 0 To $iSamples - 1
        $iShort = Int($iAmplitude * Sin($iTheta * ($iStep)))
        DllStructSetData($tWAVHeader_Data, "AudioWave", $iShort, $iStep + 1)
    Next


    _WinAPI_PlaySound(DllStructGetPtr($tWAVHeader_Data), $SND_MEMORY)


EndFunc   ;==>_Beep

Saludos

Wow thank you!  This should just be integrated into the real beep()

Share this post


Link to post
Share on other sites

A better way to make this is create a buffer before call it.

Because if you want to play a long beep it will be muted while sine wave buffer is been created.

 

Saludos

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now