_GUICtrlTreeView_ClickItem issues

[FordsFinest]

I have a macro that works well on 95% of computers. However, I am running into an issue on a couple computers where the _GUICtrlTreeView_ClickItem clicks the wrong item (an item or two below the correct one). Both the ExpandItem and SelectItem command work fine, just the click item is off on these computers (and only their user names). I'm not sure if some temp file somewhere is causing an issue or what. Note, using ONLY selectitem results in inconsistent focusing (item appears focused but the next command won't always work correctly). Hence my need to use the clickitem command.

Any help would be appreciated.

_GUICtrlTreeView_Expand($hWnd, $Array2[$i]) ;Expand $model
    Sleep(250)
    _GUICtrlTreeView_SelectItem($hWnd, $Array2[$i]) ;Select $model
    Sleep(150)
    _GUICtrlTreeView_ClickItem($hWnd, $Array2[$i]) ;Click $model
    Sleep(150)
    EndIf

 

Edited March 29, 2019 by FordsFinest

[LarsJ]

FordFinest, We have some issues with a few of the commands in the GuiTreeView UDF under Windows 10 64 bit. I had temporarily forgotten that in your previous post about the same subject a month ago. Sorry.

The problem is obvious if you try the example of _GUICtrlTreeView_ClickItem in the help file under Windows 10 64 bit. The _GUICtrlTreeView_ClickItem command (here a double click) simply does not work.

Make a copy of the example. Add the two functions here to the code and replace _GUICtrlTreeView_ClickItem with _GUICtrlTreeView_ClickItem64.

expandcollapse popup

Func _GUICtrlTreeView_ClickItem64($hWnd, $hItem, $sButton = "left", $bMove = False, $iClicks = 1, $iSpeed = 0)
  If Not IsHWnd($hWnd) Then $hWnd = GUICtrlGetHandle($hWnd)

  Local $tRECT = _GUICtrlTreeView_DisplayRectEx64($hWnd, $hItem, True)
  If @error Then Return SetError(@error, @error, 0)
  ; Always click on the left-most portion of the control, not the center.  A
  ; very wide control may be off-screen which means clicking on it's center
  ; will click outside the window.
  Local $tPoint = _WinAPI_PointFromRect($tRECT, False)
  _WinAPI_ClientToScreen($hWnd, $tPoint)
  Local $iX, $iY
  _WinAPI_GetXYFromPoint($tPoint, $iX, $iY)
  Local $iMode = Opt("MouseCoordMode", 1)
  If Not $bMove Then
    Local $aPos = MouseGetPos()
    _WinAPI_ShowCursor(False)
    MouseClick($sButton, $iX, $iY, $iClicks, $iSpeed)
    MouseMove($aPos[0], $aPos[1], 0)
    _WinAPI_ShowCursor(True)
  Else
    MouseClick($sButton, $iX, $iY, $iClicks, $iSpeed)
  EndIf
  Opt("MouseCoordMode", $iMode)
  Return 1
EndFunc   ;==>_GUICtrlTreeView_ClickItem

Func _GUICtrlTreeView_DisplayRectEx64($hWnd, $hItem, $bTextOnly = False)
  Local $tRECT = DllStructCreate($tagRECT)
  Local $iRet
  If IsHWnd($hWnd) Then
    ; RECT is expected to point to the item in its first member.
    ;DllStructSetData($tRECT, "Left", $hItem)
    $iRet = @AutoItX64 ? DllStructSetData( DllStructCreate( "ptr", DllStructGetPtr( $tRect ) ), 1, $hItem ) _
                       : DllStructSetData( $tRect, "Left", $hItem )
    If _WinAPI_InProcess($hWnd, $__g_hTVLastWnd) Then
      $iRet = _SendMessage($hWnd, $TVM_GETITEMRECT, $bTextOnly, $tRECT, 0, "wparam", "struct*")
    Else
      Local $iRect = DllStructGetSize($tRECT)
      Local $tMemMap
      Local $pMemory = _MemInit($hWnd, $iRect, $tMemMap)
      _MemWrite($tMemMap, $tRECT)
      $iRet = _SendMessage($hWnd, $TVM_GETITEMRECT, $bTextOnly, $pMemory, 0, "wparam", "ptr")
      _MemRead($tMemMap, $pMemory, $tRECT, $iRect)
      _MemFree($tMemMap)
    EndIf
  Else
    If Not IsHWnd($hItem) Then $hItem = _GUICtrlTreeView_GetItemHandle($hWnd, $hItem)
    ; RECT is expected to point to the item in its first member.
    DllStructSetData($tRECT, "Left", $hItem)
    $iRet = GUICtrlSendMsg($hWnd, $TVM_GETITEMRECT, $bTextOnly, DllStructGetPtr($tRECT))
  EndIf

  ; On failure ensure Left is set to 0 and not the item handle.
  If Not $iRet Then DllStructSetData($tRECT, "Left", 0)
  Return SetError($iRet = 0, $iRet, $tRECT)
EndFunc   ;==>_GUICtrlTreeView_DisplayRectEx

You haven't shown much code, but I think the two functions will solve your problem. If the code doesn't help then add a new post. The problem can certainly be solved.

For one reason or another, Microsoft has stopped supporting the focused state of a treeview item. However, the dotted focus rectangle is still displayed. This is not an AutoIt problem.

[FordsFinest]

Well that makes me feel a lot better! I’ll try the new code out first thing Monday! Thanks for the info!

[mLipok]

On 3/30/2019 at 10:06 AM, LarsJ said:

Make a copy of the example. Add the two functions here to the code and replace _GUICtrlTreeView_ClickItem with _GUICtrlTreeView_ClickItem64.

Confirmed as fixed.

Here is my modified version 

expandcollapse popup

Func _GUICtrlTreeView_ClickItem64($hwnd, $hItem, $sButton = "left", $bMove = False, $iClicks = 1, $iSpeed = 0)
;~  https://www.autoitscript.com/forum/topic/198379-_guictrltreeview_clickitem-issues/?do=findComment&comment=1480466
    If @OSArch <> "X64" Then
        Local $iResult_temp =  _GUICtrlTreeView_ClickItem($hwnd, $hItem, $sButton, $bMove, $iClicks, $iSpeed)
        Return SetError(@error, @extended, $iResult_temp)
    EndIf

    If Not IsHWnd($hwnd) Then $hwnd = GUICtrlGetHandle($hwnd)

    Local $tRECT = _GUICtrlTreeView_DisplayRectEx64($hwnd, $hItem, True)
    If @error Then Return SetError(@error, @error, 0)
    ; Always click on the left-most portion of the control, not the center.  A
    ; very wide control may be off-screen which means clicking on it's center
    ; will click outside the window.
    Local $tPoint = _WinAPI_PointFromRect($tRECT, False)
    _WinAPI_ClientToScreen($hwnd, $tPoint)
    Local $iX, $iY
    _WinAPI_GetXYFromPoint($tPoint, $iX, $iY)

    Local $iMode = Opt("MouseCoordMode", 1)
    If Not $bMove Then
        Local $aPos = MouseGetPos()
        _WinAPI_ShowCursor(False)
        MouseClick($sButton, $iX, $iY, $iClicks, $iSpeed)
        MouseMove($aPos[0], $aPos[1], 0)
        _WinAPI_ShowCursor(True)
    Else
        MouseClick($sButton, $iX, $iY, $iClicks, $iSpeed)
    EndIf
    Opt("MouseCoordMode", $iMode)
    Return 1
EndFunc   ;==>_GUICtrlTreeView_ClickItem64

Func _GUICtrlTreeView_DisplayRectEx64($hwnd, $hItem, $bTextOnly = False)
;~  https://www.autoitscript.com/forum/topic/198379-_guictrltreeview_clickitem-issues/?do=findComment&comment=1480466
    Local $tRECT = DllStructCreate($tagRECT)
    Local $iRet
    If IsHWnd($hwnd) Then
        ; RECT is expected to point to the item in its first member.
        ;DllStructSetData($tRECT, "Left", $hItem)
        $iRet = @AutoItX64 ? DllStructSetData(DllStructCreate("ptr", DllStructGetPtr($tRECT)), 1, $hItem) _
                 : DllStructSetData($tRECT, "Left", $hItem)
        If _WinAPI_InProcess($hwnd, $__g_hTVLastWnd) Then
            $iRet = _SendMessage($hwnd, $TVM_GETITEMRECT, $bTextOnly, $tRECT, 0, "wparam", "struct*")
        Else
            Local $iRect = DllStructGetSize($tRECT)
            Local $tMemMap
            Local $pMemory = _MemInit($hwnd, $iRect, $tMemMap)
            _MemWrite($tMemMap, $tRECT)
            $iRet = _SendMessage($hwnd, $TVM_GETITEMRECT, $bTextOnly, $pMemory, 0, "wparam", "ptr")
            _MemRead($tMemMap, $pMemory, $tRECT, $iRect)
            _MemFree($tMemMap)
        EndIf
    Else
        If Not IsHWnd($hItem) Then $hItem = _GUICtrlTreeView_GetItemHandle($hwnd, $hItem)
        ; RECT is expected to point to the item in its first member.
        DllStructSetData($tRECT, "Left", $hItem)
        $iRet = GUICtrlSendMsg($hwnd, $TVM_GETITEMRECT, $bTextOnly, DllStructGetPtr($tRECT))
    EndIf

    ; On failure ensure Left is set to 0 and not the item handle.
    If Not $iRet Then DllStructSetData($tRECT, "Left", 0)
    Return SetError($iRet = 0, $iRet, $tRECT)
EndFunc   ;==>_GUICtrlTreeView_DisplayRectEx64

I just added links to this post and this few lines:

If @OSArch <> "X64" Then
        Local $iResult_temp =  _GUICtrlTreeView_ClickItem($hwnd, $hItem, $sButton, $bMove, $iClicks, $iSpeed)
        Return SetError(@error, @extended, $iResult_temp)
    EndIf

 

Edited April 23, 2021 by mLipok

[mLipok]

@LarsJ is that mean that _GUICtrlListView_ClickItem() also need to be changed ?

 

[LarsJ]

I think the code in both _GUICtrlTreeView_ClickItem64() and _GUICtrlTreeView_DisplayRectEx64() also works as 32 bit code. However, the 32 bit code has not been tested. So I would think that _GUICtrlTreeView_ClickItem64() and _GUICtrlTreeView_DisplayRectEx64() can be renamed to _GUICtrlTreeView_ClickItem() and _GUICtrlTreeView_DisplayRectEx() and replace the old functions.

[FelixTheCat]

On 4/29/2021 at 2:23 AM, mLipok said:

@LarsJ is that mean that _GUICtrlListView_ClickItem() also need to be changed ?

I ran into a similar issue with the _GUICtrlListView_ClickItem() on 64bit, as mLipok suggests might occur. ClickItem was 'missing the target' item.

The solution I used, to avoid introducing complex API calls, was to automate a click on pixel 10,10 inside the list view... then iterate sending a "DOWN" keystroke the required number of times to reach the target item..

ControlClick("Window Name", "", "[CLASS:SysListView32; INSTANCE:1]", "left", 1, 10, 10  )
Sleep(1000)

For $i = 1 to $RequiredListItem
    Send("{DOWN}")
    Sleep(1000)
Next

The sleep is just to give the HMI time to paint. You could try running it flat out, and see if your HMI is more responsive than the one I'm working with..

I'd imagine something similar could be done to walk the nodes of  a tree control. On that topic, tree controls are sometimes populated interactively by programmers as they are navigated (based on current experience), in which case you would have to iteratively expand each child node in a tree control, while performing the tree walk to stand a better chance of success.

[mLipok]

On 4/23/2021 at 10:35 AM, mLipok said:

Here is my modified version 

I start using new AutoIt 3.3.18.0 in all of my projects.
And I notice that this modified _GUICtrlTreeView_ClickItem64() will no longer work because GuiTreeView.au3 does not use $__g_hTVLastWnd from version 3.3.18.0, where some changes were made, and my dirty/failed solution no longer works.

Will check if current _GUICtrlTreeView_ClickItem() implementation also solves the issue with 64bit systems.

Edited September 16 by mLipok