@error COM error

[hemichallenger]

Func MyErrFunc()
Local $HexNumber

If IsObj($oMyError) Then
$HexNumber = Hex($oMyError.number, 8)
    GUICtrlSetData($GreenProgress,"")
    _RedProgress()
    GUICtrlSetData($Output,"")
    GUICtrlSetData($Output, "Intercepted a COM ""Component Object Model"" Error with the computer!" & @CRLF & @CRLF & _
"Description : " & $oMyError.windescription, 10)

SetError($HexNumber)
EndIf
SetError (1)
Return
EndFunc

Has anyone ran into the issue with a COM error crashing your script? The script works and catches the error twice and then the third time it crashes the script "The RPC server is unavailable.". The script looks up the computer and grabs there MAC address and IP thru WMI.

[water]

Which version of AutoIt do you run?

[mLipok]

Sorry for inclusion, but sometimes I have similar problems (if I remember it I had them with IE.au3).

It looks as if a large number of operations performed on the object COM, one of the sites service from system has been turned off and the effect of this error arises.

Edited July 29, 2014 by mLipok

[water]

I do not think it is sensible to call GUI functions from a COM error handler. I would pack all needed error information into an array an error an error code to the main script. Then set the information for the GUI there.

[hemichallenger]

Version v3.3.12.0

[water]

There is no need for a COM error handler with 3.3.12.0.

Simply check @error after each function that could raise a COM error.

[hemichallenger]

Func MyErrFunc()
Local $HexNumber

If IsObj($oMyError) Then
$HexNumber = Hex($oMyError.number, 8)

    MsgBox(64, "test", "Intercepted a COM ""Component Object Model"" Error with the computer!" & @CRLF & @CRLF & _
"Description : " & $oMyError.windescription, 10)

SetError($HexNumber)
EndIf
SetError (1)
Return
EndFunc

I tried it this way and after displaying the error twice the script crashes on the third time.

[water]

In AutoIt 3.3.12.0 the error object is passed as the first parameter. Could you please test:

Func MyErrFunc($oMyError)
    Local $HexNumber
    $HexNumber = Hex($oMyError.number, 8)
    MsgBox(64, "test", "Intercepted a COM ""Component Object Model"" Error with the computer!" & @CRLF & @CRLF & _ "Description : " & $oMyError.windescription, 10) 
    SetError($HexNumber) 
    Return 
EndFunc

[JLogan3o13]

Water, I'm getting an error on your _, after the second @CRLF &. I'm guessing you had the lines split at one point

Edited July 29, 2014 by JLogan3o13

[hemichallenger]

That still didn't work. The third time crashed the script again. So i changed it this way and it works every time but it doesn't pull the com error description.

If @error Then  MsgBox(64, "test", "Intercepted a COM ""Component Object Model"" Error with the computer!" & @CRLF & @CRLF & "Description : " & $oMyError.windescription, 10)

[water]

What do you mean by "crashing"? Can you post an error message?

[hemichallenger]

"AutoIt V3 Script has stopped working"    A problem cause the program to stop working correctly. Please close the program.

[j0kky]

Try this:

$oMyError = ObjEvent("AutoIt.Error","MyErrFunc")
;YOUR CODE WITH COM ERROR

Func MyErrFunc()
    $HexNumber=hex($oMyError.number,8)
    Msgbox(0,"","We intercepted a COM Error !" & @CRLF & _
        "Number is: " & $HexNumber & @CRLF & _
        "Windescription is: " & $oMyError.windescription & @CRLF & _
        "Source is: " & $oMyError.source & @CRLF & _
        "Description is: " & $oMyError.description & @CRLF & _
        "Script line is: " & $oMyError.scriptline)
    Exit
Endfunc

And post here the content of the message box.

Edited July 30, 2014 by j0kky

[hemichallenger]

it shows the RPC error code and exit the program not what I wanted. But I decided just to leave the error description Func MyErrFunc() out.

If @error Then  MsgBox(64, "test", "Intercepted a COM ""Component Object Model"" Error with the computer!")

[water]

Is it possible that you post the whole script?

Information about the operating system you use would be fine too.

So we could try to reproduce the error here and do some more intense testing.
 

[hemichallenger]

expandcollapse popup

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>

#RequireAdmin

Global $oMyError

$mainWindow = GUICreate ("TEST MAC and IP", 329, 100, 330, 442)
GUISetBkColor(0xE3E3E3)
GUISetFont(9, 300)
$Button1 = GUICtrlCreateButton("TEST", 99.5, 50, 130, 21)
$Input1 = GUICtrlCreateInput('', 64.5, 12, 200, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_CENTER))
StringUpper(GUICtrlRead($Input1))
GUICtrlSendMsg(-1, $EM_SETCUEBANNER, False, "Computer Name or IP")
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
GUISetState(@SW_SHOW, $mainWindow)


While 1
    $gMsg = GUIGetMsg()
    Switch $gMsg
        Case $GUI_EVENT_CLOSE
        Exit;
        Case $Button1
            Dim $strComputer = GUICtrlRead ($Input1)
            If $strComputer = "" Then
                MsgBox(16,"ERROR","No Entry", 10)
            Else
                _TEST()
            EndIf
        EndSwitch
    WEnd


Func _TEST()
    Local $strComputer = GUICtrlRead ($Input1)
        $ping = Ping($strComputer, 500)
    If $ping Then
        $oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")
        $objWMIService = ObjGet('winmgmts:\\' & $strComputer & '\root\CIMV2')
            If Not @error Then
                $colItems = $objWMIService.ExecQuery("SELECT * FROM Win32_NetworkAdapterConfiguration WHERE (IPEnabled = True AND NOT Caption LIKE '%VMware%' AND NOT Caption LIKE '%VirtualBox%')")
                    For $objAdapter In $colItems
                        If $objAdapter.MACAddress <> "" Then
                            MsgBox(0, "Info", "Computer Name: " & $strComputer & @CRLF & _
                            "MAC Address: "& $objAdapter.MacAddress & @CRLF & _
                            "IP Address: "& $objAdapter.IPAddress(0))
                        EndIf
                    Next
            EndIf
    Else
    MsgBox(64, "test", "Computer could not be contacted.")
    EndIf
EndFunc


Func MyErrFunc()
    Local $HexNumber
    If IsObj($oMyError) Then
        $HexNumber = Hex($oMyError.number, 8)
            MsgBox(64, "test", "Intercepted a COM ""Component Object Model"" Error with the computer!" & @CRLF & @CRLF & _
            "Description : " & $oMyError.windescription, 10)
            SetError($HexNumber)
    EndIf
    Return
EndFunc

Edited August 1, 2014 by hemichallenger

[water]

I have tested 20 times with 127.0.0.1, the full IP-address and the computer name but the script didn't crash.

I'm running Windows 7 64 bit.

What do you use?

[hemichallenger]

The script works fine until you get a computer with a COM error on the network. "The RPC server is unavailable." for example.  I've tried it on both 32 and 64 bit Win7 same results. For testing ill run the script on a computer I know on the network which pulls a COM error. Script runs fine and shows the error message a couple times and third attempt  "AutoIt V3 Script has stopped working"    A problem cause the program to stop working correctly. Please close the program.

[water]

The help file describing COM says:

"You can have as many COM Error Event Handlers. The last registered and alive object is the one that gets called."

As you have only one COM error handler I would move line

$oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")

to the top of the script and overwrite line "Global $oMyError"

Global $oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")

So you only create a single COM error handler once.

[hemichallenger]

Thank you Sir. You are correct, that fixed the issue.