Assigning a Function call with Parameters to a Variable??

[bailey1274]

So I know this is possible

local $my_func = DoSomething

$my_func()

func DoSomething()
    ConsoleWrite('Foo Bar')
endfunc

But to me, this doesn't seem to add much usefulness. Maybe a couple edge cases to make things more readable? 

Although my question is if there is any way the following would be achievable? 

local $my_func = DoSomething('1') ; $my_func is now 0 but I would like to be able to call the varibale as a reference to the parameter passed in at the time of assignment

$my_func() ; -> wont work

func DoSomething($sText)
    ConsoleWrite('Foo Bar sText = '&sText)
    return 0
endfunc

 

[Nine]

How can AutoIt know that Local $my_func = DoSomething('1') is not a normal assignment ?  How would you know yourself the way to interpret that statement ?

Only way :

local $my_func = DoSomething

$my_func("123")

func DoSomething($txt)
    ConsoleWrite('Foo Bar ' & $txt & @CRLF)
endfunc

 

Edited August 13, 2020 by Nine

[mLipok]

but how about this case:

Local $my_func = DoSomething

$my_func()

Func DoSomething($sText = 1)
    ConsoleWrite('Foo Bar sText = ' & $sText & @CRLF)
    Return 0
EndFunc   ;==>DoSomething

Maybe this solve your problems, needs...

[TheXman]

What about having the delegated function read its parameters from global vars?

Global $gFuncDelegate
Global $gsText = ""

$gFuncDelegate = DoSomething

$gsText = "Test #1"
$gFuncDelegate()

$gsText = "Test #2"
$gFuncDelegate()

$gFuncDelegate = DoSomethingElse

$gsText = "Test #3"
$gFuncDelegate()

Func DoSomething()
    ConsoleWrite('Foo Bar $gsText = ' & $gsText & @CRLF)
    return 0
EndFunc

Func DoSomethingElse()
    ConsoleWrite('Bar Foo $gsText = ' & $gsText & @CRLF)
    return 0
EndFunc

 

Edited August 13, 2020 by TheXman

[RTFC]

This works:

local $my_func = DoSomething('123')

Execute($my_func)

func DoSomething($sText)
    ConsoleWrite('Foo Bar sText = '& $sText & @CRLF)
    return 0
endfunc

EDIT: forgot to copy the quotation marks around $my_func definition.

Edited August 15, 2020 by RTFC

[Nine]

2 hours ago, RTFC said:

This works:

Serious ?  That doesn't work at all. The execute or call is useless this way :

local $test = "a"
local $my_func = DoSomething('123')

$test = "b"
Execute($my_func)

func DoSomething($sText)
    ConsoleWrite('Foo Bar sText = '& $sText & $test & @CRLF)
    return 0
endfunc

but this works :

local $test = "a"
local $my_func = "DoSomething('123')"

$test = "b"
execute($my_func)

func DoSomething($sText)
    ConsoleWrite('Foo Bar sText = '& $sText & $test & @CRLF)
    return 0
endfunc

 

[bailey1274]

Thanks guys, this may be the closest to get what I'm trying to achieve

local $test = "a"
local $my_func = "DoSomething('123')"

$test = "b"
execute($my_func)

func DoSomething($sText)
    ConsoleWrite('Foo Bar sText = '& $sText & $test & @CRLF)
    return 0
endfunc

My goal is to have one variable that contains some function call with a certain parameter and be able to call that variable without giving params every time BUT ALSO be able to change that param at various sections of the script. I think this is the closest that I'll get to this sort of functionality in AutoIt.

local $ERROR

local $my_obj1 = ObjCreate(...)
$ERROR = "Error($my_obj1)"

do_something($my_obj1)
If @error Then execute($ERROR)

; More Code

local $my_obj2 = ObjCreate(...)
$ERROR = "Error($my_obj2)"

do_something($my_obj2)
If @error Then execute($ERROR)

func Error(ByRef $this_obj)
    ; Clean things up, log & destroy this obj
endfunc

func do_something(ByRef $this_obj)
    ; some function call that uses this_obj
    If @error Then Return SetError(1)
endfunc