[SOLVED] True Type Fonts install

[mLipok]

How to install True Type Fonts in Windows

Edited April 9, 2012 by mlipok

[Yashied]

Just copy to the Fonts folder.

[mLipok]

it's not that simple

I now it's realy work if I open Explorer

Focusing on TTF file

COPY (CTRL+C)

and

PASTE (CTRL+V) in c:\Windows\Fonts\

But

FileCopy($source_file,$dest_file)

it's dont work (TTF Fonts isn't installed in system - for example can't be used in WORDPAD)

Is any Windows function (WinApi, DLL, OCX or anything else ) to install TTF Fonts ?

Edited November 8, 2010 by mlipok

[Yashied]

Only for TrueType (.ttf) or OpenType (.otf) fonts.

#Include <WinAPIEx.au3>

ConsoleWrite(_FontInstall('MyFont.ttf') & @CR)

Func _FontInstall($sFile)

    Local $Font, $Name, $Path

    $Name = _WinAPI_GetFontResourceInfo($sFile, 1)
    If @error Then
        Return SetError(1, 0, 0)
    EndIf
    $Name &= ' (TrueType)'
    $Font = StringRegExpReplace($sFile, '^.*\\', '')
    If Not RegWrite('HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Fonts', $Name, 'REG_SZ', $Font) Then
        Return SetError(2, 0, 0)
    EndIf
    $Path = _WinAPI_ShellGetSpecialFolderPath($CSIDL_FONTS)
    If Not FileCopy($sFile, $Path) Then
        RegDelete('HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Fonts', $Name)
        Return SetError(3, 0, 0)
    EndIf
    If Not _WinAPI_AddFontResourceEx($Path & '\' & $Font, 0, 1) Then
        Return SetError(4, 0, 0)
    EndIf
    Return 1
EndFunc   ;==>_FontInstall

Edited November 8, 2010 by Yashied

[mLipok]

And thats exacly what I need

thank you very much

[mLipok]

Func _Windows_copy_file($f_file) ; CTRL+C CTRL+V
    Local $oShell = ObjCreate('Shell.Application')
    If @error Or Not IsObj($oShell) Then Return SetError(3)
    Local $oFolder = $oShell.NameSpace('C:\WINDOWS\Fonts\')
    If @error Or Not IsObj($oFolder) Then Return SetError(4)
    $oFolder.CopyHere($f_file)
EndFunc

[Emiel Wieldraaijer]

Func _Windows_copy_file($f_file) ; CTRL+C CTRL+V
    Local $oShell = ObjCreate('Shell.Application')
    If @error Or Not IsObj($oShell) Then Return SetError(3)
    Local $oFolder = $oShell.NameSpace('C:\WINDOWS\Fonts\')
    If @error Or Not IsObj($oFolder) Then Return SetError(4)
    $oFolder.CopyHere($f_file)
EndFunc

Func _Windows_copy_file($f_file, $f_destination) 
        ; CTRL+C CTRL+V
        ; Replace  $f_destination with "@WindowsDir & \Fonts\"
    Local $oShell = ObjCreate('Shell.Application')
    If @error Or Not IsObj($oShell) Then Return SetError(3)
    Local $oFolder = $oShell.NameSpace($f_destination')
    If @error Or Not IsObj($oFolder) Then Return SetError(4)
    $oFolder.CopyHere($f_file)
EndFunc