ListView how to change color of selected unfocused listview element / row ?

[mLipok]

11 minutes ago, WildByDesign said:

I am curious about this as well. In particular, are there any performance differences between constantly creating/deleting brushes in comparison to the non-brush solution?

Exactly this is what I'm curios too. You just worded it in a better way.

Thanks 

11 minutes ago, WildByDesign said:

I've learned a lot from this thread already.

Good for you

[UEZ]

1 hour ago, mLipok said:

@UEZ I also have a question about @Nine example and my modification .
Nine uses 

_WinAPI_DeleteObject($hBrush)

which was fired each time LV was re-drawn

My questions are about using 

_WinAPI_DeleteObject($hBrush)

in a such kind of multiple usage "like a loop"

Question 1:
Should we delete Brush each time or they can be static ? (which I did in my modification to Nine example)

Question 2:
Are there any advantages or disadvantages of using Brush in comparition to yours "non Brush solution" - of coruse in such scenario (using Brush in WM_NOTIFY especially with big ListView) 

Thank you very much in advance
mLipok

 

1) As a general rule, when you open a resource, you should release it again to avoid a memory leak. For example, if you constantly call _WinAPI_CreateSolidBrush(), you’re reserving memory without freeing it up. Eventually, the memory will run out.
Yes, every call to _WinAPI_CreateSolidBrush() / _WinAPI_DeleteObject() takes processing time, which may become noticeable if there are a large number of calls. I don’t think this plays a major role for “normal” applications.

2) At first glance, it appears that no brush is being used, but I assume that Windows creates a brush internally and then deletes it to prevent a memory leak.

[Nine]

5 hours ago, mLipok said:

What is your opionion on this modification ?

No problem with it.  I do not think it really matters, but it doesn't hurt either.

[mLipok]

3 hours ago, UEZ said:

Yes, every call to _WinAPI_CreateSolidBrush() / _WinAPI_DeleteObject() takes processing time, which may become noticeable if there are a large number of calls. I don’t think this plays a major role for “normal” applications.

On big 4K screen with huge numbers of rows in the listview it can be noticeable.

[mLipok]

On 4/22/2026 at 11:44 AM, mLipok said:

My finall modification:

expandcollapse popup

;~ https://www.autoitscript.com/forum/topic/213651-listview-how-to-change-color-of-selected-unfocused-listview-element-row/#findComment-1551804

;Coded by UEZ build 2020-04-21
#include <ColorConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <StructureConstants.au3>
#include <WinAPISys.au3>
#include <WindowsConstants.au3>

Opt("MustDeclareVars", True)

Example1()
Example2()

Func Example1()
    Local $hGUI = GUICreate("Listview Example1", 300, 300)
    Local $idListview = GUICtrlCreateListView("Col1|Col2|Col3  ", 10, 10, 200, 150)
    GUICtrlCreateListViewItem("item2|col22|col23", $idListview)
    GUICtrlCreateListViewItem("item1|col12|col13", $idListview)
    GUICtrlCreateListViewItem("item3|col32|col33", $idListview)
    Local $idButton = GUICtrlCreateButton("Test", 75, 170, 70, 20)
    GUISetState()

    While True
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                GUIDelete($hGUI)
                ExitLoop
            Case $idButton
                _GUICtrlListView_GetSelectedIndices($idListview)
                GUICtrlSetState($idListview, $GUI_FOCUS)
        EndSwitch
    WEnd
EndFunc   ;==>Example1

Func Example2()
    Local $hGUI = GUICreate("Listview Custom Draw Example2", 300, 300)

    Local $idListview = GUICtrlCreateListView("Col1|Col2|Col3", 10, 10, 200, 150, BitOR($LVS_SHOWSELALWAYS, $LVS_REPORT))
    _GUICtrlListView_SetExtendedListViewStyle($idListview, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_DOUBLEBUFFER))

    GUICtrlCreateListViewItem("item2|col22|col23", $idListview)
    GUICtrlCreateListViewItem("item1|col12|col13", $idListview)
    GUICtrlCreateListViewItem("item3|col32|col33", $idListview)
    GUICtrlCreateListViewItem("item4||col33", $idListview)

    Local $idButton = GUICtrlCreateButton("Test", 75, 170, 70, 20)

    GUISetState(@SW_SHOW)
    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

    While True
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                GUIDelete($hGUI)
                ExitLoop
            Case $idButton
                ConsoleWrite("Button clicked." & @CRLF)
        EndSwitch
    WEnd
EndFunc   ;==>Example2

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam

    Local $tNMHDR = DllStructCreate($tagNMHDR, $lParam) ; $tagNMHDR is defined in #include <StructureConstants.au3>
    Local $iCode = $tNMHDR.Code
    Local $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))

    If _WinAPI_GetClassName($hWndFrom)= "SysListView32" Then
        Local $tNMLVCUSTOMDRAW = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam) ; $tagNMLVCUSTOMDRAW is defined in #include <StructureConstants.au3> ; https://learn.microsoft.com/en-us/windows/win32/api/commctrl/ns-commctrl-nmlvcustomdraw
        Local $dwItemSpec = $tNMLVCUSTOMDRAW.dwItemSpec
        Local $dwDrawStage = $tNMLVCUSTOMDRAW.dwDrawStage
        Local $uItemState = $tNMLVCUSTOMDRAW.uItemState
        Local $tItem = DllStructCreate($tagNMLVCUSTOMDRAW, $lParam)
        Local $dwItemType = $tItem.dwItemType

        If $dwItemType = $LVCDI_ITEM Then
            Switch $iCode
                Case $NM_CUSTOMDRAW
                    Switch $dwDrawStage
                        Case $CDDS_PREPAINT
                            Return $CDRF_NOTIFYITEMDRAW

                        Case $CDDS_ITEMPREPAINT
                            If _GUICtrlListView_GetItemSelected($hWndFrom, $dwItemSpec) Then
                                ;remove SELECTED-State and draw system colors
                                $tNMLVCUSTOMDRAW.uItemState = BitAND($uItemState, BitNOT($CDIS_SELECTED), BitNOT($CDIS_FOCUS))
;~                              $tNMLVCUSTOMDRAW.clrTextBk = _WinAPI_GetSysColor($COLOR_HIGHLIGHT) ; for _WinAPI_GetSysColor() "system" color should be used - $COLOR_HIGHLIGHT is defined in WindowsSysColorConstants.au3
;~                              $tNMLVCUSTOMDRAW.clrText = _WinAPI_GetSysColor($COLOR_HIGHLIGHTTEXT) ; for _WinAPI_GetSysColor() "system" color should be used - $COLOR_HIGHLIGHTTEXT is defined in WindowsSysColorConstants.au3
                                $tNMLVCUSTOMDRAW.clrTextBk = $COLOR_BLACK ; direct color - defined in ColorConstants.au3 or given by hand 0x000000
                                $tNMLVCUSTOMDRAW.clrText = $COLOR_WHITE ; direct color - defined in ColorConstants.au3 or given by hand 0xFFFFFF
                                Return $CDRF_NEWFONT
                            EndIf
                    EndSwitch
            EndSwitch
        EndIf
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

 

 

@UEZ yours example is using  Return $CDRF_NEWFONT

Other uses Return $CDRF_SKIPDEFAULT  

The problem that I have with your examples is that I would like to combine them with autonumbering by putting $dwItemSpec to first column .
And adding Grid lines.
As so far I used this snippet:

If $dwDrawStage = $CDDS_PREPAINT Then Return $CDRF_NOTIFYITEMDRAW
            If $dwDrawStage = $CDDS_ITEMPREPAINT Then Return $CDRF_NOTIFYSUBITEMDRAW
            Local $bIsSelected = _GUICtrlListView_GetItemState($tItem.hWndFrom, $tItem.dwItemSpec, $LVIS_SELECTED)
            If $bIsSelected Then
                _WinAPI_SelectObject($hDC, $hBrushItem_Selected)
            Else
                _WinAPI_SelectObject($hDC, $hBrushItem_Unselected)
            EndIf

            _WinAPI_SelectObject($hDC, $hPenItem_Borders)
            If $tItem.dwItemSpec > 0 Then $tRect.top -= 1
            $tRect.bottom += 1
            _WinAPI_Rectangle($hDC, $tRect)

            _WinAPI_SetTextColor($hDC, $bIsSelected ? $clrWhite : $clrBlack)
            _WinAPI_SetBkMode($hDC, $TRANSPARENT)

            $tRect.Left += 5
            $tRect.Top += 2
            If $tItem.iSubitem = $LV_COL__IDX_for_user Then
                _WinAPI_SetTextColor($hDC, $clrGroup2)
                _WinAPI_DrawText($hDC, $dwItemSpec, $tRect, BitOR($DT_CENTER, $DT_INTERNAL, $DT_WORDBREAK))
            Else
                _WinAPI_DrawText($hDC, _GUICtrlListView_GetItemText($tItem.hWndFrom, $tItem.dwItemSpec, $tItem.iSubitem), $tRect, BitOR($DT_LEFT, $DT_INTERNAL, $DT_WORDBREAK))
            EndIf
            Return $CDRF_SKIPDEFAULT

but this impact CPU usage on my i5 8gen laptop - about 4% constant CPU usage instead 0.2% in your solution (without text changing and without gridlines ) .

So my question is do you have idea how to draw gridlines and change text together wiht yours quick/fast solution:

 

                        Case $CDDS_ITEMPREPAINT
                            If _GUICtrlListView_GetItemSelected($hWndFrom, $dwItemSpec) Then
                                ;remove SELECTED-State and draw system colors
                                $tNMLVCUSTOMDRAW.uItemState = BitAND($uItemState, BitNOT($CDIS_SELECTED), BitNOT($CDIS_FOCUS))
;~                              $tNMLVCUSTOMDRAW.clrTextBk = _WinAPI_GetSysColor($COLOR_HIGHLIGHT) ; for _WinAPI_GetSysColor() "system" color should be used - $COLOR_HIGHLIGHT is defined in WindowsSysColorConstants.au3
;~                              $tNMLVCUSTOMDRAW.clrText = _WinAPI_GetSysColor($COLOR_HIGHLIGHTTEXT) ; for _WinAPI_GetSysColor() "system" color should be used - $COLOR_HIGHLIGHTTEXT is defined in WindowsSysColorConstants.au3
                                $tNMLVCUSTOMDRAW.clrTextBk = $COLOR_BLACK ; direct color - defined in ColorConstants.au3 or given by hand 0x000000
                                $tNMLVCUSTOMDRAW.clrText = $COLOR_WHITE ; direct color - defined in ColorConstants.au3 or given by hand 0xFFFFFF
                                Return $CDRF_NEWFONT
                            EndIf

 

Edited May 7 by mLipok