MS Spell Checking API

[mLipok]

I saw here on the forum few different ways of checking spell:
Spell Checker (by iCode)
OpenOffice/LibreOffice Spell Checker (by GMK) 
v0.1.1 Scite4AutoIt SpellChecker using LibreOffice

even few topics about spell checking with Word.
Custom Spell Checker

But I start wondering how Notepad in Windows 11 finds out that some words are written incorrectly.

Then I ask ChatGPT about and he point me to Spell Checking API.

https://learn.microsoft.com/en-us/windows/win32/intl/about-the-spell-checker-api

So here is my question: Has anyone worked in AutoIt with MS Windows Spell Checking API ?



EDIT:
https://github.com/microsoft/Windows-classic-samples/blob/main/Samples/SpellCheckerClient/cpp/SampleSpellingClient.cpp

Edited Sunday at 10:03 PM by mLipok

[mLipok]

btw.
It is little funny (as I did many COM stuff in AutoIt) but ....

I'm not familiar with ObjCreateInterface() and for this reason at first I also asked ChatGPT for example:
 

expandcollapse popup

#include <MsgBoxConstants.au3>

; === COM interface GUIDs (global constants) ===
Global Const $CLSID_SpellCheckerFactory = "{7AB36653-1796-484B-BDFA-E74F1DB7C1DC}"
Global Const $IID_ISpellCheckerFactory = "{8E018A9D-2415-4677-BF08-794EA61F94BB}"
Global Const $IID_ISpellChecker = "{B6FD0B71-E2BC-4653-8D05-F197E0D3B83B}"

; === Interface definitions (global tags) ===
Global Const $TAG_ISpellCheckerFactory = _
        "CreateSpellChecker hresult(wstr;ptr*);" & _ ; Create spell checker for language
        "get_SupportedLanguages hresult(ptr*);"  ; Get supported languages

Global Const $TAG_ISpellChecker = _
        "Check hresult(wstr;ptr*);" & _ ; Check text for spelling errors
        "Suggest hresult(wstr;ptr*);" ; Get suggestions

; === Example entry point ===
_EXAMPLE()

Func _EXAMPLE()
    ; Create SpellCheckerFactory COM object
    Local $oFactory = ObjCreateInterface( _
            $CLSID_SpellCheckerFactory, _
            $IID_ISpellCheckerFactory, _
            $TAG_ISpellCheckerFactory)

    If @error Then
        MsgBox($MB_ICONERROR, "Error", "Failed to create SpellCheckerFactory")
        Return
    EndIf

    ; Create spell checker for Polish language
    Local $pSpellChecker = 0
    $oFactory.CreateSpellChecker("pl-PL", $pSpellChecker)

    If $pSpellChecker = 0 Then
        MsgBox($MB_ICONERROR, "Error", "Failed to create SpellChecker for pl-PL")
        Return
    EndIf

    ; Bind ISpellChecker interface
    Local $oSpell = ObjCreateInterface($pSpellChecker, $IID_ISpellChecker, $TAG_ISpellChecker)

    If @error Then
        MsgBox($MB_ICONERROR, "Error", "Failed to bind ISpellChecker interface")
        Return
    EndIf

    ; Word to test
    Local $sWord = "ksionszka"

    ; Perform spell check
    Local $pErrors = 0
    $oSpell.Check($sWord, $pErrors)

    ; NOTE: This is simplified logic!
    ; Proper implementation should enumerate IEnumSpellingError
    If $pErrors = 0 Then
        MsgBox($MB_ICONINFORMATION, "Result", "Word is correct: " & $sWord)
    Else
        MsgBox($MB_ICONWARNING, "Result", "Word is INCORRECT: " & $sWord)
    EndIf
EndFunc   ;==>_EXAMPLE

of course not works well.

[Nine]

If you can provide spellcheck.h file (not link), I will look at it.

[mLipok]

https://learn.microsoft.com/en-us/windows/win32/api/spellcheck/
https://github.com/gcc-mirror/gcc/blob/master/gcc/spellcheck.h
https://gist.github.com/mnovakovic/583648d14835de86bd45608c1c507826
https://github.com/microsoft/Windows-classic-samples/blob/main/Samples/SpellCheckerClient/cpp/commands.h

?

 

 

Edited Monday at 02:21 PM by mLipok

[ioa747]

spellcheck.h

Windows Kits\10\Include\10.0.26100.0\um

Edit:
it has to do with
'Methods/properties of the description tag string must be in correct Vtable order'

👉  related

Edited Monday at 02:02 PM by ioa747

[Nine]

24 minutes ago, ioa747 said:

Methods/properties of the description tag string must be in correct Vtable order

Exactly.  It is not the greatest idea of MS to list the methods in alphabetical order instead of the real order.

[mLipok]

2 hours ago, Nine said:

spellcheck.h file (not link),

I was in hope that my links were good.
Finally I found this file on my disc as I had this file:
c:\Program Files (x86)\Windows Kits\10\Include\10.0.26100.0\um\spellcheck.h

but @ioa747 was faster than me.

[Nine]

That seems to work correctly (at least in french)  :

expandcollapse popup

; From Nine

Opt("MustDeclareVars", True)

#include <Constants.au3>

Global Const $CLSID_SpellCheckerFactory = "{7AB36653-1796-484B-BDFA-E74F1DB7C1DC}"
Global Const $IID_ISpellCheckerFactory = "{8E018A9D-2415-4677-BF08-794EA61F94BB}"
Global Const $tag_ISpellCheckerFactory = _
    "get_SupportedLanguages hresult(ptr*);" & _
    "IsSupported hresult(wstr;bool*);" & _
    "CreateSpellChecker hresult(wstr;ptr*);"

Global Const $IID_ISpellChecker = "{B6FD0B71-E2BC-4653-8D05-F197E412770B}"
Global Const $tag_ISpellChecker = _
    "get_LanguageTag hresult(wstr*);" & _
    "Check hresult(wstr;ptr*);" & _
    "Suggest hresult(wstr;ptr*);" & _
    "Add hresult(wstr);" & _
    "Ignore hresult(wstr);"

Global Const $IID_IEnumSpellingError = "{803E3BD4-2828-4410-8290-418D1D73C762}"
Global Const $tag_IEnumSpellingError = _
    "Next hresult(ptr*);"

Example()

Func Example()
  Local $oFactory = ObjCreateInterface($CLSID_SpellCheckerFactory, $IID_ISpellCheckerFactory, $tag_ISpellCheckerFactory)
  If Not IsObj($oFactory) Then Exit ConsoleWrite("Err : oFactory" & @CRLF)
  Local $pSpellChecker
  $oFactory.CreateSpellChecker("fr-FR", $pSpellChecker)
  Local $oSpell = ObjCreateInterface($pSpellChecker, $IID_ISpellChecker, $tag_ISpellChecker)
  If Not IsObj($oSpell) Then Exit ConsoleWrite("Err : oSpell" & @CRLF)

  Local $aWord = ["Test", "Entêté", "Pasd'allure"]
  Local $pErrors, $oErrors, $iHresult
  For $sWord In $aWord
    $oSpell.Check($sWord, $pErrors)
    $oErrors = ObjCreateInterface($pErrors, $IID_IEnumSpellingError, $tag_IEnumSpellingError)
    If Not IsObj($oErrors) Then Exit ConsoleWrite("oErrors" & @CRLF)
    $iHresult = $oErrors.Next($pErrors)
    MsgBox($MB_OK, $iHresult ? "Correct" : "Error", $sWord)
  Next
EndFunc   ;==>Example

I didn't list all methods of ISpellChecker.  But I am tempted to explore this interface as it looks quite robust and promising.

Edited Monday at 05:55 PM by Nine

[mLipok]

Small refactoring:

expandcollapse popup

; From Nine

Opt("MustDeclareVars", True)

#include <Constants.au3>

Global Const $CLSID_SpellCheckerFactory = "{7AB36653-1796-484B-BDFA-E74F1DB7C1DC}"
Global Const $IID_ISpellCheckerFactory = "{8E018A9D-2415-4677-BF08-794EA61F94BB}"
Global Const $tag_ISpellCheckerFactory = _
        "get_SupportedLanguages hresult(ptr*);" & _
        "IsSupported hresult(wstr;bool*);" & _
        "CreateSpellChecker hresult(wstr;ptr*);"

Global Const $IID_ISpellChecker = "{B6FD0B71-E2BC-4653-8D05-F197E412770B}"
Global Const $tag_ISpellChecker = _
        "get_LanguageTag hresult(wstr*);" & _
        "Check hresult(wstr;ptr*);" & _
        "Suggest hresult(wstr;ptr*);" & _
        "Add hresult(wstr);" & _
        "Ignore hresult(wstr);"

Global Const $IID_IEnumSpellingError = "{803E3BD4-2828-4410-8290-418D1D73C762}"
Global Const $tag_IEnumSpellingError = _
        "Next hresult(ptr*);"

Example()

Func Example()
    ; initialize Spell Checking API
    Local $oSpell = _MSSpellCheckingAPI_CreateSpell("en-EN") ; English SetUp
;~  Local $oSpell = _MSSpellCheckingAPI_CreateSpell("fr-FR") ; French SetUp
;~  Local $oSpell = _MSSpellCheckingAPI_CreateSpell("pl-PL") ; Polish SetUp
    If @error Then Return SetError(@error, @extended, '')

    ; some words to check
    Local $aWord = ["Spell Checking", "Speell", "Checcking"] ; English words
;~  Local $aWord = ["Test", "Entêté", "Pasd'allure"] ; French words
;~  Local $aWord = ["Sprawdzanie pisowni", "sprawdanie", "pissowni"] ; Polish words

    Local $bHresult = False
    For $sWord In $aWord
        $bHresult = _MSSpellCheckingAPI_Check($oSpell, $sWord)
        MsgBox((($bHresult) ? ($MB_OK) : ($MB_ICONWARNING)), ($bHresult ? "Correct" : "Error"), $sWord)
    Next
EndFunc   ;==>Example

Func _MSSpellCheckingAPI_CreateSpell($tag_language = "en-EN")
    Local $oFactory = ObjCreateInterface($CLSID_SpellCheckerFactory, $IID_ISpellCheckerFactory, $tag_ISpellCheckerFactory)
    If Not IsObj($oFactory) Then
        If Not @Compiled Then ConsoleWrite("! Err : oFactory" & @CRLF)
        Return SetError(1)
    EndIf

    Local $pSpellChecker
    $oFactory.CreateSpellChecker($tag_language, $pSpellChecker)
    Local $oSpell = ObjCreateInterface($pSpellChecker, $IID_ISpellChecker, $tag_ISpellChecker)
    If Not IsObj($oSpell) Then
        If Not @Compiled Then ConsoleWrite("! Err : oSpell" & @CRLF)
        Return SetError(2)
    EndIf

    Return $oSpell

EndFunc   ;==>_MSSpellCheckingAPI_CreateSpell

Func _MSSpellCheckingAPI_Check(ByRef $oSpell, $sWord)
    Local $pErrors, $oErrors, $iHresult
    $oSpell.Check($sWord, $pErrors)
    $oErrors = ObjCreateInterface($pErrors, $IID_IEnumSpellingError, $tag_IEnumSpellingError)
    If Not IsObj($oErrors) Then
        If Not @Compiled Then ConsoleWrite("! Err : oErrors" & @CRLF)
        Return SetError(3, 0, False)
    EndIf
    $iHresult = $oErrors.Next($pErrors)
    Return $iHresult ? True : False
EndFunc   ;==>_MSSpellCheckingAPI_Check

 

Edited Monday at 09:12 PM by mLipok