Au3Stripper strips a used function

[Factfinder]

$Form = GUICreate("TEST", 500, 200, 200, 100, BitOR($WS_MAXIMIZEBOX, $WS_MINIMIZEBOX))
_Timer_SetTimer($Form, 2000, "Timertest")
GUISetState(@SW_SHOW)
While 1
WEnd

Func Timertest($hWnd, $iMsg, $iIDTimer, $iTime)
    #forceref $hWnd, $iMsg, $iIDTimer, $iTime
    Exit
EndFunc   ;==>TimeA

The above script works if not compiled or compiled without using Au3Stripper. When compiled with default Au3Stripper, it doesn't work because /sf removes the Timertest() function. By adding a dummy function (like If 1=2 then Timertest() ) to the script, the script works. I guess Au3Stripper doesn't regard the function "Timertest" called by _Timer_SetiTmer as a call to a function.

My apologies if I have posted this to the wrong section as I was not sure if this should be reported as an Autoit bug because it is related to the compiler and not AutoIt itself.

[Nine]

Remove quotes around TimerTest

[Factfinder]

It works thank you.

The example given here should be corrected as _UpdateProgressBar function is put in the quotes.

 

[Nine]

Both ways are accepted, but you need to be careful about this if you intend to use AutoItStripper.  Using quotes (instead of naming the function directly) hides the function name to Stripper.  That is why in your snippet it was not working correctly.

Edited November 28, 2020 by Nine

[Jos]

This is the best way of doing it as au3stripper doesn't know about all udf that possibly have a func name as parameter. Only internal functions are checked:

#include <WindowsConstants.au3>
#include <Timers.au3>
#Au3Stripper_Ignore_Funcs=Timertest
$Form = GUICreate("TEST", 500, 200, 200, 100, BitOR($WS_MAXIMIZEBOX, $WS_MINIMIZEBOX))
_Timer_SetTimer($Form, 2000, "Timertest")
GUISetState(@SW_SHOW)
While 1
WEnd

Func Timertest($hWnd, $iMsg, $iIDTimer, $iTime)
    #forceref $hWnd, $iMsg, $iIDTimer, $iTime
    Exit
EndFunc   ;==>TimeA

Jos

ps: please post a runnable script so it's easier to test... just like to ba lazy.  

Edited November 28, 2020 by Jos

[JockoDundee]

  On 11/28/2020 at 9:43 PM, Jos said:

au3stripper doesn't know about all udf that possibly have a func name as parameter. Only internal functions are checked:

Expand  

I’m confused, why did removing the quotes work then?

[jchd]

Because functions are now first-class citizens, have two new recognized datatypes, whereas a string  argument may evaluate or not to a function.

So it's easy for AutoIt compiler, runtime executable and companion programs to detect that an argument is a function. Something evaluating to a string is not detectable in the general case.

_RunMeNative(10, _f)
_RunMeString(12, Chr(0x5F) & Chr(0x40 + 6))

ConsoleWrite(VarGetType(_f) & @TAB & VarGetType(Mod) & @TAB & VarGetType(Chr(0x5F) & Chr(0x40 + 6)) & @LF)

Func _RunMeNative($n, $fct)
    $fct($n)
EndFunc

Func _RunMeString($n, $fct)
    Call($fct, $n)
EndFunc

Func _f($i)
    ConsoleWrite(($i * $i) & @LF)
EndFunc

 

[JockoDundee]

  On 11/29/2020 at 12:27 AM, jchd said:

Because functions are now first-class citizens, have two new recognized datatypes, whereas a string  argument may evaluate or not to a function.

Expand  

That I understand, but my question was directed at Jos, since he said:

  On 11/28/2020 at 9:43 PM, Jos said:

This is the best way of doing it as au3stripper doesn't know about all udf that possibly have a func name as parameter. Only internal functions are checked:

Expand  

Wherein he says the “best way” is to use a string and with the directive.  But if the function can be recognized directly without quoting, and without the need for a directive, then I would think that that would be the cleaner way.

Which way do you think is best and why?

[Nine]

  On 11/29/2020 at 4:20 AM, JockoDundee said:

Which way do you think is best and why?

Expand  

Not using quotes.  You will get immediate error without quotes:

#include <Timers.au3>
#include <GUIConstants.au3>

$Form = GUICreate("TEST", 500, 200, 200, 100, BitOR($WS_MAXIMIZEBOX, $WS_MINIMIZEBOX))
_Timer_SetTimer($Form, 2000, _Timertest)
GUISetState(@SW_SHOW)
While GUIGetMsg() <> $GUI_EVENT_CLOSE
WEnd

Func Timertest($hWnd, $iMsg, $iIDTimer, $iTime)
    #forceref $hWnd, $iMsg, $iIDTimer, $iTime
    Exit
EndFunc

Whereas using quotes, it will go undetected.  In a large program, it can be a pain to find the bug :

#include <Timers.au3>
#include <GUIConstants.au3>

$Form = GUICreate("TEST", 500, 200, 200, 100, BitOR($WS_MAXIMIZEBOX, $WS_MINIMIZEBOX))
_Timer_SetTimer($Form, 2000, "_Timertest")
GUISetState(@SW_SHOW)
While GUIGetMsg() <> $GUI_EVENT_CLOSE
WEnd

Func Timertest($hWnd, $iMsg, $iIDTimer, $iTime)
    #forceref $hWnd, $iMsg, $iIDTimer, $iTime
    Exit
EndFunc

I always preferred compilers to help me, instead of me helping compilers 

Edited November 29, 2020 by Nine

[JockoDundee]

  On 11/29/2020 at 6:47 AM, Nine said:

Not using quotes.  You will get immediate error without quotes:

Expand  

Agreed.  
Perhaps I misunderstood @Jos...

[Jos]

  On 11/28/2020 at 11:52 PM, JockoDundee said:

I’m confused, why did removing the quotes work then?

Expand  

That's simple: When removing the "" around the literal funcname it becomes a real variable, and since a while a variable notation can also refer to a UDF, hence au3stripper simply assumes that the parameter must be a reference to the func.  

Still think it is better to instruct au3stripper not to strip those func's you always want to keep with the indicated directive.

Jos

Edited November 29, 2020 by Jos

[LukeWCS]

Very interesting. I didn't know that the function can be passed directly as a function name in this case. That is also one of the things that are not mentioned in the help. Or I haven't found it yet. ^^

@Jos
You favor the function name as a string together with the definition of an au3stripper directive. Is there also a technical background for this, or is it personal preference?

The background to my question: in one of my larger projects I have a large number of events and it would be very helpful for me if I could pass all the functions directly as function names for one simple reason: auto-completion. It is agony when I have to know exactly the function name that I want to call every time I define a new event. It would be much easier with autocomplete.

Edited January 11, 2021 by LukeWCS

[mLipok]

  On 1/11/2021 at 10:36 AM, LukeWCS said:

That is also one of the things that are not mentioned in the help

Expand  

https://www.autoitscript.com/autoit3/docs/function_notes.htm

  Quote

Function Notes

Functions in AutoIt are first class objects. Among other things, that means you can assign a function to a variable, pass it around as an argument or return from another function.

Expand  

But I can agree that this section of HelpFile could be suplemented by additional examples.
 

Edited January 11, 2021 by mLipok

[Jos]

  On 1/11/2021 at 10:36 AM, LukeWCS said:

@Jos
You favor the function name as a string together with the definition of an au3stripper directive. Is there also a technical background for this, or is it personal preference?

Expand  

Not sure what you mean with favor function name as string?
Also not sure about the next part... so maybe a simple example snippet to show me what you mean?

Jos
 

 

[Jos]

  On 1/11/2021 at 11:45 AM, mLipok said:

But I can agree that this section of HelpFile could be suplemented by additional examples.

Expand  

More information doesn't always help making it better. Think that page is pretty clear as is as long as one knows what to look for an read it.  

Edited January 11, 2021 by Jos

[LukeWCS]

  On 1/11/2021 at 11:45 AM, mLipok said:

https://www.autoitscript.com/autoit3/docs/function_notes.htm

But I can agree that this section of HelpFile could be suplemented by additional examples.
 

Expand  

Thanks for the hint. It took me a few minutes to find it in Help. Even if I had remembered it, I would not have linked this section to the Factfinder problem. Which is probably related to the fact that the example shown there with "MsgBox" does not explain what this is good for. A more detailed example would actually have made sense here. I only know something similar from other languages as an "anonymous function". But this seems to be something else.

 

  On 1/11/2021 at 3:29 PM, Jos said:

Not sure what you mean with favor function name as string?

Expand  

I relate that to your two answers:

 

  On 11/28/2020 at 9:43 PM, Jos said:

This is the best way of doing it as au3stripper doesn't know about all udf that possibly have a func name as parameter. Only internal functions are checked:

Expand  

 

  On 11/29/2020 at 12:48 PM, Jos said:

Still think it is better to instruct au3stripper not to strip those func's you always want to keep with the indicated directive.

Expand  

From these two posts I can see that in this case you prefer the text variant plus au3stripper directive. And I wanted to know why you prefer that as I would rather prefer Nine's variant.

 

  On 1/11/2021 at 3:29 PM, Jos said:

Also not sure about the next part... so maybe a simple example snippet to show me what you mean?

Expand  

In the help for the function that Factfinder uses it says:
 

_Timer_SetTimer ($ hWnd [, $ iElapse = 250 [, $ sTimerFunc = "" [, $ iTimerID = -1]]])

And in the help for the function, which is about in my case, it says:
 

GUISetOnEvent (specialID, "function" [, winhandle])

In both cases it is clearly a matter of a string that is to be passed in the parameter. So, of course, I assumed that this was the only variant. In the help, there is no indication that the function names can also be passed directly in the parameter, not just as text.

 

 

[mLipok]

  On 1/12/2021 at 11:00 AM, LukeWCS said:

Which is probably related to the fact that the example shown there with "MsgBox" does not explain what this is good for. A more detailed example would actually have made sense here

Expand  

 

  On 1/11/2021 at 3:32 PM, Jos said:

More information doesn't always help making it better. Think that page is pretty clear as is as long as one knows what to look for an read it.

Expand  

I try to propose something this week.

 

[jchd]

I've contributed a revised version of help about types and variables.  It's likely to appear with the next release but don't ask me when.

[Jos]

  On 1/12/2021 at 11:00 AM, LukeWCS said:

From these two posts I can see that in this case you prefer the text variant plus au3stripper directive. And I wanted to know why you prefer that as I would rather prefer Nine's variant.

Expand  

No preference, just explained the consequences and the difference. My stated preference is to add those functions to an  directive so they never will be stripped:

  Quote

#Au3Stripper_Ignore_Funcs=                 Do not Strip these functions. FuncNames may end with an * to indicated matching FuncNames starting with the specified string.

Expand  

Jos

Edited January 12, 2021 by Jos

[Nine]

I believe it is because most of the documentation was written before the addition of function as a variable type (appeared in 3.3.10.0 - end of dec. 2013).  After that it was common habit to use quotes around function to reference them as parameters.   But I cannot see any good reason to use them with quotes anymore.  Like it has already been said, using function as a variable gains multiple advantages :

1- Auto-completion

2- Recognition by Au3Check

3- Identification in Au3Stripper

4- Faster access to the function

5- Usage of function in variables