Help File/Documentation Issues. (Discussion Only)

[argumentum]

what I meant by "Local Const $PW_RENDERFULLCONTENT = 0x2 ; this will go to where it should 😃" is that we need to add $PW_RENDERFULLCONTENT, PW_CLIENTONLY and PW_CLIENTGoFigure to the constants script.

PW_CLIENTONLY used to be true/false. After Win8.1 PW_RENDERFULLCONTENT came along, and are now BitOR values.
Given that is not documented, declaring PW_CLIENTONLY = 1 but we ( at least myself ) don't have a const. name for ZERO.
PW_RENDERFULLCONTENT + PW_CLIENTONLY = 3, and works as such.

We ( well, you @mLipok ) have to come with proper naming. Good luck Jim

If you don't find a name, I'll look around and invent a proper sounding one

[argumentum]

The doc says "By default, the entire window is copied." So if you set 0, PW_CLIENTONLY is not set and PrintWindow calls GetWindowRect instead of GetClientRect

PW_WINDOW = 0x0. ( uses GetWindowRect )
PW_CLIENTONLY = 0x1 ( uses GetClientRect )
PW_RENDERFULLCONTENT = 0x2 ( uses Windows.Graphics.Capture API )

( am working.. at work, so I can't give it more attention right now  )

[mLipok]

20 hours ago, argumentum said:

The doc says "By default, the entire window is copied." So if you set 0, PW_CLIENTONLY is not set and PrintWindow calls GetWindowRect instead of GetClientRect

PW_WINDOW = 0x0. ( uses GetWindowRect )
PW_CLIENTONLY = 0x1 ( uses GetClientRect )
PW_RENDERFULLCONTENT = 0x2 ( uses Windows.Graphics.Capture API )

( am working.. at work, so I can't give it more attention right now  )

@jpm took everything into account (I have seen it I on SVN.)
https://www.autoitscript.com/trac/autoit/ticket/4069#comment:2

Thanks @jpm

Edited January 29 by mLipok

[mLipok]

Today thanks to @ioa747 I hit something new to me.
You can create many Event Handlers for the same Object.
Did you know that ?

Here is modified example: ObjEvent.au3

expandcollapse popup

#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Error monitoring. This will trap all COM errors while alive.
    ; This particular object is declared as local, meaning after the function returns it will not exist.
    Local $oErrorHandler = ObjEvent("AutoIt.Error", "_ErrFunc")

    ; Create Internet Explorer object
    Local $oIE = ObjCreate("InternetExplorer.Application")
    ; Check for errors
    If @error Then Return

    $oIE.Visible = True ; set visibility

    ; Custom sink object
    Local $oIEEvents_1 = ObjEvent($oIE, "_IEEvent_1_", "DWebBrowserEvents2")
    Local $oIEEvents_2 = ObjEvent($oIE, "_IEEvent_2_", "DWebBrowserEvents2")

    ; Navigate somewhere
    $oIE.navigate("http://www.google.com/")
    ; Check for errors while loading
    If @error Then
        $oIE.Quit()
        Return
    EndIf

    ; Wait for page to load
    While 1
        If $oIE.readyState = "complete" Or $oIE.readyState = 4 Then ExitLoop
        Sleep(10)
    WEnd

    ; Deliberately cause error by calling non-existing method
    $oIE.PlayMeARockAndRollSong()

    ; Check for errors
    If @error Then MsgBox($MB_SYSTEMMODAL, "COM Error", "@error is set to COM error number." & @CRLF & "@error = 0x" & Hex(@error))

    ; Wait few seconds to see if more events will be fired
    Sleep(3000)

    ; Nothing more to do. Close IE and return from the function
    $oIE.Quit()

    #forceref $oErrorHandler, $oIEEvents_1, $oIEEvents_2
EndFunc   ;==>Example

; BeforeNavigate2 method definition
Func _IEEvent_1_BeforeNavigate2($oIEpDisp, $sIEURL, $iIEFlags, $sIETargetFrameName, $sIEPostData, $iIEHeaders, $bIECancel)
    ConsoleWrite("!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!--_IEEvent_1_BeforeNavigate2() fired--!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!! " & @CRLF & _
            "$oIEpDisp = " & $oIEpDisp() & "  -  " & ObjName($oIEpDisp) & @CRLF & _ ; e.g. default property and name for the object
            "$sIEURL = " & $sIEURL & @CRLF & _
            "$iIEFlags = " & $iIEFlags & @CRLF & _
            "$sIETargetFrameName = " & $sIETargetFrameName & @CRLF & _
            "$sIEPostData = " & $sIEPostData & @CRLF & _
            "$iIEHeaders = " & $iIEHeaders & @CRLF & _
            "$bIECancel = " & $bIECancel & @CRLF & _
            "!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!! " & @CRLF & @CRLF)
EndFunc   ;==>_IEEvent_BeforeNavigate2

Func _IEEvent_2_BeforeNavigate2($oIEpDisp, $sIEURL, $iIEFlags, $sIETargetFrameName, $sIEPostData, $iIEHeaders, $bIECancel)
    ConsoleWrite("!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!--_IEEvent_2_BeforeNavigate2() fired--!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!! " & @CRLF & _
            "$oIEpDisp = " & $oIEpDisp() & "  -  " & ObjName($oIEpDisp) & @CRLF & _ ; e.g. default property and name for the object
            "$sIEURL = " & $sIEURL & @CRLF & _
            "$iIEFlags = " & $iIEFlags & @CRLF & _
            "$sIETargetFrameName = " & $sIETargetFrameName & @CRLF & _
            "$sIEPostData = " & $sIEPostData & @CRLF & _
            "$iIEHeaders = " & $iIEHeaders & @CRLF & _
            "$bIECancel = " & $bIECancel & @CRLF & _
            "!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!! " & @CRLF & @CRLF)
EndFunc   ;==>_IEEvent_BeforeNavigate2

; User's COM error function. Will be called if COM error occurs
Func _ErrFunc($oError)
    ; Do anything here.
    ConsoleWrite(@ScriptName & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc   ;==>_ErrFunc

 

[mLipok]

Hello my friends

Please take a look here: https://www.autoitscript.com/trac/autoit/ticket/4070

What do you think ?

[mLipok]

Original MapKeys() example:

#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Declare a map and assign with various keys value pairs.
    Local $mMap[]
    $mMap[1] = "Integer One" ; Integer value as a key.
    $mMap["2"] = "String Two" ; String value representing an integer as a key. This is a string not an integer.
    MapAppend($mMap, "Integer Two") ; Append a value using the next available integer, which is 2 in this case.

    ; Retrieve the keys contained in the map. A zero-based one-dimensional array is returned.
    Local $aMapKeys = MapKeys($mMap)
    For $vKey In $aMapKeys ; Or a For loop can be used as well.
        MsgBox($MB_SYSTEMMODAL, "", "Key: " & $vKey & @CRLF & _ ; The key.
                "Value: " & $mMap[$vKey] & @CRLF & _ ; Use the array value of MapKeys() to display the value of the key.
                "Variable Type: " & VarGetType($vKey) & @CRLF) ; Display the variable type of the key i.e. integer or string.
    Next
EndFunc   ;==>Example

proposal:

#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Declare a map and assign with various keys value pairs.
    Local $mMap[]
    $mMap[1] = "Integer One" ; Integer value as a key.
    $mMap["2"] = "String Two" ; String value representing an integer as a key. This is a string not an integer.
    MapAppend($mMap, "Integer Two") ; Append a value using the next available integer, which is 2 in this case.
    $mMap.test = 'testing' ;

    ; Retrieve the keys contained in the map. A zero-based one-dimensional array is returned.
    Local $aMapKeys = MapKeys($mMap)
    For $vKey In $aMapKeys ; Or a For loop can be used as well.
        MsgBox($MB_SYSTEMMODAL, "", _
                "Key: " & $vKey & @CRLF & _ ; The key.
                "Key Type: " & VarGetType($vKey) & @CRLF & _ ; Display the variable type of the key i.e. integer or string.
                "Key Value: " & $mMap[$vKey] & @CRLF & _ ; Use the array value of MapKeys() to display the value of the key.
                "")
    Next
EndFunc   ;==>Example

please suggest comments for:

$mMap.test = 'testing' ;

 

Any comments are welcome.

Edited 14 hours ago by mLipok

[argumentum]

I don't like MsgBox() outputs, but that is just my preference.
The change looks good to me.

There is a problem with using integers as index ( look here ). That should be noted, in the fact that strings are preferable in maps due to 🤷‍♂️

[pixelsearch]

4 hours ago, argumentum said:

I don't like MsgBox() outputs, but that is just my preference.

I don't like them only when they're displayed in a loop, 1 MsgBox for 1 result, it may be endless.
That's why I used another kind of display when it comes to visualize a Map content, in this thread

[mLipok]

#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Declare a map and assign with various keys value pairs.
    Local $mMap[]
    $mMap[1] = "Integer One" ; Integer value as a key.
    $mMap["2"] = "String Two" ; String value representing an integer as a key. This is a string not an integer.
    MapAppend($mMap, "Integer Two") ; Append a value using the next available integer, which is 2 in this case.
    $mMap.test = 'testing' ;

    ; Retrieve the keys contained in the map. A zero-based one-dimensional array is returned.
    Local $aMapKeys = MapKeys($mMap)
    For $vKey In $aMapKeys ; Or a For loop can be used as well.
        ConsoleWrite(@CRLF & _
                '> Key: ' & $vKey & @CRLF & _ ; The key.
                '> Key Type: ' & VarGetType($vKey) & @CRLF & _ ; Display the variable type of the key i.e. integer or string.
                '> Key Value: "' & $mMap[$vKey] & '"' & @CRLF & _ ; Use the array value of MapKeys() to display the value of the key.
                '')
    Next
EndFunc   ;==>Example

please suggest comment for:

$mMap.test = 'testing' ;

 

Edited 7 hours ago by mLipok
script modified -2nd time

[Nine]

42 minutes ago, mLipok said:

please suggest comment for:

$mMap.test = 'testing' ; Dot notation equivalent to $mMap["test"] = "testing"

ps. you do not need the #include anymore

Edited 6 hours ago by Nine

[mLipok]

finall version:

Example()

Func Example()
    ; Declare a map and assign with various keys value pairs.
    Local $mMap[]
    $mMap[1] = "Integer One" ; Integer value as a key.
    $mMap["2"] = "String Two" ; String value representing an integer as a key. This is a string not an integer.
    MapAppend($mMap, "Integer Two") ; Append a value using the next available integer, which is 2 in this case.
    $mMap.test = 'testing' ; Dot notation equivalent to $mMap["test"] = "testing"

    ; Retrieve the keys contained in the map. A zero-based one-dimensional array is returned.
    Local $aMapKeys = MapKeys($mMap)
    For $vKey In $aMapKeys ; Or a For loop can be used as well.
        ConsoleWrite(@CRLF & _
                '> Key: ' & $vKey & @CRLF & _ ; The key.
                '> Key Type: ' & VarGetType($vKey) & @CRLF & _ ; Display the variable type of the key i.e. integer or string.
                '> Key Value: "' & $mMap[$vKey] & '"' & @CRLF & _ ; Use the array value of MapKeys() to display the value of the key.
                '')
    Next
EndFunc   ;==>Example

 

[donnyh13]

Looks good @mLipok,

Perhaps the trailing &  _ '' could be removed?

Example()

Func Example()
    ; Declare a map and assign with various keys value pairs.
    Local $mMap[]
    $mMap[1] = "Integer One" ; Integer value as a key.
    $mMap["2"] = "String Two" ; String value representing an integer as a key. This is a string not an integer.
    MapAppend($mMap, "Integer Two") ; Append a value using the next available integer, which is 2 in this case.
    $mMap.test = 'testing' ; Dot notation equivalent to $mMap["test"] = "testing"

    ; Retrieve the keys contained in the map. A zero-based one-dimensional array is returned.
    Local $aMapKeys = MapKeys($mMap)
    For $vKey In $aMapKeys ; Or a For loop can be used as well.
        ConsoleWrite(@CRLF & _
                '> Key: ' & $vKey & @CRLF & _ ; The key.
                '> Key Type: ' & VarGetType($vKey) & @CRLF & _ ; Display the variable type of the key i.e. integer or string.
                '> Key Value: "' & $mMap[$vKey] & '"' & @CRLF) ; Use the array value of MapKeys() to display the value of the key.
    Next
EndFunc   ;==>Example