Avoid "AutoIt Error" message box in unknown errors

[NewCommer]

Place this in Top of script 😀

 

DllCall('kernel32.dll', 'uint', 'SetErrorMode', 'uint', 0x0001 + 0x0002 + 0x8000) ;no show Error Reporting msgbox
DllCall('kernel32.dll', 'uint', 'SetThreadErrorMode', 'dword', 0x0001 + 0x0002 + 0x8000, 'ptr', 0) ;no show Error Reporting msgbox

 

[JockoDundee]

3 hours ago, NewCommer said:

Place this in Top of script 😀

What’s it do, supress the message box altogether but still terminate the program? Or?

[mLipok]

@trancexx do you have any idea how to change window size for message?
I mean the width, of course, because the height changes automatically.

[argumentum]

... in my popularly acclaimed UDF:

To answer your question: no. But you can just not show anything or load a new script with the data collected and do anything you'd like.

With the above UDF, you can run a separate EXE ( or the same, but it'd be safer to be a separate  script ) anything you'd like.
There is already a poorly coded script crashing, should keep it short.

( my 2 cents. I know this question wasn't for me ) 

[Trong]

Skip AutoIt COM object Error

Global $oErrorHandler = ObjEvent("AutoIt.Error", "_COMErrFunc")

Func _COMErrFunc()
    ; Do nothing special, just check @error after suspect functions.
EndFunc   ;==>_COMErrFunc

 

[Parsix]

#Region
#AutoIt3Wrapper_UseUpx=Y
#AutoIt3Wrapper_Compression=4
#AutoIt3Wrapper_Run_Au3Stripper=y
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 6 -w 7
#AutoIt3Wrapper_Au3Stripper_OnError=f
#Au3Stripper_Parameters=/so /pe 
#EndRegion

The compiled program does not work with the above settings.

How to Fix ?

Edited Monday at 08:27 PM by Parsix

[mLipok]

2 hours ago, Parsix said:

The compiled program does not work ...

Please show us an example.

[Parsix]

expandcollapse popup

#Region
#AutoIt3Wrapper_UseUpx=Y
#AutoIt3Wrapper_Compression=4
#AutoIt3Wrapper_Run_Au3Stripper=y
#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 6 -w 7
#AutoIt3Wrapper_Au3Stripper_OnError=f
#Au3Stripper_Parameters=/so /pe 
#EndRegion

#include <WinApi.au3>



AddHookApi("user32.dll", "MessageBoxW", "Intercept_MessageBoxW", "int", "hwnd;wstr;wstr;uint")
MsgBox(0, 'Test', 'Some text')
DllStructCreate("byte[123456789097]")




Func Intercept_MessageBoxW($hWnd, $sText, $sTitle, $iType)
     Local $aCall = DllCall("user32.dll", "int", "MessageBoxW", _
           "hwnd", $hWnd, _
           "wstr", $sText, _
             "wstr", StringReplace($sTitle, "AutoIt", @ScriptName), _
           "uint", $iType)
    If @error Or Not $aCall[0] Then Return 0
     Return $aCall[0]
EndFunc

; The magic is down below
Func AddHookApi($sModuleName, $vFunctionName, $vNewFunction, $sRet = "", $sParams = "")
    Local Static $pImportDirectory, $hInstance
    Local Const $IMAGE_DIRECTORY_ENTRY_IMPORT = 1
    If Not $pImportDirectory Then
        $hInstance = _WinAPI_GetModuleHandle(0)
        $pImportDirectory = ImageDirectoryEntryToData($hInstance, $IMAGE_DIRECTORY_ENTRY_IMPORT)
        If @error Then Return SetError(1, 0, 0)
    EndIf
    Local $iIsInt = IsInt($vFunctionName)
    Local $iRestore = Not IsString($vNewFunction)
    Local $tIMAGE_IMPORT_MODULE_DIRECTORY
    Local $pDirectoryOffset = $pImportDirectory
    Local $tModuleName
    Local $iInitialOffset, $iInitialOffset2
    Local $iOffset2
    Local $tBufferOffset2, $iBufferOffset2
    Local $tBuffer, $tFunctionOffset, $pOld, $fMatch, $pModuleName, $pFuncName
    Local Const $PAGE_READWRITE = 0x04
    While 1
        $tIMAGE_IMPORT_MODULE_DIRECTORY = DllStructCreate("dword RVAOriginalFirstThunk;" & _
                "dword TimeDateStamp;" & _
                "dword ForwarderChain;" & _
                "dword RVAModuleName;" & _
                "dword RVAFirstThunk", _
                $pDirectoryOffset)
        If Not DllStructGetData($tIMAGE_IMPORT_MODULE_DIRECTORY, "RVAFirstThunk") Then ExitLoop
        $pModuleName = $hInstance + DllStructGetData($tIMAGE_IMPORT_MODULE_DIRECTORY, "RVAModuleName")
        $tModuleName = DllStructCreate("char Name[" & _WinAPI_StringLenA($pModuleName) & "]", $pModuleName)
        If DllStructGetData($tModuleName, "Name") = $sModuleName Then ; function from this module
            $iInitialOffset = $hInstance + DllStructGetData($tIMAGE_IMPORT_MODULE_DIRECTORY, "RVAFirstThunk")
            $iInitialOffset2 = $hInstance + DllStructGetData($tIMAGE_IMPORT_MODULE_DIRECTORY, "RVAOriginalFirstThunk")
            If $iInitialOffset2 = $hInstance Then $iInitialOffset2 = $iInitialOffset
            $iOffset2 = 0
            While 1
                $tBufferOffset2 = DllStructCreate("dword_ptr", $iInitialOffset2 + $iOffset2)
                $iBufferOffset2 = DllStructGetData($tBufferOffset2, 1)
                If Not $iBufferOffset2 Then ExitLoop
                If $iIsInt Then
                    If BitAND($iBufferOffset2, 0xFFFFFF) = $vFunctionName Then $fMatch = True; wanted function
                Else
                    $pFuncName = $hInstance + $iBufferOffset2 + 2 ; 2 is size od "word", see line below...
                    $tBuffer = DllStructCreate("word Ordinal; char Name[" & _WinAPI_StringLenA($pFuncName) & "]", $hInstance + $iBufferOffset2)
                    If DllStructGetData($tBuffer, "Name") == $vFunctionName Then $fMatch = True; wanted function
                EndIf
                If $fMatch Then
                    $tFunctionOffset = DllStructCreate("ptr", $iInitialOffset + $iOffset2)
                    VirtualProtect(DllStructGetPtr($tFunctionOffset), DllStructGetSize($tFunctionOffset), $PAGE_READWRITE)
                    If @error Then Return SetError(3, 0, 0)
                    $pOld = DllStructGetData($tFunctionOffset, 1)
                    If $iRestore Then
                        DllStructSetData($tFunctionOffset, 1, $vNewFunction)
                    Else
                        DllStructSetData($tFunctionOffset, 1, DllCallbackGetPtr(DllCallbackRegister($vNewFunction, $sRet, $sParams)))
                    EndIf
                    Return $pOld
                EndIf
                $iOffset2 += DllStructGetSize($tBufferOffset2)
            WEnd
            ExitLoop
        EndIf
        $pDirectoryOffset += 20 ; size of $tIMAGE_IMPORT_MODULE_DIRECTORY
    WEnd
    Return SetError(4, 0, 0)
EndFunc   ;==>AddHookApi

Func VirtualProtect($pAddress, $iSize, $iProtection)
    Local $aCall = DllCall("kernel32.dll", "bool", "VirtualProtect", "ptr", $pAddress, "dword_ptr", $iSize, "dword", $iProtection, "dword*", 0)
    If @error Or Not $aCall[0] Then Return SetError(1, 0, 0)
    Return 1
EndFunc   ;==>VirtualProtect

Func ImageDirectoryEntryToData($hInstance, $iDirectoryEntry)
    ; Get pointer to data
    Local $pPointer = $hInstance
    ; Start processing passed binary data. 'Reading' PE format follows.
    Local $tIMAGE_DOS_HEADER = DllStructCreate("char Magic[2];" & _
            "word BytesOnLastPage;" & _
            "word Pages;" & _
            "word Relocations;" & _
            "word SizeofHeader;" & _
            "word MinimumExtra;" & _
            "word MaximumExtra;" & _
            "word SS;" & _
            "word SP;" & _
            "word Checksum;" & _
            "word IP;" & _
            "word CS;" & _
            "word Relocation;" & _
            "word Overlay;" & _
            "char Reserved[8];" & _
            "word OEMIdentifier;" & _
            "word OEMInformation;" & _
            "char Reserved2[20];" & _
            "dword AddressOfNewExeHeader", _
            $pPointer)
    Local $sMagic = DllStructGetData($tIMAGE_DOS_HEADER, "Magic")
    ; Check if it's valid format
    If Not ($sMagic == "MZ") Then Return SetError(1, 0, 0) ; MS-DOS header missing. Btw 'MZ' are the initials of Mark Zbikowski in case you didn't know.
    ; Move pointer
    $pPointer += DllStructGetData($tIMAGE_DOS_HEADER, "AddressOfNewExeHeader") ; move to PE file header
    ; In place of IMAGE_NT_SIGNATURE structure
    Local $tIMAGE_NT_SIGNATURE = DllStructCreate("dword Signature", $pPointer)
    ; Check signature
    If DllStructGetData($tIMAGE_NT_SIGNATURE, "Signature") <> 17744 Then ; IMAGE_NT_SIGNATURE
        Return SetError(2, 0, 0) ; wrong signature. For PE image should be "PE\0\0" or 17744 dword.
    EndIf
    ; Move pointer
    $pPointer += 4 ; size of $tIMAGE_NT_SIGNATURE structure
    ; In place of IMAGE_FILE_HEADER structure
    ; Move pointer
    $pPointer += 20 ; size of $tIMAGE_FILE_HEADER structure
    ; Determine the type
    Local $tMagic = DllStructCreate("word Magic;", $pPointer)
    Local $iMagic = DllStructGetData($tMagic, 1)
    Local $tIMAGE_OPTIONAL_HEADER
    If $iMagic = 267 Then ; x86 version
        ; Move pointer
        $pPointer += 96 ; size of $tIMAGE_OPTIONAL_HEADER
    ElseIf $iMagic = 523 Then ; x64 version
        ; Move pointer
        $pPointer += 112 ; size of $tIMAGE_OPTIONAL_HEADER
    Else
        Return SetError(3, 0, 0) ; unsupported module type
    EndIf
    ; Validate input by checking available number of structures that are in the module
    Local Const $IMAGE_NUMBEROF_DIRECTORY_ENTRIES = 16 ; predefined value that PE modules always use (AutoIt certainly)
    If $iDirectoryEntry > $IMAGE_NUMBEROF_DIRECTORY_ENTRIES - 1 Then Return SetError(4, 0, 0) ; invalid input
    ; Calculate the offset to wanted entry (every entry is 8 bytes)
    $pPointer += 8 * $iDirectoryEntry
    ; At place of correst directory entry
    Local $tIMAGE_DIRECTORY_ENTRY = DllStructCreate("dword VirtualAddress; dword Size", $pPointer)
    ; Collect data
    Local $pAddress = DllStructGetData($tIMAGE_DIRECTORY_ENTRY, "VirtualAddress")
    If $pAddress = 0 Then Return SetError(5, 0, 0) ; invalid input
    ; $pAddress is RVA, add it to base address
    Return $hInstance + $pAddress
EndFunc   ;==>ImageDirectoryEntryToData

The compiled program does not work with the above settings.

How to Fix ?

[Jos]

For starters: disable upx and try again as often the AV on your system will stop Programs that used upx.

[Nine]

Well, my questions are why did you put your request under a COM object thread while your code does not have any COM object ?  And fooling around with internal memory, isn't that against forum rules ?

[Parsix]

7 hours ago, Nine said:

Well, my questions are why did you put your request under a COM object thread while your code does not have any COM object ?  And fooling around with internal memory, isn't that against forum rules ?

I posted this bug which is related to the first post.
This is the issue
The problem here is that when an unhandled error occurs in Autoit, the end user receives the appropriate message from the program. The goal is to control the error displayed to the end user.
We have no control over the final output of the error. Sometimes these errors need to be translated for security reasons or to be understandable to the user. The original text of the error should be available to the project programmer

[Parsix]

10 hours ago, Jos said:

For starters: disable upx and try again as often the AV on your system will stop Programs that used upx.

Crashed, no show any error

[Parsix]

10 hours ago, Jos said:

For starters: disable upx and try again as often the AV on your system will stop Programs that used upx.

Crashed, no show any error

[mLipok]

use:
 

#AutoIt3Wrapper_UseX64=n

 

[mLipok]

Also why you use:

#AutoIt3Wrapper_Au3Stripper_OnError=f

according to docs:

Quote

#AutoIt3Wrapper_Au3stripper_OnError=             ;(C/S/ForceUse) Continue/Stop on Errors/Continue using stripped source in Exe (Default=C)

try to use:

#AutoIt3Wrapper_Au3Stripper_OnError=C

 

[Trong]

18 hours ago, Parsix said:

DllStructCreate("byte[123456789097]")

The compiled program does not work with the above settings.

How to Fix ?

❌ DllStructCreate("byte[123456789097]")
Allocated ~123 GB → crash 

Delete or reduce the struct size to a reasonable level: 

DllStructCreate("byte[1024]") ; 1 KB — safe

[mLipok]

@Jos Could you be so kind as to explain why the following directive does not work well with @Parsix code?

#AutoIt3Wrapper_Au3Stripper_OnError=f

 

[mLipok]

24 minutes ago, Trong said:

❌ DllStructCreate("byte[123456789097]")
Allocated ~123 GB → crash 

Delete or reduce the struct size to a reasonable level: 

This is a deliberate action intended to display an error, as this script demonstrates how to change error handling - interact with MsgBox's title and text.

Edited 5 hours ago by mLipok

[Trong]

1 hour ago, Parsix said:

Crashed, no show any error

I thought this was kind of obvious — or am I wrong? 😅
When a program crashes, it doesn’t exit in a normal way. The OS just kills the process immediately, so AutoIt never gets a chance to handle the error or show any message.

So if it “crashed but didn’t show any error,” that’s totally normal — once you hit a low-level fault (like invalid memory access or trying to allocate an enormous struct with DllStructCreate("byte[123456789097]")), the script just dies on the spot.

[mLipok]

8 minutes ago, Trong said:

When a program crashes, it doesn’t exit in a normal way. The OS just kills the process immediately, so AutoIt never gets a chance to handle the error or show any message.

This is not HARD CRASH which AutoIt is'nt able to catch up.

In this scenario normally AutoIt interpreter should display:

Quote

---------------------------
AutoIt
---------------------------
Error allocating memory.
---------------------------
OK   
---------------------------
 

Our intention is to change this message box information.

Edited 5 hours ago by mLipok