RegExp - question - new line between two different start-up lines

[mLipok]

I have this kind of source data:

TEST1   2013-02-08  some text
TEST1   2013-2-08   some text
TEST1   2013-01-15  some text
TEST1   2013-01-15  some text
TEST1   2013-01-03  some text
TEST2   2013-1-17   some text
TEST2   2013-1-18   some text
TEST2   2013-1-21   some text

 

I wondered how using SRE add a new line, but only at the point where the difference in the first word, ie in the present case, separate lines starting with TEST1 from the line starting with TEST2 

 

Can someone give me a hint?

[Melba23]

mLipok,

Why use an SRE - I see no advantage here. Read the file into an array, run through it until you find a changeover point, insert the new line, and then save the new array.

M23

[mLipok]

You light up my mind as a light bulb 

Thanks.

I just use your idea.

But the question is still interesting for me. 

As someone who has a solution for RegExp I would be grateful.

[Melba23]

mLipok,

When I first started learning about SREs, GEOSoft gave me the best piece of advice I ever got concerning them - "learn when not to use them". I now pass the same advice on to you (and anyone else reading).

M23

[mLipok]

Not so long ago I read the same "golden idea" / anecdote from another member.

 

Just tell me if by this time the idea in your case, turned out to be right.

[mikell]

Yes ... absolutely

Why do it simple when it can be complicated ?

$txt = _
"TEST1   2013-02-08  some text" & @crlf & _
"TEST1   2013-2-08   some text" & @crlf & _
"TEST1   2013-01-15  some text" & @crlf & _
"TEST2   2013-01-15  some text" & @crlf & _
"TEST2   2013-01-03  some text" & @crlf & _
"TEST3   2013-1-17   some text" & @crlf & _
"TEST4   2013-1-18   some text" & @crlf & _
"TEST4   2013-1-19   some text" & @crlf & _
"TEST5   2013-1-21   some text"

$txt = StringRegExpReplace($txt, '((?<=\v)(\S+).+\R(?!\2))', '$1' & @crlf )

Msgbox(0,"", $txt)

Melba, read and agreed

Edited January 29, 2014 by mikell

[mLipok]

Super 

Thanks a lot. 

I am grateful.

 

mLipok

[guinness]

Sweet regular expression.

[Malkey]

A fine adjustment needed.

Because of this "(?<=v)(S+)", the first line will not match because it does not have a preceeding vertical white space. Therefore, when using this post's example's test data, "StringRegExpReplace($txt, '((?<=v)(S+).+R(?!2))', '$1' & @crlf )" would fail to put an extra newline after the first line.
Otherwise it works great.

Local $txt = _
        "TEST1   2013-02-08  some text" & @CRLF & _
        "TEST2   2013-2-08   some text" & @CRLF & _
        "TEST2   2013-01-15  some text" & @CRLF & _
        "TEST2   2013-01-15  some text" & @CRLF & _
        "TEST2   2013-01-03  some text" & @LF & _
        "TEST3   2013-1-17   some text" & @LF & _
        "TEST4   2013-1-18   some text" & @LF & _
        "TEST4   2013-1-19   some text" & @LF & _
        "TEST5   2013-1-21   some text"

;$txt = StringRegExpReplace($txt, '(((?<=\v)\S+)\N+\R(?!\2))',  '$1' & @crlf )
$txt = StringRegExpReplace($txt, '(?m)((^\S+)\V+\R(?!\2))', '$1' & @CRLF)

ConsoleWrite($txt & @LF)

[mikell]

Thanks for this note

Shame on me, I didn't pay attention to this... yet it was easy

$txt = StringRegExpReplace($txt, '((?<=\v|^)(\S+).+\R(?!\2))',  '$1' & @crlf )

[mLipok]

I worked a bit on this and I wanted do a little more complicated task. 

But unfortunately I lost. 

 

Here is What I trying:

Source string is a content copied from XLS.

Column are separated by @TAB. 

First column ie. TEST1 or TEST2 can contain whitechar.

 

 

Local $txt = ''
$txt &= "TEST1   2013-02-08  some text" & @CRLF 
; HERE I want to add new line
$txt &= "TEST 2   2013-2-08   some text" & @CRLF
$txt &= "TEST 2   2013-01-15  some text" & @CRLF
$txt &= "TEST 2   2013-01-15  some text" & @CRLF
$txt &= "TEST 2   2013-01-03  some text" & @LF
; HERE I want to add new line
$txt &= "TEST3   2013-1-17   some text" & @LF
; HERE I want to add new line
$txt &= "TEST4   2013-1-17   some text" & @LF
$txt &= "TEST4   2013-1-18   some text" & @LF
$txt &= "TEST4   2013-1-18   some text" & @LF
; HERE I want to add new line
$txt &= "TEST5   2013-1-21   some text" & @LF
$txt &= "TEST5   2013-1-21   some text" & @CRLF
; HERE I want to add new line
$txt &= "TEST 5   2013-1-21   some text" & @LF

;$txt = StringRegExpReplace($txt, '(((?<=\v)\S+)\N+\R(?!\2))',  '$1' & @crlf )
$txt = StringRegExpReplace($txt, '((?<=\v|^)(\S+).+\R(?!\2))',  '$1' & @crlf )

ConsoleWrite($txt & @LF)

[mikell]

The correction to do is really a minor one, simple adaptation to new circumstances

Here you only need to match non-tab characters in the first group

Local $txt = ''
$txt &= "TEST1" &@TAB& "2013-02-08" &@TAB& "some text" & @CRLF 
; HERE I want to add new line
$txt &= "TEST 2" &@TAB& "2013-2-08" &@TAB& "some text" & @CRLF
$txt &= "TEST 2" &@TAB& "2013-01-15" &@TAB& "some text" & @CRLF
$txt &= "TEST 2" &@TAB& "2013-01-15" &@TAB& "some text" & @CRLF
$txt &= "TEST 2" &@TAB& "2013-01-03" &@TAB& "some text" & @LF
; HERE I want to add new line
$txt &= "TEST3" &@TAB& "2013-1-17" &@TAB& "some text" & @LF
; HERE I want to add new line
$txt &= "TEST4" &@TAB& "2013-1-17" &@TAB& "some text" & @LF
$txt &= "TEST4" &@TAB& "2013-1-18" &@TAB& "some text" & @LF
$txt &= "TEST4" &@TAB& "2013-1-18" &@TAB& "some text" & @LF
; HERE I want to add new line
$txt &= "TEST5" &@TAB& "2013-1-21" &@TAB& "some text" & @LF
$txt &= "TEST5" &@TAB& "2013-1-21" &@TAB& "some text" & @CRLF
; HERE I want to add new line
$txt &= "TEST 5" &@TAB& "2013-1-21" &@TAB& "some text" 

$txt = StringRegExpReplace($txt, '((?<=\v|^)([^\t]+).+\R(?!\2))', '$1' & @crlf )
Msgbox(0,"", $txt)

Or this using Malkey's code

$txt = StringRegExpReplace($txt, '(?m)((^[^\t]+)\V+\R(?!\2))', '$1' & @CRLF)

Edited January 30, 2014 by mikell

[Melba23]

mikell,

Well done.

It seems I was once again too pessimistic about the capabilities of RegExes. But if you add in the time it would have taken me to develop a pattern like that (close to the known age of the universe I expect ) using an SRE would have taken longer for me than my initial suggestion!

M23

[mLipok]

  On 1/30/2014 at 11:31 AM, mikell said:

 

The correction to do is really a minor one, simple adaptation to new circumstances

Here you only need to match non-tab characters in the first group

Local $txt = ''
$txt &= "TEST1" &@TAB& "2013-02-08" &@TAB& "some text" & @CRLF 
; HERE I want to add new line
$txt &= "TEST 2" &@TAB& "2013-2-08" &@TAB& "some text" & @CRLF
$txt &= "TEST 2" &@TAB& "2013-01-15" &@TAB& "some text" & @CRLF
$txt &= "TEST 2" &@TAB& "2013-01-15" &@TAB& "some text" & @CRLF
$txt &= "TEST 2" &@TAB& "2013-01-03" &@TAB& "some text" & @LF
; HERE I want to add new line
$txt &= "TEST3" &@TAB& "2013-1-17" &@TAB& "some text" & @LF
; HERE I want to add new line
$txt &= "TEST4" &@TAB& "2013-1-17" &@TAB& "some text" & @LF
$txt &= "TEST4" &@TAB& "2013-1-18" &@TAB& "some text" & @LF
$txt &= "TEST4" &@TAB& "2013-1-18" &@TAB& "some text" & @LF
; HERE I want to add new line
$txt &= "TEST5" &@TAB& "2013-1-21" &@TAB& "some text" & @LF
$txt &= "TEST5" &@TAB& "2013-1-21" &@TAB& "some text" & @CRLF
; HERE I want to add new line
$txt &= "TEST 5" &@TAB& "2013-1-21" &@TAB& "some text" 

$txt = StringRegExpReplace($txt, '((?<=\v|^)([^\t]+).+\R(?!\2))', '$1' & @crlf )
Msgbox(0,"", $txt)

Or this using Malkey's code

$txt = StringRegExpReplace($txt, '(?m)((^[^\t]+)\V+\R(?!\2))', '$1' & @CRLF)

 

Thanks

I try tonight

  On 1/30/2014 at 11:39 AM, Melba23 said:

mikell,

Well done.

It seems I was once again too pessimistic about the capabilities of RegExes. But if you add in the time it would have taken me to develop a pattern like that (close to the known age of the universe I expect ) using an SRE would have taken longer for me than my initial suggestion!

M23

 

I will try to do tonight benchmarking performance.

[mikell]

  On 1/30/2014 at 11:39 AM, Melba23 said:

But if you add in the time it would have taken me to develop a pattern like that (close to the known age of the universe I expect ) using an SRE would have taken longer for me than my initial suggestion!

M23

 

Melba,

Really too pessimistic about yourself !

Although you precisely described the purpose of this forum, didn't you ?

Edited January 30, 2014 by mikell

[Malkey]

Another fine adjustment needed.

When the test data has a trailing linefeed as in mLipok's example of post #11, another additional linefeed is added. So "|z"is added to the RE pattern to stop the additional trailing linefeed being added to the output.

Local $txt = ''
$txt &= "TEST1"  & @TAB & "2013-02-08" & @TAB & "some text" & @CRLF
; HERE I want to add new line
$txt &= "TEST 2" & @TAB & "2013-2-08" & @TAB & "some text" & @CRLF
$txt &= "TEST 2" & @TAB & "2013-01-15" & @TAB & "some text" & @CRLF
$txt &= "TEST 2" & @TAB & "2013-01-15" & @TAB & "some text" & @CRLF
$txt &= "TEST 2" & @TAB & "2013-01-03" & @TAB & "some text" & @LF
; HERE I want to add new line
$txt &= "TEST3"  & @TAB & "2013-1-17" & @TAB & "some text" & @LF
; HERE I want to add new line
$txt &= "TEST4"  & @TAB & "2013-1-17" & @TAB & "some text" & @LF
$txt &= "TEST4"  & @TAB & "2013-1-18" & @TAB & "some text" & @LF
$txt &= "TEST4"  & @TAB & "2013-1-18" & @TAB & "some text" & @LF
; HERE I want to add new line
$txt &= "TEST5"  & @TAB & "2013-1-21" & @TAB & "some text" & @LF
$txt &= "TEST5"  & @TAB & "2013-1-21" & @TAB & "some text" & @CRLF
; HERE I want to add new line
$txt &= "TEST 5" & @TAB & "2013-1-21" & @TAB & "some text" & @LF

;$txt = StringRegExpReplace($txt, '((?<=\v|^)([^\t]+).+\R(?!\2))', '$1' & @crlf )    ; mikell's original
;$txt = StringRegExpReplace($txt, '((?<=\v|^)([^\t]+).+\R(?!\2|\z))', '$1' & @crlf ) ;  mikell's corrected for trailing @LF.
$txt = StringRegExpReplace($txt, '(?m)((^[^\t]+)\V+\R(?!\2|\z))', '$1' & @CRLF)      ; Malkey's corrected for trailing @LF.

ConsoleWrite($txt & @LF)

 

[mikell]

Nicely noticed

This reminds me of a discussion I read somewhere about _FileCountLines and the existence of an EOF blank line

[jchd]

Exactly the same issue.