Bug with IniReadSectionNames if file is coded with UTF-8-BOM

[IronFine]

I have an ini-file that is formatted with UTF-8-BOM. If the file does not start with a linebreak, IniReadSectionNames does not retrieve the first section.
 

Local $sPathA, $sPathB, $sPathC, $sPathD, $hFile

; File A - UTF-8-BOM - No Leading LineBreak
$sPathA = @DesktopDir & "\File_UTF-8-BOM_v1.ini"
$hFile = FileOpen($sPathA, 2 + 8 + 128)
FileWrite($hFile, "[SectionA]" & @CRLF & "Key=Value")
FileClose($hFile)

; File B - UTF-8-BOM - Leading LineBreak
$sPathB = @DesktopDir & "\File_UTF-8-BOM_v2.ini"
$hFile = FileOpen($sPathB, 2 + 8 + 128)
FileWrite($hFile, @CRLF & "[SectionB]" & @CRLF & "Key=Value")
FileClose($hFile)

; File C - UTF-8 - No Leading LineBreak
$sPathC = @DesktopDir & "\File_UTF-8_v1.ini"
$hFile = FileOpen($sPathC, 2 + 8 + 256)
FileWrite($hFile, "[SectionA]" & @CRLF & "Key=Value")
FileClose($hFile)

; File D - UTF-8 - Leading LineBreak
$sPathD = @DesktopDir & "\File_UTF-8_v2.ini"
$hFile = FileOpen($sPathD, 2 + 8 + 256)
FileWrite($hFile, @CRLF & "[SectionB]" & @CRLF & "Key=Value")
FileClose($hFile)

Local $aSectionA = IniReadSectionNames($sPathA)
Local $aSectionB = IniReadSectionNames($sPathB)
Local $aSectionC = IniReadSectionNames($sPathC)
Local $aSectionD = IniReadSectionNames($sPathD)
ConsoleWrite("$aSectionA" & @TAB & UBound($aSectionA) & @CRLF)
ConsoleWrite("$aSectionB" & @TAB & UBound($aSectionB) & @CRLF)
ConsoleWrite("$aSectionC" & @TAB & UBound($aSectionC) & @CRLF)
ConsoleWrite("$aSectionD" & @TAB & UBound($aSectionD) & @CRLF)
Exit

Am I doing something wrong?

[Nine]

41 minutes ago, IronFine said:

Am I doing something wrong?

Nope.  Files are created correctly with right signature.
Seems to me you find yourself a bug 

ps. write a ticket in bug tracker.

Edited Wednesday at 04:42 PM by Nine

[UEZ]

It seems to be a problem with GetPrivateProfileStringW which I suppose is internally used. Obviously ANSI and UTF-16 LE with BOM only are supported by this WinAPI call.

expandcollapse popup

#include <Array.au3>
Local $sPathA, $sPathB, $sPathC, $sPathD, $hFile

; File A - UTF-8-BOM - No Leading LineBreak
$sPathA = "C:\Temp\File_UTF-8-BOM_v1.ini"
$hFile = FileOpen($sPathA, 2 + 8 + 128)
FileWrite($hFile, "[SectionA]" & @CRLF & "Key=Value")
FileClose($hFile)

; File B - UTF-8-BOM - Leading LineBreak
$sPathB = "C:\Temp\File_UTF-8-BOM_v2.ini"
$hFile = FileOpen($sPathB, 2 + 8 + 128)
FileWrite($hFile, @CRLF & "[SectionB]" & @CRLF & "Key=Value")
FileClose($hFile)

; File C - UTF-8 - No Leading LineBreak
$sPathC = "C:\Temp\File_UTF-8_v1.ini"
$hFile = FileOpen($sPathC, 2 + 8 + 256)
FileWrite($hFile, "[SectionA]" & @CRLF & "Key=Value")
FileClose($hFile)

; File D - UTF-8 - Leading LineBreak
$sPathD = "C:\Temp\File_UTF-8_v2.ini"
$hFile = FileOpen($sPathD, 2 + 8 + 256)
FileWrite($hFile, @CRLF & "[SectionB]" & @CRLF & "Key=Value")
FileClose($hFile)

Local $aSectionA = IniReadSectionNames($sPathA)
Local $aSectionB = IniReadSectionNames($sPathB)
Local $aSectionC = IniReadSectionNames($sPathC)
Local $aSectionD = IniReadSectionNames($sPathD)
ConsoleWrite("$aSectionA" & @TAB & UBound($aSectionA) & @CRLF)
ConsoleWrite("$aSectionB" & @TAB & UBound($aSectionB) & @CRLF)
ConsoleWrite("$aSectionC" & @TAB & UBound($aSectionC) & @CRLF)
ConsoleWrite("$aSectionD" & @TAB & UBound($aSectionD) & @CRLF)
ConsoleWrite("-------------------------------------------------" & @CRLF)

Global $a = _WinAPI_IniReadSection($sPathA)
ConsoleWrite("$aSectionA" & @TAB & UBound($a) & @CRLF)
Global $b = IniSectionRead($sPathA)
ConsoleWrite("$aSectionA" & @TAB & UBound($b) & @CRLF)

Exit

Func _WinAPI_IniReadSection($sIniFile)
    If Not FileExists($sIniFile) Then Return SetError(1, 0, 0)
    Local $iSize = 4096
    Local $tBuffer = DllStructCreate("wchar d[" & $iSize & "]")
    Local $aResult = DllCall("Kernel32.dll", "dword", "GetPrivateProfileStringW", "ptr", Null, "ptr", Null, "wstr", "default", "struct*", $tBuffer, "dword", $iSize, "wstr", $sIniFile)
    If @error Or Not IsArray($aResult) Then Return SetError(2, 0, 0)
    If $aResult[0] < 1 Then Return SetError(3, 0, 0)
    
    Local $aSections[0]
    Local $sTemp = ""

    For $i = 1 To $iSize
        Local $tChar = DllStructCreate("wchar t", DllStructGetPtr($tBuffer) + ($i - 1) * 2)
        Local $sChar = $tChar.t

        If $sChar = Chr(0) Then
            If $sTemp = "" Then ExitLoop
            ReDim $aSections[UBound($aSections) + 1]
            $aSections[UBound($aSections) - 1] = $sTemp
            $sTemp = ""
        Else
            $sTemp &= $sChar
        EndIf
    Next

    Return $aSections
EndFunc

Func IniSectionRead($sIniFile)
    Local $hFile = FileOpen($sIniFile, 256)
    Local $sContent = FileRead($hFile)
    FileClose($hFile)

    Local $aLines = StringSplit($sContent, @CRLF, 1)
    Local $aSections[1]

    For $i = 1 To $aLines[0]
        If StringRegExp($aLines[$i], "^\[.+\]$") Then
            ReDim $aSections[UBound($aSections) + 1]
            $aSections[UBound($aSections) - 1] = StringMid($aLines[$i], 2, StringLen($aLines[$i]) - 2)
        EndIf
    Next
    $aSections[0] = UBound($aSections) - 1
    Return $aSections
EndFunc

 

Edited Wednesday at 08:24 PM by UEZ

[mLipok]

 

[mLipok]

also

 

[argumentum]

..so, ...wassup doc. ( Bugs bunny )

So the solution is to work the INI files in UTF16 LE. Then again a RegEx could be done to fake the windows API. 🤔

@IronFine, an anonymous user opened a trac with your complain. Lucky you.

Ok, my job is done.

P.S.: oh, my job was to have a link to the trac#4086 as a note to self 🤓

[IronFine]

13 hours ago, argumentum said:

@IronFine, an anonymous user opened a trac with your complain. Lucky you.

 

[donnyh13]

22 hours ago, mLipok said:

 

Just a quick note that this can't be seen by non-MVP's.

Edited 20 hours ago by donnyh13

[argumentum]

5 minutes ago, donnyh13 said:

..a quick note that this can't be seen by non-MVP's.

> Staff Room > MVPs (Private Chat) > INI functions and ini file encoding
Yes, those MVPs are ....  
That chat didn't show anything. Well, it isn't fix so, yeah, nothing burger 😕

The trac entry should bring about a solution.   

[KaFu]

This is what I posted in MVP.

Helpfile for Iniwrite() says this:

If you want to use an ini file with Unicode encoding, first create an .ini file by using the FileOpen() function with the mode parameter set to a Unicode parameter.

Fyi, here's my standard approach to this:

If Not FileExists(@ScriptDir & "\_cache\") Then DirCreate(@ScriptDir & "\_cache\")
Func _Ini_Initialization($sFile, $sSectioName)
    If FileExists($sFile) Then Return
    Local $h_file = FileOpen($sFile, 2 + 32) ; 32 = Use Unicode UTF16 Little Endian reading and writing mode.
    FileWrite($h_file, $sSectioName & @CRLF) ; you need to write something
    FileClose($h_file)
EndFunc   ;==>_Ini_Initialization
_Ini_Initialization(@ScriptDir & "\_cache\_MPV-Enhancer.ini", "[Settings]")