ParseHeadersToSciTE() - Parse include headers to the appropriate format for SciTE calltips and properties.

[guinness]

Just a quick snippet I created to parse UDF headers into the format used by SciTE for calltips and properties. This came about as I was constantly having to mess around with the files for >ResourcesEx UDF and overtime it became quite laborious.

#include <FileConstants.au3>
#include <WinAPIShPath.au3>

Local $sFileOpenDialog = FileOpenDialog('Select an Au3 script file with headers.', @ScriptDir & '\', 'Au3 Script (*.au3)', $FD_FILEMUSTEXIST)
If Not @error Then
    Local $sOutput = ParseHeadersToSciTE($sFileOpenDialog)
    ConsoleWrite($sOutput)
    ClipPut($sOutput)
EndIf

Func ParseHeadersToSciTE($sFilePath)
    Local Enum $PARAMS_FUNCTIONNAME, $PARAMS_DESCRIPTION, $PARAMS_PARAMSIGNATURE
    Local $sReturn = ''
    Local $aSRE = StringRegExp(FileRead($sFilePath), '(?is:\R;\hName\h\.+:\h(\w+)\h*\R;\hDescription\h\.+:\h(.+?)\R;\hSyntax\h\.+:\h(\1.+?)(?=\R;\hParameters\h\.))', $STR_REGEXPARRAYGLOBALMATCH)
    If Not @error Then
        Local $iFuncCount = 0, _
                $sCallTips = '', $sProperties = '', $sUDFName = _WinAPI_PathStripPath($sFilePath)
        For $i = 0 To UBound($aSRE) - 1 Step 3
            $iFuncCount += 1
            $sCallTips &= StringRegExpReplace($aSRE[$i + $PARAMS_PARAMSIGNATURE], '\h*\R;\h+', '') & ' ' & $aSRE[$i + $PARAMS_DESCRIPTION] & ' (Requires: #include <' & $sUDFName & '>)' & @CRLF
            $sProperties &= StringLower($aSRE[$i + $PARAMS_FUNCTIONNAME]) & ' '
            If Not Mod($iFuncCount, 5) Then
                $sProperties &= '\' & @CRLF & @TAB
                $iFuncCount = 0
            EndIf
        Next
        If Mod($iFuncCount, 5) Then
            $sProperties &= '\'
        EndIf
        $sReturn = 'Add to au3.user.calltips.api:' & @CRLF & $sCallTips & @CRLF & 'Add to au3.userudfs:' & @CRLF & $sProperties & @CRLF
    EndIf
    Return $sReturn
EndFunc   ;==>ParseHeadersToSciTE

[mLipok]

This script return also internal function.

[guinness]

Probably. But then I don't use headers with internal functions, only functions accessed by the user.