Breakup an XML document into separate documents

[ijourneaux]

I have an XML document with multiple nodes called "Entity". I would like to create individual xml documents for each Entity.  I am using the addin XML_1.1.1.13 to read the xml file but I can't seem to figure out how to save out the individual entities.

I am successfully processing the XML file using the snippet below. Do I need to create a new XMLDoc and copy the nodes over one at a time?

 

$oXmlDoc = _XML_CreateDOMDocument(Default)
    _XML_Load($oXmlDoc,$sFileXML)  ;<== ENTER XML FILE PATH HERE

    ;Get number of Property nodes
    $oEntities= _XML_SelectNodes($oXmlDoc,"//Entity")

    For $oEntity In $oEntities
        Save Entity
    Next

 

[careca]

You could read the file and do a stringsplit and then write the contents into those other files.

Edited December 12, 2018 by careca

[ijourneaux]

That could work. Is there a way to stringsplit on a string instead of a single character. It would be easy if I could do something like

$entitystr = StringSplit($xmlFIleContents, "<Entity")

 

[mLipok]

$STR_ENTIRESPLIT

[FrancescoDiMuro]

@ijourneaux

Could you post a sample XML file?

[jdelaney]

Use filewrite in your loop...write $oEnity.xml to each file.   use an id inside entity as the file name so they are all unique

[ijourneaux]

  On 12/12/2018 at 8:11 PM, jdelaney said:

Use filewrite in your loop...write $oEnity.xml to each file.   use an id inside entity as the file name so they are all unique

Expand  

Here is a typical XML file I am dealing with.  I would like to write each Entity as a separate XML file.

walkaround.xml

[jdelaney]

Did you try as I suggested?  .xml on a node outputs the xml relative to that node.   throw it into a consoleoutput

Edited December 17, 2018 by jdelaney

[TheXman]

You could also parse out the <Entity> nodes using a regular expression.

#include <Constants.au3>

example()

Func example()
    Const $XML_FILE  = "walkaround.xml" ;<-- Point to your xml file

    Local $sXmlData  = FileRead($XML_FILE)
    Local $aEntities = StringRegExp($sXmlData, "(?s)(<Entity.*?</Entity>)", $STR_REGEXPARRAYGLOBALMATCH)

    FileDelete("~xml_file_*")
    For $i = 0 To UBound($aEntities) - 1
        FileWrite(StringFormat("~xml_file_%02i.xml", $i), $aEntities[$i])
    Next
EndFunc

 

Edited December 17, 2018 by TheXman

[careca]

;=============================================================================
#Region ;Includes
#RequireAdmin
;=============================================================================
#include <String.au3> ;This for _StringBetween
;=============================================================================
#EndRegion ;Includes
;=============================================================================
Global $StrBt
Global $FO = FileOpen('walkaround.xml')
Global $FR = FileRead($FO)
FileClose($FO)
$StrBt = _StringBetween($FR, '<Entity ', '</Entity>')
If Not @error Then
For $i = 0 To UBound($StrBt)-1
$FO = FileOpen(@ScriptDir&'\tmp\'& $i&'.txt', 10)
FileWrite($FO, $StrBt[$i])
FileClose($FO)
Next
MsgBox(64 + 262144, '', 'Done')
EndIf

 

Edited December 17, 2018 by careca

[ijourneaux]

  On 12/17/2018 at 2:57 PM, jdelaney said:

Did you try as I suggested?  .xml on a node outputs the xml relative to that node.   throw it into a consoleoutput

Expand  

I tried but the files were 0bytes long.

For $oEntity In $oEntities
         $sString = ""
         filewrite("c:\temp\test"& $cnt & ".xml", $oEntity)
         $cnt = $cnt+1
     Next

 

[ijourneaux]

The StringBetween approach works (with some very minor adjustments to output formatting to maintain correct XML formating). I am sure the regular expression approach would work as well but I have not used to using regular expressions much.

It would have been nice if filewrite( filename, $oEntity) would have worked but as I indicated, that only output 0 bytes.

[careca]

In the remarks of Filewrite:

"The file must be opened in write mode or the FileWrite() command will fail."

Maybe it has something to do with that.

Try opening using flag 9 or 10 and then write and then close.

[TheXman]

  On 12/17/2018 at 3:57 PM, ijourneaux said:

It would have been nice if filewrite( filename, $oEntity) would have worked but as I indicated, that only output 0 bytes.

Expand  

This works for me.  It uses the .xml property that @jdelaney was referring to.

#include <xml.au3>  ;<-- Change to your location

example()

Func example()
    Const $XML_FILE  = "walkaround.xml" ;<-- Point to your xml file

    Local $oXmlDoc, $oNode
    Local $iNodeCount = 0

    ;Load XML file
    $oXmlDoc = _XML_CreateDOMDocument()
    $oXmlDoc = _XML_Load($oXmlDoc, $XML_FILE)

    ;Get number of Entity nodes
    $iNodeCount = _XML_GetNodesCount($oXmlDoc, "//Entity")

    ;Write each Entity node to a separate file
    FileDelete("~xml_file_*")
    For $i = 1 To $iNodeCount
        $oNode = _XML_SelectSingleNode($oXmlDoc, StringFormat("//Entity[%i]", $i))
        FileWrite(StringFormat("~xml_file_%02i.xml", $i), $oNode.xml)
    Next
EndFunc

 

Edited December 17, 2018 by TheXman

[jdelaney]

You need to add .xml to it. .. $oEntity.xml

[ijourneaux]

Thank you. That is exactly what I was looking for.

[ijourneaux]

Unfortunately it doesn't quite work the way I need. When I use the approach proposed by TheXMan, I end up losing the <Entities> node that wraps all of the Entity nodes. 
 

<?xml version="1.0"?>
<Entities>
...
</Entities>

[jdelaney]

FileWrite("yourfile.xml","<Entities>" & $oEntity.xml & "</Entities>")

 

[ijourneaux]

It is amazing how obvious the answer is after someone shows you.

Thanks Everyone for the help. As alwasy a great learning experience.