Table/listview with word wrap

[eatfishdk]

Hi

I'm trying to make a gui and need to have a table/listview (dont know how else to describe it), but I need it to have word wrap and size (of row height) set automatic (all the text should be visible at all times).

I've made this in excel to show how it could look:

All the text (in both colums) come from data from so all the text can change, and there need to be a way to add more rows..
I've tried the "normal" autoit ways and tried several different udf's from here. But the ones i've found need to have size set, single line only etc.

The text that needs to be shown could be any length and could contain line-endings (CR/LF) and so on..

 

Does anybody know of a way to do it?

The simpler the better..

 

Regards

Martin

 

[mLipok]

Take a look at @LarsJ stuff.

[eatfishdk]

@mLipok yes, that was one of the first ones I've tried.. But I can't get it to set the row height to fit the string. The whole ui yes but just the row no..

I've might overlooked something but can't get it to work..

 

 

[Nine]

Not exactly what you want but close enough.  AFAIK, you cannot set variable heights on LV.  I have seen very complicated ways, but not sure I could translate it in autoIt.

But with ListBox, it is pretty simple (based on a previous thread) :

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListBox.au3>

; based on https://www.autoitscript.com/forum/topic/193949-multi-line-listview-items-with-rows-of-different-heights/

; DRAWITEMSTRUCT
Global Const $tagDRAWITEMSTRUCT = "uint CtlType;uint CtlID;uint itemID;uint itemAction;uint itemState;hwnd hwndItem;handle hDC;dword rcItem[4];ptr itemData"

; CtlType
Global Const $ODT_LISTBOX = 2

; itemAction
Global Const $ODA_DRAWENTIRE = 0x1
Global Const $ODA_SELECT = 0x2
Global Const $ODA_FOCUS = 0x4

; itemState
Global Const $ODS_SELECTED = 0x1

Global Const $ROW_HEIGHT = 16, $MARGIN = 4
Global $aRows = [ _
    [2, "Title:", "This is a long title for making sure we use two lines"], _
    [4, "Description:", "This is a very long description for making sure we use many lines.  It can be estimated with a simple algorithm, but I decided to set it manually, since it is not the purpose of the thread."]]

Example()

Func Example()
  GUICreate("Ownerdrawn Listbox", 300, 300)
  Local $idListBox = GUICtrlCreateList("", 4, 4, 292, 292, $WS_VSCROLL + $LBS_OWNERDRAWVARIABLE)

  ; Set row height
  For $i = 0 To UBound($aRows) - 1
    _GUICtrlListBox_AddString($idListBox, $aRows[$i][1])
    _GUICtrlListBox_SetItemHeight($idListBox, $aRows[$i][0] * $ROW_HEIGHT + $MARGIN * 2, $i)
  Next

  GUIRegisterMsg($WM_DRAWITEM, WM_DRAWITEM)
  GUISetState(@SW_SHOW)

  Do
  Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

Func WM_DRAWITEM($hWnd, $iMsg, $wParam, $lParam)
  Local $tDRAWITEMSTRUCT = DllStructCreate($tagDRAWITEMSTRUCT, $lParam)
  Local $CtlType = DllStructGetData($tDRAWITEMSTRUCT, "CtlType")
  If $CtlType <> $ODT_LISTBOX Then Return $GUI_RUNDEFMSG

  Local $itemID = DllStructGetData($tDRAWITEMSTRUCT, "itemID")
  Local $itemAction = DllStructGetData($tDRAWITEMSTRUCT, "itemAction")
  ;Local $itemState = DllStructGetData( $tDRAWITEMSTRUCT, "itemState" )
  Local $hDC = DllStructGetData($tDRAWITEMSTRUCT, "hDC")

  Switch $itemAction
    Case $ODA_DRAWENTIRE, $ODA_SELECT
      ; Item rectangle
      Local $tRECT = DllStructCreate($tagRECT, DllStructGetPtr($tDRAWITEMSTRUCT, "rcItem"))
      Local $hBrush = _WinAPI_CreateSolidBrush(0x97EEEA)
      _WinAPI_FillRect($hDC, $tRECT, $hBrush)
      _WinAPI_SetBkMode($hDC, $TRANSPARENT)

      ; Text color - no need if black
      ;_WinAPI_SetTextColor($hDC, 0 )

      ; Item text 1
      DllStructSetData($tRECT, "Left", DllStructGetData($tRECT, "Left") + $MARGIN)
      Local $sItemText = $aRows[$itemID][1]
      DllStructSetData($tRECT, "Top", DllStructGetData($tRECT, "Top") + $MARGIN)
      _WinAPI_DrawText($hDC, $sItemText, $tRECT, $DT_LEFT)

      ; Item text 2
      If $aRows[$itemID][2] Then
        $sItemText = $aRows[$itemID][2]
        DllStructSetData($tRECT, "Left", 80)
        DllStructSetData($tRECT, "Bottom", DllStructGetData($tRECT, "Top") + ($aRows[$itemID][0] * $ROW_HEIGHT) + $MARGIN)
        _WinAPI_DrawText($hDC, $sItemText, $tRECT, $DT_WORDBREAK)
      EndIf

      _WinAPI_DeleteObject($hBrush)
  EndSwitch

  Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_DRAWITEM