Help pulling data out of XML file

[ChrisBair]

I'm trying to read some data from an XML file (order numbers, tracking numbers and ship date) and can't seem to get _XMLDomWrapper_.au3 to work. 

Ultimately my goal is to use the data to navigate to a web page (baseURL+order#) change a value, click a button, enter the tracking number and date and then click another button (repeated however many orders were in the XML file). I have a pretty good foundation with automating IE to do what I need (would prefer chrome but it seems the UDF for that died when google started enforcing chrome app origination) but I can't seem to get the XML down. Here is a seriously abbreviated version of the XML file with all the non-relevant nodes removed (and the tracking numbers are fake)

<?xml version="1.0" encoding="utf-8"?>
<Print xmlns="http://stamps.com/xml/namespace/2009/8/Client/BatchProcessingV1">
  <Item>
    <OrderID>5235</OrderID>
    <TrackingNumber>910551169922324005344</TrackingNumber>
    <ActualMailingDate>2015-08-11</ActualMailingDate>
  </Item>
  <Item>
    <OrderID>5236</OrderID>
    <TrackingNumber>94055118992354208016</TrackingNumber>
    <ActualMailingDate>2015-08-11</ActualMailingDate>
  </Item>
  <Item>
    <OrderID>5237</OrderID>
    <TrackingNumber>94055158992354208016</TrackingNumber>
    <ActualMailingDate>2015-08-11</ActualMailingDate>
  </Item>
</Print>

 

[guinness]

It's polite to post what you have tried instead of us second guessing how you misunderstood the UDF.

[ChrisBair]

Basing off other examples I found on this forum, the best I came up with was 

$sXmlFile = "c:\xmlfile.xml"
$oOXml = _XMLFileOpen ($sXmlFile)
$cnt = _XMLGetNodeCount ('//Print/Item/*', "")

Dim $aAttrName[1], $aAttrValue[1]

For $i = 0 To $cnt - 1
    $ret = _XMLGetAllAttribIndex ("//Print/Item/OrderID/*", $aAttrName, $aAttrValue, "", $i)
    If IsArray($aAttrName) Then
        _ArrayDisplay($aAttrName, "Attrib Names")
        _ArrayDisplay($aAttrValue, "Attrib Values")
    Else
        MsgBox(0, "Error", "No items found.")
        Exit
    EndIf
Next

doesn't return anything.

 

Earlier I tried

$xmlarray = _XML_ElementsToArry("c:\xmlfile.xml")

Func _XML_ElementsToArry ( $sXMLFilePath )
    Local $i = 1
    Local $aRetAry[1]
    $aRetAry[0] = 0
    Local $xmldoc = ObjCreate( 'Microsoft.XMLDOM' )
    If Not IsObj($xmldoc) Then
        SetError ( 1 )
        Return -1
    EndIf
    $xmldoc.async = False
    $xmldoc.load ( $sXMLFilePath )
    For $x In $xmldoc.documentElement.childNodes
        $aRetAry[0] = $aRetAry[0] + 1
        ReDim $aRetAry[$aRetAry[0]+1]
        $aRetAry[$i] = $x.NodeName
        $i = $i + 1
    Next
    Return $aRetAry
EndFunc


_ArrayDisplay($xmlarray, "2D display")

but that just gives me the first level node names ("Item" x15)

[mLipok]

This is because you have:

<Print xmlns="http://stamps.com/xml/namespace/2009/8/Client/BatchProcessingV1">

instead:

<Print>

 

Try this 

Local $cnt
;~ $cnt = _XMLGetNodeCount($oXml, '//Print/Item', "")
$cnt = _XMLGetNodeCount($oXml, "//*[name()='Item']")
....
$ret = _XMLGetAllAttribIndex($oXml, "//*[name()='Item']/OrderID/*", $aAttrName, $aAttrValue, "", $i)

 

 

Edited August 20, 2015 by mLipok

[jdelaney]

Here you go:

; just demonstrating through a temp file
#include <File.au3>
$sTempFile = "Temp.xml"
$string = "<?xml version=""1.0"" encoding=""utf-8""?>" & @CRLF & _
"<Print xmlns=""http://stamps.com/xml/namespace/2009/8/Client/BatchProcessingV1"">" & @CRLF & _
  "<Item>" & @CRLF & _
    "<OrderID>5235</OrderID>" & @CRLF & _
    "<TrackingNumber>910551169922324005344</TrackingNumber>" & @CRLF & _
    "<ActualMailingDate>2015-08-11</ActualMailingDate>" & @CRLF & _
  "</Item>" & @CRLF & _
  "<Item>" & @CRLF & _
    "<OrderID>5236</OrderID>" & @CRLF & _
    "<TrackingNumber>94055118992354208016</TrackingNumber>" & @CRLF & _
    "<ActualMailingDate>2015-08-11</ActualMailingDate>" & @CRLF & _
  "</Item>" & @CRLF & _
  "<Item>" & @CRLF & _
    "<OrderID>5237</OrderID>" & @CRLF & _
    "<TrackingNumber>94055158992354208016</TrackingNumber>" & @CRLF & _
    "<ActualMailingDate>2015-08-11</ActualMailingDate>" & @CRLF & _
  "</Item>" & @CRLF & _
"</Print>"
_FileCreate($sTempFile)
FileWrite($sTempFile,$string)

; real stuff here
Local $oXML = ObjCreate("Microsoft.XMLDOM")
$oXML.load($sTempFile)

$oItems = $oXML.SelectNodes("//Print/Item")         ; or //Item
For $oItem In $oItems

    $oOrderID = $oItem.SelectSingleNode("./OrderID")
    $oTrackingNum = $oItem.SelectSingleNode("./TrackingNumber")
    $oActualDate = $oItem.SelectSingleNode("./ActualMailingDate")
    ConsoleWrite("$oOrderID=[" & $oOrderID.text & "]; $oTrackingNum=[" & $oTrackingNum.text & "]; $oActualDate=[" & $oActualDate.text & "]" & @CRLF)
Next

Output:

$oOrderID=[5235]; $oTrackingNum=[910551169922324005344]; $oActualDate=[2015-08-11]
$oOrderID=[5236]; $oTrackingNum=[94055118992354208016]; $oActualDate=[2015-08-11]
$oOrderID=[5237]; $oTrackingNum=[94055158992354208016]; $oActualDate=[2015-08-11]

[mLipok]

Why it works with:

Local $oXML = ObjCreate("Microsoft.XMLDOM")
; or
Local $oXML = ObjCreate("Msxml2.DOMDocument.3.0")

and not working with:

Local $oXML = ObjCreate("Msxml2.DOMDocument.4.0")
; or
Local $oXML = ObjCreate("Msxml2.DOMDocument.6.0")

 

EDIT:

https://msdn.microsoft.com/en-us/library/ms754523(v=vs.85).aspx

Note

Previously, in MSXML 3.0 and earlier versions, the selection object created by calling the selectNodes method would gradually calculate the node-set. If the DOM tree was modified, while the selectNodes call was still actively iterating its contents, the behavior could potentially change the nodes that were selected or returned. In MSXML 6., the node-set result is fully calculated at the time of selection. This ensures that the iteration is simple and predictable. In rare instances, this change might impact legacy code written to accommodate previous behavior.

 

Edited August 15, 2015 by mLipok

[pseakins]

Here you go: 

; just demonstrating through a temp file

Like the OP I'm trying to read data from an XML file and your post really helped me. However I am still having trouble accessing a text field. I have modified the code to include typical but fictitious examples of the text fields in the XML. I have hard coded ItemSize and ItemColour strings in the extraction code and it would help greatly if you could show me how to adjust the first two lines in the loop such that the actual text fields are extracted from the sample.

expandcollapse popup

; just demonstrating through a temp file
#include <File.au3>
$sTempFile = "Temp.xml"
$string = "<?xml version=""1.0"" encoding=""utf-8""?>" & @CRLF & _
"<Print xmlns=""http://stamps.com/xml/namespace/2009/8/Client/BatchProcessingV1"">" & @CRLF & _
  "<Item ItemSize=""XL"" ItemColour=""White"">" & @CRLF & _
    "<OrderID>5235</OrderID>" & @CRLF & _
    "<TrackingNumber>910551169922324005344</TrackingNumber>" & @CRLF & _
    "<ActualMailingDate>2015-08-11</ActualMailingDate>" & @CRLF & _
  "</Item>" & @CRLF & _
  "<Item ItemSize=""SM"" ItemColour=""Green"">" & @CRLF & _
    "<OrderID>5236</OrderID>" & @CRLF & _
    "<TrackingNumber>94055118992354208016</TrackingNumber>" & @CRLF & _
    "<ActualMailingDate>2015-08-11</ActualMailingDate>" & @CRLF & _
  "</Item>" & @CRLF & _
  "<Item ItemSize=""XL"" ItemColour=""Blue"">" & @CRLF & _
    "<OrderID>5237</OrderID>" & @CRLF & _
    "<TrackingNumber>94055158992354208016</TrackingNumber>" & @CRLF & _
    "<ActualMailingDate>2015-08-11</ActualMailingDate>" & @CRLF & _
  "</Item>" & @CRLF & _
"</Print>"
_FileCreate($sTempFile)
FileWrite($sTempFile,$string)

; real stuff here
Local $oXML = ObjCreate("Microsoft.XMLDOM")
$oXML.load($sTempFile)

$oItems = $oXML.SelectNodes("//Print/Item")         ; or //Item
For $oItem In $oItems
    $sItemSize = "XL" ;$sItemSize = $oItem.UnknownMethod("ItemSize")
    $sItemColour = "Blue" ;$sItemColour = $oItem.UnknownMethod("ItemColour")
    $oOrderID = $oItem.SelectSingleNode("./OrderID")
    $oTrackingNum = $oItem.SelectSingleNode("./TrackingNumber")
    $oActualDate = $oItem.SelectSingleNode("./ActualMailingDate")
    ;ConsoleWrite("$oOrderID=[" & $oOrderID.text & "]; $oTrackingNum=[" & $oTrackingNum.text & "]; $oActualDate=[" & $oActualDate.text & "]" & @CRLF)
    ConsoleWrite("ItemSize=[" & $sItemSize & "]; ItemColour=[" & $sItemColour & "]; $oOrderID=[" & $oOrderID.text & "]; $oTrackingNum=[" & $oTrackingNum.text & "]; $oActualDate=[" & $oActualDate.text & "]" & @CRLF)
Next

 

[jdelaney]

Local $oXML = ObjCreate("Microsoft.XMLDOM")
$oXML.load($sTempFile)
ConsoleWrite($oXml.xml)
$oItems = $oXML.SelectNodes("//Print/Item")         ; or //Item
For $oItem In $oItems

    $oOrderID = $oItem.SelectSingleNode("./OrderID")
    $sItemSize = $oItem.getattribute("ItemSize")
    $sItemColour = $oItem.getattribute("ItemColour")
    $oTrackingNum = $oItem.SelectSingleNode("./TrackingNumber")
    $oActualDate = $oItem.SelectSingleNode("./ActualMailingDate")
    ;ConsoleWrite("$oOrderID=[" & $oOrderID.text & "]; $oTrackingNum=[" & $oTrackingNum.text & "]; $oActualDate=[" & $oActualDate.text & "]" & @CRLF)
    ConsoleWrite("ItemSize=[" & $sItemSize & "]; ItemColour=[" & $sItemColour & "]; $oOrderID=[" & $oOrderID.text & "]; $oTrackingNum=[" & $oTrackingNum.text & "]; $oActualDate=[" & $oActualDate.text & "]" & @CRLF)
Next

 

[pseakins]

Wow what a champion! I've been wrestling with this for weeks, I go to lunch and when I get back you've given me the complete answer. Funnily enough I have https://msdn.microsoft.com/en-us/library/ms761380(v=vs.85).aspx  MSDN getAttribute Method already open in one of my browser tabs. The answer was right in front of me and I couldn't see it.

I really appreciate your rapid and helpful responses. Thanks heaps.

[pseakins]

After jdelaney put me on the right path, I tried methods I had seen while researching and found that it is possible to get the same result as post #5 with a For-Next loop. Individual elements\attributes of the required node can be directly addressed. The OP may be interested in looking at this modified loop giving the same output.

ConsoleWrite('$oItems.length = [' & $oItems.length & ']' & @CRLF)
For  $i = 0 To $oItems.length - 1
  $sOrderID = $oItems($i).SelectSingleNode("OrderID").text
  $sTrackingNum = $oItems($i).SelectSingleNode("TrackingNumber").text
  $sActualDate = $oItems($i).SelectSingleNode("ActualMailingDate").text
  ConsoleWrite("$sOrderID=[" & $sOrderID & "]; $sTrackingNum=[" & $sTrackingNum & "]; $sActualDate=[" & $sActualDate & "]" & @CRLF)
Next