TxTextControl - problem with ObjCreate - Class not registered

[mLipok]

I'am trying to use

http://www.textcontrol.com/en_US/products/activex/overview/

How you can see here this object is registered:

 

but when I'am trying

$oTXTextControl = ObjCreate("TIS.TX.TextControl.21")

Then I get:

 

TxTextControl.au3 (42) : ==> COM Error intercepted !
    err.number is:         0x80040154
    err.windescription:    Klasa niezarejestrowana.

    err.description is:     
    err.source is:         
    err.helpfile is:     
    err.helpcontext is:     
    err.lastdllerror is:     0
    err.scriptline is:     42
    err.retcode is:     0x00000000

 

 err.windescription:    Klasa niezarejestrowana. >>> Class not registered

even if I add #RequireAdmin then the same problem happend.

 

Any concept why ?

mLipok

 

EDIT: added tags to topic

Edited March 27, 2015 by mLipok

[mLipok]

I have more experience in this field.
But I need the help of people who know C ++

Below is a description of how to set the license key.

http://www.textcontrol.com/en_US/support/documentation/activex/o_techarticle_licensing.htm

 

...
   if (CWnd::Create(lpszClassName, lpszWindowName, dwStyle,rect, 
      pParentWnd, nID, pContext) == 0)
      return 0;
   WCHAR szLic[] = L"TS-1234567890";
   BSTR bstrKey = SysAllocString(szLic);
   BOOL bSuccess = m_txctrl.Create(NULL, dwStyle, rect,
      this, 1000, NULL, NULL,bstrKey);
   SysFreeString(bstrKey);
   if (!bSuccess)
      return 0;
   ...

The license string must be a valid Text Control serial number. Replace the example string "TS-1234567890" with your serial number.

The question of how to set it in AutoIt ?

 

[mLipok]

last attempt.
Anyone else who can help?

 

I need this to make UDF for TXTextControl

 

mLipok

EDIT:

the following code snippet from the WM_CREATE handler of a Visual C++ sample application:

...
   if (CWnd::Create(lpszClassName, lpszWindowName, dwStyle,rect, 
      pParentWnd, nID, pContext) == 0)
      return 0;
   WCHAR szLic[] = L"TS-1234567890";
   BSTR bstrKey = SysAllocString(szLic);
   BOOL bSuccess = m_txctrl.Create(NULL, dwStyle, rect,
      this, 1000, NULL, NULL,bstrKey);
   SysFreeString(bstrKey);
   if (!bSuccess)
      return 0;
   ...

 

Edited May 9, 2015 by mLipok

[mLipok]

It may seem to you that I'm trying to "hack" this library AcitveX.
But it is not.
The manufacturer of this library, simply using strange (at least for me) licensing method.
Their objects do not have the normal method to use a license key.

After contact with their support team they showed me the above-mentioned link.

 

Hi Michał, Thanks for your reply. I do not think that you will be able to use the trial version in autoit as it apparently does not support the same license model as Visual Basic 6 does. Additionally, I have no idea how autoit works with licenses or if it supports that altogether. Anyway, here is a guide for C++ licensing, maybe that will help you: http://www.textcontrol.com/en_US/support/documentation/activex/o_techarticle_licensing.htm Please note that you required a valid TX Text Control serial number for the code in the above article to work.   Best regards, Gunnar Giffey -- Text Control Support Department http://www.textcontrol.com Text Control GmbH Firmensitz: Admiralstr. 54, D-28215 Bremen Registergericht: Amtsgericht Bremen HRB 25 927 Geschäftsführer: Heiner Suhr

 

So, any help in solving this problem will be greatly appreciated.

Best regards,

mLipok

 

EDIT:

some more info:

http://forums.textcontrol.com/showthread.php?319006-can-i-use-this-activeX-in-my-MFC-project&highlight=license+key

http://forums.textcontrol.com/showthread.php?325531-How-can-I-include-my-product-serial-number-in-my-code

http://forums.textcontrol.com/showthread.php?321455-License-question-for-interop&highlight=license+key

http://forums.textcontrol.com/showthread.php?314366-License-Error

http://forums.textcontrol.com/showthread.php?322607-Licensing-in-CAB&highlight=license+key

 

 

and:

http://www.peg.com/forums/api/200804/msg00006.html
http://www.textcontrol.com/en_US/support/documentation/activex/o_explorer_using.step5.htm

 

Edited May 11, 2015 by mLipok
wording

[mLipok]

Hm... I back to this case with ChatGPT which uses:

Local $oObj = $oFactory.CreateInstanceLic(0, 0, $IID_IDispatch, $sLicenseKey)

here is example:

expandcollapse popup

#AutoIt3Wrapper_UseX64=N
#include <MsgBoxConstants.au3>

_Example()

Func _Example()
    ;=========================================================
    ; TEST
    ;=========================================================
    Local $sKey = "YOUR_LICENSE_KEY"
    Local $sLog = @ScriptDir & "\tx_debug.log"

    Local $oTX = _TXTextControl_Create($sKey, True, $sLog)

    If IsObj($oTX) Then
        MsgBox($MB_ICONINFORMATION, "TX Text Control", "OK - control initialized")

        ; SAFE ACCESS
        $oTX.Text = "Hello TX Text Control"
    Else
        MsgBox($MB_ICONERROR, "TX Text Control", "Initialization error")
    EndIf

EndFunc   ;==>_Example


;=========================================================
; MAIN FUNCTION
;=========================================================
Func _TXTextControl_Create($sLicenseKey, $bDebug = True, $sLogFile = "")

    Local Const $CLSCTX_INPROC_SERVER = 1

    Local Const $CLSID_TX = "{510E4201-2487-11E4-A584-0013D350667C}"
    Local Const $IID_IClassFactory2 = "{B196B28F-BAB4-101A-B69C-00AA00341D07}"
    Local Const $IID_IDispatch = "{00020400-0000-0000-C000-000000000046}"

    __log("INIT COM", $bDebug, $sLogFile)
    DllCall("ole32.dll", "long", "CoInitialize", "ptr", 0)

    ;=========================================================
    ; CLSID / IID
    ;=========================================================
    Local $tCLSID = DllStructCreate("byte[16]")
    Local $pCLSID = DllStructGetPtr($tCLSID)
    Local $tIIDFactory = DllStructCreate("byte[16]")
    Local $tIIDDispatch = DllStructCreate("byte[16]")

    Local $aCLSID = DllCall("ole32.dll", "long", "CLSIDFromString", _
            "wstr", $CLSID_TX, _
            "ptr", $pCLSID)

    If @error Or $aCLSID[0] <> 0 Then
        __log("CLSIDFromString FAILED", $bDebug, $sLogFile)
        Return 0
    EndIf

    DllCall("ole32.dll", "long", "IIDFromString", _
        "wstr", $IID_IClassFactory2, _
        "ptr", DllStructGetPtr($tIIDFactory))

    DllCall("ole32.dll", "long", "IIDFromString", _
        "wstr", $IID_IDispatch, _
        "ptr", DllStructGetPtr($tIIDDispatch))

    ;=========================================================
    ; MODE 1 - SAFE IClassFactory2 (NO CRASH)
    ;=========================================================
    __log("MODE 1: CreateInstanceLic (SAFE)", $bDebug, $sLogFile)

    Local $aFactory = DllCall("ole32.dll", "long", "CoGetClassObject", _
            "ptr", $pCLSID, _
            "dword", $CLSCTX_INPROC_SERVER, _
            "ptr", 0, _
            "ptr", DllStructGetPtr($tIIDFactory), _
            "ptr*", 0)

    If @error Or $aFactory[0] <> 0 Then
        __log("MODE 1 FAIL: CoGetClassObject", $bDebug, $sLogFile)
    Else

        Local $pFactory = $aFactory[5]

        ; SAFE COM WRAP (NO VTABLE, NO DLLCALLADDRESS)
        Local $oFactory = ObjCreateInterface($pFactory, $IID_IClassFactory2)

        If IsObj($oFactory) Then

            Local $oObj = $oFactory.CreateInstanceLic(0, 0, $IID_IDispatch, $sLicenseKey)

            If IsObj($oObj) Then
                __log("MODE 1 SUCCESS", $bDebug, $sLogFile)
                Return $oObj
            EndIf
        EndIf

        __log("MODE 1 FAILED: CreateInstanceLic", $bDebug, $sLogFile)
    EndIf


    ;=========================================================
    ; MODE 2 - License Manager
    ;=========================================================
    __log("MODE 2: LicManager", $bDebug, $sLogFile)

    Local $oLic = ObjCreate("TIS.TX.LicManager.30")

    If IsObj($oLic) Then
        __log("LicManager OK", $bDebug, $sLogFile)
    Else
        __log("LicManager FAIL", $bDebug, $sLogFile)
    EndIf


    ;=========================================================
    ; MODE 3 - Direct ActiveX
    ;=========================================================
    __log("MODE 3: Direct Create", $bDebug, $sLogFile)

    Local $oTX = ObjCreate("TIS.TX.TextControl.30")

    If IsObj($oTX) Then
        __log("MODE 3 SUCCESS", $bDebug, $sLogFile)

        $oTX.LicenseKey = $sLicenseKey

        Return $oTX
    EndIf

    __log("ALL MODES FAILED", $bDebug, $sLogFile)

    Return 0

EndFunc   ;==>_TXTextControl_Create


;=========================================================
; LOGGER
;=========================================================
Func __log($msg, $bDebug, $sLogFile)
    If $bDebug Then ConsoleWrite("[TX] " & $msg & @CRLF)
    If $sLogFile <> "" Then FileWrite($sLogFile, "[TX] " & $msg & @CRLF)
EndFunc   ;==>__log

almost with success as the control initialize with this following Trial Version info:

 

But finally I get error in Exit code:

Quote

[TX] INIT COM
[TX] MODE 1: CreateInstanceLic (SAFE)
>Exit code: 3221225477    Time: 2.5025

Wondering how to fix this.
Any help would be appreciated.

Edited June 11 by mLipok

[Danyfirex]

@mLipok could you show documentation?

 

 

Saludos

 

[mLipok]

https://www.textcontrol.com/documentation/?param=index.htm&product=ocx

https://www.textcontrol.com/documentation/?param=o_techarticle_licensing.htm&product=ocx

 

[Danyfirex]

But I dont see any reference about how vb6 add the license.

 

Saludos

[mLipok]

9 hours ago, Danyfirex said:

But I dont see any reference about how vb6 add the license.

ha..
Here is the answer from tech support:

Quote

The only information we provide in terms of custom licensing apart from Visual Basic 6 for our ActiveX product, is listed in the documentation, which you already found.

https://www.textcontrol.com/documentation/?param=o_techarticle_licensing.htm&product=ocx

Unfortunately, there’s no other available documentation or guides available for PowerBasic or PureBasic, sorry.

 

[Danyfirex]

that support's reply is lazy as shit 😅😂

 

I'll will not be able to help you. sorry.

 

Saludos

[Danyfirex]

Do you have a valid license? try this. I'm able to make it work partially with CreateInstanceLic  but I dont have a valid license to check if it works correctly. 

expandcollapse popup

#AutoIt3Wrapper_UseX64=N
#include <MsgBoxConstants.au3>

_Example()

Func _Example()
    ;=========================================================
    ; TEST
    ;=========================================================
    Local $sKey = "LICENSE"
    Local $sLog = @ScriptDir & "\tx_debug.log"

    Local $oTX = _TXTextControl_Create($sKey, True, $sLog)

    If IsObj($oTX) Then
        MsgBox($MB_ICONINFORMATION, "TX Text Control", "OK - control initialized")
        ; SAFE ACCESS
        $oTX.Text = "Hello TX Text Control"
        GUICreate("Test TX Text", 640, 580, (@DesktopWidth - 640) / 2, (@DesktopHeight - 580) / 2)
        GUICtrlCreateObj($oTX, 10, 40, 600, 360)
        GUISetState(@SW_SHOW)     ;Show GUI
        $oTX.Text = "Hello TX Text Control"
;~      $oTX.AboutBox()
        ; Loop until the user exits.
        While 1
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = -3
                    ExitLoop
            EndSelect
        WEnd

        GUIDelete()
    Else
        MsgBox($MB_ICONERROR, "TX Text Control", "Initialization error")
    EndIf

EndFunc   ;==>_Example


;=========================================================
; MAIN FUNCTION
;=========================================================
Func _TXTextControl_Create($sLicenseKey, $bDebug = True, $sLogFile = "")

    Local Const $CLSCTX_INPROC_SERVER = 1

    Local Const $CLSID_TX = "{4424D201-9EB2-11F0-BB49-7085C299DB80}"
    Local Const $IID_IClassFactory2 = "{B196B28F-BAB4-101A-B69C-00AA00341D07}"
    Local Const $IID_IDispatch = "{00020400-0000-0000-C000-000000000046}"
    Global Const $tagIClassFactory = "CreateInstance hresult(ptr;clsid;ptr*);" & _
            "LockServer hresult(bool);"
    Global Const $tagIClassFactory2 = $tagIClassFactory & "GetLicInfo hresult(struct*);RequestLicKey hresult(dword;bstr*);CreateInstanceLic hresult(ptr;ptr;clsid;bstr;object*);"



    __log("INIT COM", $bDebug, $sLogFile)
    DllCall("ole32.dll", "long", "CoInitialize", "ptr", 0)

    ;=========================================================
    ; CLSID / IID
    ;=========================================================
    Local $tCLSID = DllStructCreate("byte[16]")
    Local $pCLSID = DllStructGetPtr($tCLSID)
    Local $tIIDFactory = DllStructCreate("byte[16]")
    Local $tIIDDispatch = DllStructCreate("byte[16]")

    Local $aCLSID = DllCall("ole32.dll", "long", "CLSIDFromString", _
            "wstr", $CLSID_TX, _
            "ptr", $pCLSID)

    If @error Or $aCLSID[0] <> 0 Then
        __log("CLSIDFromString FAILED", $bDebug, $sLogFile)
        Return 0
    EndIf

    DllCall("ole32.dll", "long", "IIDFromString", _
            "wstr", $IID_IClassFactory2, _
            "ptr", DllStructGetPtr($tIIDFactory))

    DllCall("ole32.dll", "long", "IIDFromString", _
            "wstr", $IID_IDispatch, _
            "ptr", DllStructGetPtr($tIIDDispatch))

    ;=========================================================
    ; MODE 1 - SAFE IClassFactory2 (NO CRASH)
    ;=========================================================
    __log("MODE 1: CreateInstanceLic (SAFE)", $bDebug, $sLogFile)

    Local $aFactory = DllCall("ole32.dll", "long", "CoGetClassObject", _
            "ptr", $pCLSID, _
            "dword", $CLSCTX_INPROC_SERVER, _
            "ptr", 0, _
            "ptr", DllStructGetPtr($tIIDFactory), _
            "ptr*", 0)

    If @error Or $aFactory[0] <> 0 Then
        __log("MODE 1 FAIL: CoGetClassObject", $bDebug, $sLogFile)
    Else

        Local $pFactory = $aFactory[5]

        ; SAFE COM WRAP (NO VTABLE, NO DLLCALLADDRESS)
        Local $oFactory = ObjCreateInterface($pFactory, $IID_IClassFactory2, $tagIClassFactory2)

        If IsObj($oFactory) Then
            Local $oObj = Null
            Local $hResult = $oFactory.CreateInstanceLic(0, 0, $IID_IDispatch, $sLicenseKey, $oObj)

            If IsObj($oObj) Then
                __log("MODE 1 SUCCESS", $bDebug, $sLogFile)
                Return $oObj
            EndIf
        EndIf

        __log("MODE 1 FAILED: CreateInstanceLic", $bDebug, $sLogFile)
    EndIf


    ;=========================================================
    ; MODE 2 - License Manager
    ;=========================================================
    __log("MODE 2: LicManager", $bDebug, $sLogFile)

    Local $oLic = ObjCreate("TIS.TX.LicManager.34")

    If IsObj($oLic) Then
        __log("LicManager OK", $bDebug, $sLogFile)
    Else
        __log("LicManager FAIL", $bDebug, $sLogFile)
    EndIf


    ;=========================================================
    ; MODE 3 - Direct ActiveX
    ;=========================================================
    __log("MODE 3: Direct Create", $bDebug, $sLogFile)

    Local $oTX = ObjCreate("TIS.TX.TextControl.34")

    If IsObj($oTX) Then
        __log("MODE 3 SUCCESS", $bDebug, $sLogFile)

        $oTX.LicenseKey = $sLicenseKey

        Return $oTX
    EndIf

    __log("ALL MODES FAILED", $bDebug, $sLogFile)

    Return 0

EndFunc   ;==>_TXTextControl_Create


;=========================================================
; LOGGER
;=========================================================
Func __log($msg, $bDebug, $sLogFile)
    If $bDebug Then ConsoleWrite("[TX] " & $msg & @CRLF)
    If $sLogFile <> "" Then FileWrite($sLogFile, "[TX] " & $msg & @CRLF)
EndFunc   ;==>__log

 

 

Saludos

[mLipok]

12 hours ago, Danyfirex said:

Do you have a valid license?

As so far no.

I will write to them and ask them to check your's code, with my little mod:

expandcollapse popup

;~ https://www.autoitscript.com/forum/topic/169256-txtextcontrol-problem-with-objcreate-class-not-registered/#findComment-1553232

#AutoIt3Wrapper_UseX64=N
#include <MsgBoxConstants.au3>

_Example()

Func _Example()
    ;=========================================================
    ; TEST
    ;=========================================================
    Local $sKey = "LICENSE"
    Local $sLog = @ScriptDir & "\tx_debug.log"

    Local $oTX = _TXTextControl_Create($sKey, True, $sLog)

    If IsObj($oTX) Then
        MsgBox($MB_ICONINFORMATION, "TX Text Control", "OK - control initialized")
        ; SAFE ACCESS
        $oTX.Text = "Hello TX Text Control"
        GUICreate("Test TX Text", 640, 580, (@DesktopWidth - 640) / 2, (@DesktopHeight - 580) / 2)
        GUICtrlCreateObj($oTX, 10, 40, 600, 360)
        GUISetState(@SW_SHOW)     ;Show GUI
        $oTX.Text = "Hello TX Text Control"
;~      $oTX.AboutBox()
        ; Loop until the user exits.
        Local $iMsg
        While 1
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = -3
                    ExitLoop
            EndSelect
        WEnd

        GUIDelete()
    Else
        MsgBox($MB_ICONERROR, "TX Text Control", "Initialization error")
    EndIf

EndFunc   ;==>_Example


;=========================================================
; MAIN FUNCTION
;=========================================================
Func _TXTextControl_Create($sLicenseKey, $bDebug = True, $sLogFile = "")

    Local Const $CLSCTX_INPROC_SERVER = 1

    Local Const $CLSID_TX = "{4424D201-9EB2-11F0-BB49-7085C299DB80}"
    Local Const $IID_IClassFactory2 = "{B196B28F-BAB4-101A-B69C-00AA00341D07}"
    Local Const $IID_IDispatch = "{00020400-0000-0000-C000-000000000046}"
    Local Const $tagIClassFactory = "CreateInstance hresult(ptr;clsid;ptr*);" & _
            "LockServer hresult(bool);"
    Local Const $tagIClassFactory2 = $tagIClassFactory & "GetLicInfo hresult(struct*);RequestLicKey hresult(dword;bstr*);CreateInstanceLic hresult(ptr;ptr;clsid;bstr;object*);"

    __log(@ScriptLineNumber, "INIT COM", $bDebug, $sLogFile)
    DllCall("ole32.dll", "long", "CoInitialize", "ptr", 0)

    ;=========================================================
    ; CLSID / IID
    ;=========================================================
    Local $tCLSID = DllStructCreate("byte[16]")
    Local $pCLSID = DllStructGetPtr($tCLSID)
    Local $tIIDFactory = DllStructCreate("byte[16]")
    Local $tIIDDispatch = DllStructCreate("byte[16]")

    Local $aCLSID = DllCall("ole32.dll", "long", "CLSIDFromString", _
            "wstr", $CLSID_TX, _
            "ptr", $pCLSID)

    If @error Or $aCLSID[0] <> 0 Then
        __log(@ScriptLineNumber, "CLSIDFromString FAILED", $bDebug, $sLogFile)
        Return 0
    EndIf

    DllCall("ole32.dll", "long", "IIDFromString", _
            "wstr", $IID_IClassFactory2, _
            "ptr", DllStructGetPtr($tIIDFactory))

    DllCall("ole32.dll", "long", "IIDFromString", _
            "wstr", $IID_IDispatch, _
            "ptr", DllStructGetPtr($tIIDDispatch))

    ;=========================================================
    ; MODE 1 - SAFE IClassFactory2 (NO CRASH)
    ;=========================================================
    __log(@ScriptLineNumber, "MODE 1: CreateInstanceLic (SAFE)", $bDebug, $sLogFile)

    Local $aFactory = DllCall("ole32.dll", "long", "CoGetClassObject", _
            "ptr", $pCLSID, _
            "dword", $CLSCTX_INPROC_SERVER, _
            "ptr", 0, _
            "ptr", DllStructGetPtr($tIIDFactory), _
            "ptr*", 0)

    If @error Or $aFactory[0] <> 0 Then
        __log(@ScriptLineNumber, "MODE 1 FAIL: CoGetClassObject", $bDebug, $sLogFile)
    Else

        Local $pFactory = $aFactory[5]

        ; SAFE COM WRAP (NO VTABLE, NO DLLCALLADDRESS)
        Local $oFactory = ObjCreateInterface($pFactory, $IID_IClassFactory2, $tagIClassFactory2)

        If IsObj($oFactory) Then
            Local $oObj = Null
            Local $hResult = $oFactory.CreateInstanceLic(0, 0, $IID_IDispatch, $sLicenseKey, $oObj)
            #forceref $hResult

            If IsObj($oObj) Then
                __log(@ScriptLineNumber, "MODE 1 SUCCESS", $bDebug, $sLogFile)
                Return $oObj
            EndIf
        EndIf

        __log(@ScriptLineNumber, "MODE 1 FAILED: CreateInstanceLic", $bDebug, $sLogFile)
    EndIf

    ;=========================================================
    ; MODE 2 - License Manager
    ;=========================================================
    __log(@ScriptLineNumber, "MODE 2: LicManager", $bDebug, $sLogFile)

    Local $oLic = ObjCreate("TIS.TX.LicManager.34")

    If IsObj($oLic) Then
        __log(@ScriptLineNumber, "LicManager OK", $bDebug, $sLogFile)
    Else
        __log(@ScriptLineNumber, "LicManager FAIL", $bDebug, $sLogFile)
    EndIf

    ;=========================================================
    ; MODE 3 - Direct ActiveX
    ;=========================================================
    __log(@ScriptLineNumber, "MODE 3: Direct Create", $bDebug, $sLogFile)

    Local $oTX = ObjCreate("TIS.TX.TextControl.34")

    If IsObj($oTX) Then
        __log(@ScriptLineNumber, "MODE 3 SUCCESS", $bDebug, $sLogFile)

        $oTX.LicenseKey = $sLicenseKey

        Return $oTX
    EndIf

    __log(@ScriptLineNumber, "ALL MODES FAILED", $bDebug, $sLogFile)

    Return 0

EndFunc   ;==>_TXTextControl_Create

;=========================================================
; LOGGER
;=========================================================
Func __log($_ScriptLineNumber, $msg, $bDebug, $sLogFile)
    If $bDebug Then ConsoleWrite("[TX] " & $_ScriptLineNumber & " : " & $msg & @CRLF)
    If $sLogFile <> "" Then FileWrite($sLogFile, "[TX] " & $msg & @CRLF)
EndFunc   ;==>__log